Sort Array (2D) ? Topic is solved

[IMEime]

Sorry, I guess, it is already somewhere else, but I can not find it easily.

Code: Select all

myArray := [[2, "Quick"]
, [4, "Brown"]
, [3, "Fox"]
, [1, "Jumps"]]	
For Each, x In myArray
	myResult .= x[1] " " x[2] "`n"
MsgBox % myResult

I'd like make it like this

1 Jumps
2 Quick
3 Fox
4 Brown

Thanks

[swagfag]

if u use an object it will sort itself automatically:

Code: Select all

myArray := {2: "Quick"
		  , 4: "Brown"
		  , 3: "Fox"
		  , 1: "Jumps"}	

For i, x In myArray
	myResult .= i " " x "`n"
MsgBox % myResult

[IMEime]

possible workaround is to combine it into 1D, sort and make it 2D again
but... that is not so beautiful...

[IMEime]

if u use an object it will sort itself automatically:..

ah.. really ? interesting..

[IMEime]

on second thought..
I could have, for instance, two (2) 2's
Is it OK with the Object ?

[EDIT]
Nah.. it overwrites....

[sinkfaze]

Since objects already sort in the manner that you would like, pass everything to an object and pass them back out into their arrays:

Code: Select all

myArray := [[2, "Quick"]
 ,[4, "Brown"]
 ,[3, "Fox"]
 ,[1, "Jumps"]]

tObj :=	{}	

For each, arr In myArray
	tObj[arr[1]] :=	arr[2]

myArray :=	[]

For n, w in tObj
	myArray.Push([n,w])

For each, arr In myArray
	myResult .= arr[1] " " arr[2] "`n"

MsgBox %	Trim(myResult)

[IMEime]

Since objects already sort in the manner that you would like, pass everything to an object and pass them back out into their arrays:...

Thanks for the nice tip
But
It overwrites too.

Code: Select all

myArray := [[2, "Quick"]
 ,[4, "Brown"]
 ,[3, "Fox"]
 ,[3, "Over"]
 ,[1, "Jumps"]]

1 Jumps
2 Quick
3 Over
4 Brown

[sinkfaze]

It overwrites too.

Pass the elements to a variable, use Sort, parse, split, back to arrays.

Code: Select all

myArray := [[2, "Quick"]
 ,[4, "Brown"]
 ,[3, "Fox"]
 ,[3, "Over"]
 ,[1, "Jumps"]]

tList :=	""

For each, arr In myArray
	tList .=	arr[1] " " arr[2] "`n"

tList :=	RegExReplace(tList,"s)^\v+|\v+$")
Sort, tList

myArray :=	[]

Loop, parse, tList, `n, `r
	_ :=	StrSplit(A_LoopField," "), myArray.Push([_[1],_[2]])

For each, arr In myArray
	myResult .= arr[1] " " arr[2] "`n"

MsgBox %	myResult

[IMEime]

possible workaround is to combine it into 1D, sort and make it 2D again
but... that is not so beautiful...

anyway.. thanks "sinkfaze" for your efforts..

[oif2003]

Hi,
It is not obvious to me how one would sort a 2D array. Are you trying to say, sort by rows first, then by columns? or the other way around?

[IMEime]

Hi,
It is not obvious to me how one would sort a 2D array. Are you trying to say, sort by rows first, then by columns? or the other way around?

thanks for comment
you have a point
But
that is minor stuff
that is your choice (or default)
I am not good at C# though
I have tried, have a look at it

Code: Select all

List<List<string>> myArray = 
	new List<List<string>> {				       
		new List<string> { "2", "Quick" },
		new List<string> { "4", "Brown" },
		new List<string> { "3", "Fox" },
		new List<string> { "3", "Over" },
		new List<string> { "1", "Jump" }};
MessageBox.Show(string.Join("\n", 
	myArray
		.OrderBy(x => x[0])
		.ThenBy(x => x[1])
		//.ThenByDescending(x => x[1])
		.Select(x => x[0] + " " + x[1])));

//  1 Jump
//  2 Quick
//  3 Fox
//  3 Over
//  4 Brown

//  1 Jump
//  2 Quick
//  3 Over
//  3 Fox
//  4 Brown

i am not wanted the same procedure like another language, they are there.
i am looking for a way how to sort myArray in AHK
thanks

[IMEime]

Post Closed
"impossible"

[Helgef]

I'd like make it like this

