Check Variable Contain Numbers/Letters Topic is solved

[snowmind]

Hi People

Can anyone give me a hint?I need to validate if a variable contains letters and numbers together. I tried something else didn't work

Code: Select all

Var=UDP4324

if (RegExMatch(Var, "i)[^A-Z ^0-9 ]"))
{
	MsgBox, OK
}
else
{
	MsgBox, NO
}

[jeeswg]

Cheers.

Code: Select all

;q:: ;check that string contains at least one number and at least one letter
Var=UDP4324
;Var=aaaaaaa
;Var=1111111
if RegExMatch(Var, "i)(?=.*[A-Z])(?=.*\d)")
;if RegExMatch(Var, "\d") && RegExMatch(Var, "[A-Za-z]") ;equivalent to line above
{
	MsgBox, OK
}
else
{
	MsgBox, NO
}
return

[snowmind]

Cheers.

Code: Select all

;q:: ;check that string contains at least one number and at least one letter
Var=UDP4324
;Var=aaaaaaa
;Var=1111111
if RegExMatch(Var, "i)(?=.*[A-Z])(?=.*\d)")
;if RegExMatch(Var, "\d") && RegExMatch(Var, "[A-Za-z]") ;equivalent to line above
{
	MsgBox, OK
}
else
{
	MsgBox, NO
}
return

really realy really thanksss

[teadrinker]

Another approach: RegExMatch(var, "i)\d[a-z]|[a-z]\d")

[ThumpieBunnyEve]

@teadrinker If var was "1,A+2.B" then your

Code: Select all

RegExMatch(var, "i)\d[a-z]|[a-z]\d")

version would report that there was not AlphaAndNumeric items in var.

[teadrinker]

I think the variable is supposed to contain only letters and numbers. If not, @jeeswg's code also can not always work:

Code: Select all

var := "a`r`n1"
MsgBox, % RegExMatch(Var, "i)(?=.*[A-Z])(?=.*\d)")

s option must be added.

[ThumpieBunnyEve]

so all one has to do is add s to cover the possibility of carriage-returns & line-breaks.

Would this function name be too long? i forget if there is a limit on function name length.

Code: Select all

StrHasLettersAndDigits(Var){
return RegExMatch(Var, "is)(?=.*[A-Z])(?=.*\d)")
}

This reports 1 if the string has at least 1 letter and 1 number. Even if the string searched has new lines in it "`r`n".

[teadrinker]

Would this function name be too long?

I don’t know anything about the permissible length of function names, but you can experiment:

Code: Select all

Loop 150
   str .= "a"

Func(str).Call()

aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa() {
   MsgBox, % StrLen(A_ThisFunc)
}

[Odlanir]

I don’t know anything about the permissible length of function names, but you can experiment:

After some experimenting seems 253. I think the total is 255 so 253 + the 2 parenthesis is equal to 255.

[teadrinker]

Yeah, my test:

Code: Select all

SetBatchLines, -1
Loop {
   funcName .= "a"
   ToolTip % i := A_Index
} until !ExecScript("#NoTrayIcon`n" . funcName . "()`n" . funcName . "() {`nFileAppend, t, *`n}")
MsgBox, % "Max function name length: " . --i

ExecScript(script)  {
   shell := ComObjCreate("WScript.Shell")
   exec := shell.Exec(A_AhkPath . " *")
   exec.StdIn.Write(script)
   exec.StdIn.Close()
   return exec.StdOut.ReadAll()
}

[swagfag]

Code: Select all

// -2 for the beginning and ending g_DerefChars:
#define MAX_VAR_NAME_LENGTH (UCHAR_MAX - 2)

in the variable case it says "line doesnt contain a recognized action". maybe it could be changed to refer to the length instead, same as in the function case?

[teadrinker]

Maybe, you could try

[swagfag]

i cant, no cpp knowledge