How to display ResponseText in UTF-8 format? Topic is solved

[afe]

When whr.ResponseText contains UTF-8 text, garbled characters may be displayed.

I have read this post,
https://www.autohotkey.com/boards/viewtopic.php?f=5&t=16083

UrlDownloadToFile can be recognized correctly. Is there a solution for WinHttp?

For example,

Code: Select all

whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
whr.Open("GET", "https://ipmsg.org/protocol.txt", true)
whr.Send()
whr.WaitForResponse()
MsgBox % whr.ResponseText

[teadrinker]

Use ResponseBody instead of ResponseText:

Code: Select all

whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
whr.Open("GET", "https://ipmsg.org/protocol.txt", true)
whr.Send()
whr.WaitForResponse()
arr := whr.responseBody
pData := NumGet(ComObjValue(arr) + 8 + A_PtrSize)
length := arr.MaxIndex() + 1
MsgBox, % text := StrGet(pData, length, "utf-8")

[afe]

Wonderful!

Why to add 8 here?

Code: Select all

NumGet(ComObjValue(arr) + 8 + A_PtrSize)

Thank you very much!

[teadrinker]

Why to add 8 here?

ComObjValue(arr) returns the pointer to SAFEARRAY structure:



We need to get the pointer to pvData. USHORT + USHORT + ULONG = 8 bytes; the next USHORT = 4 bytes, but since pvData contains a pointer, it must be on the boundary, which is multiple of A_PtrSize, so instead of 4 we add A_PtrSize.

[afe]

Thank you very much!

[teadrinker]

USHORT + USHORT + ULONG = 8 bytes; the next USHORT = 4 bytes

There is a typo here, should be

USHORT + USHORT + ULONG = 8 bytes; the next ULONG = 4 bytes

[haichen]

And here is the code for AutoHotkey V2.

Code: Select all

whr := ComObject("WinHttp.WinHttpRequest.5.1")
whr.Open("GET", "http://some/url", true)
whr.Send()
whr.WaitForResponse()
arr := Whr.responseBody
pData := NumGet(ComObjValue(arr)+8 +A_PtrSize,0,"UPtr")
length := (arr.MaxIndex() - arr.MinIndex()) + 1
response := StrGet(pData,  "utf-8")

Hopefully correct.