Very easy with nnnik's nice sort function

Code: Select all

myArray := [[2, "Quick"]
, [4, "Brown"]
, [3, "Fox"]
, [1, "Jumps"]]	

sort myArray, (a, b) => a[1] < b[1] ? -1 : a[1] > b[1] ? 1 : 0


For Each, x In myArray
	myResult .= x[1] " " x[2] "`n"
MsgBox  myResult

And it is for v2

Cheers

[IMEime]

thanks
BUT
I am not interested in Version 2

Current line number is 48.000 for my main script only(it is a single file).
-and some lesser lines of scripts are a little bit more than hundred files.

I do not have any kind of Energy to change it into V2
Why do I have to ? Just to sort an Array ?

How about V3 in the near future or V4 ? no, no, no..

[john_c]

@IMEime There is a function here: https://sites.google.com/site/ahkref/custom-functions/sort2darray

Also, https://autohotkey.com/board/topic/12837-sort-2d-arrayfile/

[Chunjee]

Sorry, I guess, it is already somewhere else, but I can not find it easily.

I tested this with biga.ahk and it works: https://www.npmjs.com/package/biga.ahk

Code: Select all

A := new biga()
array := [[2, "Quick"]
, [4, "Brown"]
, [3, "Fox"]
, [1, "Jumps"]]

sortedArray := A.sortBy(array, 1)
msgbox, % A.print(sortedArray)
; => [[1, "Jumps"], [2, "Quick"], [3, "Fox"], [4, "Brown"]]

This works because the key of 1 is the order integer you have as the first element in the inner arrays.

I would recommend the following as easier to work with:

Code: Select all

array := [{"order": 2, "value": "Quick"}
, {"order": 4, "value": "Brown"}
, {"order": 3, "value": "Fox"}
, {"order": 1, "value": "Jumps"}]

in which case sorting by the key "order" is clearer like so: A.sortBy(array, "order")

[BartmanEH]

I tested this with biga.ahk and it works: https www.npmjs.com /package/biga.ahk Broken Link for safety

How does one install/use biga.ahk given that AHK is for Windowz and Windowz doesn't have npm installer (AFAIK... noob alert)

[Chunjee]

How does one install/use biga.ahk given that AHK is for Windowz and Windowz doesn't have npm installer (AFAIK... noob alert)

if you are not familiar with npm or don't have it installed. You may wish to download the library directly from github. All you need is export.ahk which you would #Incude as you would normally a class library.

[BartmanEH]

I would recommend the following as easier to work with:

Code: Select all

array := [{"order": 2, "value": "Quick"}
, {"order": 4, "value": "Brown"}
, {"order": 3, "value": "Fox"}
, {"order": 1, "value": "Jumps"}]

in which case sorting by the key "order" is clearer like so: A.sortBy(array, "order")

I am going to try this. Thanks for suggestion on how to use biga.ahk.

[BartmanEH]

if you are not familiar with npm or don't have it installed. You may wish to download the library directly from github. All you need is export.ahk Broken Link for safety which you would #Incude as you would normally a class library.

I have manually included export.ahk but the following array is not sorting:

Code: Select all

     Result_Array_Filtered := [{"distance": 10540, "Lat": 40.75423387, "Lon": -73.92452087, "target": "<trkpt lat=""40.75423387"" lon=""-73.92452087""><name>#001</name></trkpt>"}
    ,    {"distance": 47430, "Lat": 40.68004787, "Lon": -73.93168387, "target": "<trkpt lat=""40.68004787"" lon=""-73.93168387""><name>#002</name></trkpt>"}
    ,    {"distance": 1030, "Lat": 40.90804987, "Lon": -73.83052687, "target": "<trkpt lat=""40.90804987"" lon=""-73.83052687""><name>#003</name></trkpt>"}
    ,    {"distance": 3510, "Lat": 40.85642787, "Lon": -73.87724487, "target": "<trkpt lat=""40.85642787"" lon=""-73.87724487""><name>#004</name></trkpt>"}
    ,    {"distance": 144, "Lat": 40.71114687, "Lon": -73.77809887, "target": "<trkpt lat=""40.71114687"" lon=""-73.77809887""><name>#005</name></trkpt>"}]
    
    Result_Array_Filtered_Sorted := A.reverse(A.sortBy(Result_Array_Filtered, "distance"))

The new array is simply reversed but not sorted by Key “distance”—what am I missing?