DllCall - SetWindowsHookEx - WH_SHELL

[DRocks]

Hey

I'm trying to replace the "SetWinEventHook" DllCall for "SetWindowsHookEx" to only register Top Window Creation events.

Reason:

Spoiler

I want to create a child GUI on top of a third party software with AHK.
How I am currently doing it is with the SetWinEventHook that looks for EVENT_OBJECT_CREATE
but I do not like the 300+ callbacks that happen regularly with this function.
Hence I am trying to register more precisely TOP WINDOW CREATION so that I can only create the AHK GUI when the desired third party window come to existance for the first time.

So I've checked for RegisterShellHookWindow and prefered SetWindowsHookEx because the first is mentionned to possibly stop working in later Window versions. Quote Microsoft:

Spoiler

[This function is not intended for general use. It may be altered or unavailable in subsequent versions of Windows.]
Many of the messages are the same as those that can be received after calling the SetWindowsHookEx function and specifying WH_SHELL for the hook type. The difference with RegisterShellHookWindow is that the messages are received through the specified window's WindowProc and not through a call back procedure.

Can you please help me make that DllCall so that SetWindowsHookEx actualy works.
Here is what I have so far - which isn't working:

Code: Select all

		; Refer to:
		; 	- https://docs.microsoft.com/fr-fr/windows/win32/api/winuser/nf-winuser-setwindowshookexa
		; 	- https://www.autohotkey.com/boards/viewtopic.php?t=18813
		;	- https://autohotkey.com/board/topic/71347-setwindowshookex-fails/
		;
		; Used Microsoft constants in this DllCall :
		;  	- WH_SHELL := 10
		;
		; PS: my system is a 64-bits process
		hWinEventHook := DllCall("SetWindowsHookEx"
			, "Int", 10	; idHook of type int := WH_SHELL := 10
			, "Ptr", RegisterCallback("OnWH_SHELL") ; lpfn of type HOOKPROC ???
			, "Ptr", 0 ; hmod of type HINSTANCE ???
			, "Ptr", ProcessID) ; dwThreadId of type DWORD ???
			
;--------------------------------------------------------------------------------
OnWM_SHELL(nCode, wParam, lParam) {
;--------------------------------------------------------------------------------
	
	; Handle Callbacks on Sage.exe ProcessID
	Tooltip %A_TickCount%`n%nCode%`n%wParam%`n%lParam%
	
}

For reference here's the working SetWinEventHook that I want to replace:

Spoiler

Code: Select all

		; Refer to: 
		;  	- https://autohotkey.com/boards/viewtopic.php?f=5&t=48911
		;  	- https://autohotkey.com/boards/viewtopic.php?f=76&t=57546&p=243839#p243839
		;  	- https://www.autohotkey.com/boards/viewtopic.php?t=830
		;  	- https://www.autohotkey.com/boards/viewtopic.php?f=6&t=59149
		;
		; Used Microsoft constants in this DllCall :
		;  	- EVENT_OBJECT_CREATE	  := 0x8000
		;  	- WINEVENT_OUTOFCONTEXT   := 0x0000
		;  	- WINEVENT_SKIPOWNPROCESS := 0x0002 
		/*
			hWinEventHook := DllCall("SetWinEventHook"
				,"UInt",0x8000										;  UINT eventMin							
				,"UInt",0x8000										;  UINT eventMax
				,"Ptr" ,0x0											;  HMODULE hmodWinEventProc
				,"Ptr" ,RegisterCallback("OnEVENT_OBJECT_CREATE")	;  WINEVENTPROC lpfnWinEventProc
				,"UInt",ProcessID									;  DWORD idProcess
				,"UInt",0x0											;  DWORD idThread
				,"UInt",0x0|0x2										;  UINT dwflags
				,"Ptr")									
		*/

For more reference here's the RegisterShellHookWindow that could work if SetWindowsHookEx doesn't:

Code: Select all

Gui +LastFound
DllCall("RegisterShellHookWindow", UInt, A_ScriptHwnd)
OnMessage(DllCall("RegisterWindowMessage", Str, "SHELLHOOK"), "On_WINDOWCREATED")

On_WINDOWCREATED(wParam, hwnd) {
	static HSHELL_WINDOWCREATED := 1
	static HSHELL_WINDOWACTIVATED := 4
	static HSHELL_RUDEAPPACTIVATED := 32772
	static index1
	static index2
	
	index1++
	if (wParam != HSHELL_WINDOWCREATED) ; only listen for this event
		return
	
	index2++
	WinGetActiveTitle, title
	Tooltip % title "`hwnd:"hwnd "`n"index1 "`n"index2
}

Thanks

[teadrinker]

Can you please help me make that DllCall so that SetWindowsHookExactualy works.

You can't use SetWindowsHookEx with WH_SHELL in pure AHK since the callback function must be placed in a dll in this case (if you want to monitor windows belonging to the external processes).

How I am currently doing it is with the SetWinEventHook that looks for EVENT_OBJECT_CREATE
but I do not like the 300+ callbacks that happen regularly with this function.

300+ callbacks won't happen, if you write the code properly. For example, MsgBox will appear only if the Notepad window is created:

Code: Select all

#Persistent
DetectHiddenWindows, On
EVENT_OBJECT_CREATE := 0x8000
hHook := SetWinEventHook( EVENT_OBJECT_CREATE, EVENT_OBJECT_CREATE, 0, RegisterCallback("HookProc", "F"), 0, 0, 0 )
OnExit( Func("FreeResource").Bind(hHook) )
Return

FreeResource(hHook) {
   DllCall("UnhookWindowsHookEx", "Ptr", hHook)
}

HookProc(hWinEventHook, event, hwnd, idObject, idChild, dwEventThread, dwmsEventTime)
{
   static OBJID_WINDOW := 0
   if (idObject != OBJID_WINDOW)
      Return
   WinGetClass, winClass, ahk_id %hwnd%
   if (winClass != "Notepad")
      Return
   MsgBox, 4096, % " ", Notepad window has been created!
}

SetWinEventHook(eventMin, eventMax, hmodWinEventProc, lpfnWinEventProc, idProcess, idThread, dwFlags)
{
   return DllCall("SetWinEventHook", "UInt", eventMin, "UInt", eventMax, "Ptr", hmodWinEventProc
                                   , "Ptr", lpfnWinEventProc, "UInt", idProcess, "UInt", idThread, "UInt", dwFlags, "Ptr")
}

[DRocks]

300+ callbacks won't happen, if you write the code properly. For example, MsgBox will appear only if the Notepad window is created:

Hey @teadrinker Thank you very much for your reply.
This has indeed helped reduce the number of callbacks that passthrough the "returns"
Thank you very much.

Side question: you have used the "Fast" keyword in your DllCall, why are you using it. What are the benefits?
I've tried it before and it seemed to miss some calls and was not properly trigerring the functions I needed to trigger inside the callback

Here's my sample

Code: Select all

;--------------------------------------------------------------------------------
OnEVENT_OBJECT_CREATE(hWinEventHook, event, hWnd, idObject) {
;--------------------------------------------------------------------------------
	
	; Handle Callbacks for = EVENT_OBJECT_CREATE (0x8000) on Sage.exe ProcessID
	static OBJID_WINDOW := 0
	static index
	
	if (idObject != OBJID_WINDOW)
		Return, 0
	
	WinGetClass, winClass, ahk_id %hWnd%
	if (!InStr(winClass , "WindowsForms10.Window.8.app.0."))
		Return, 0 ; only target Sage Top Window classes
	
	index++
	tooltip(index "`n" winClass)
	
	if ((!WinExist(Achats["hChildGui"])) and (hParent:=WinExist(WinTitles["Achats"]))) {
		CreateAchatsChildGui(hParent)
	}
}

I am still interested in the WindowsHookEx though but id does seem very complex.

[teadrinker]

Side question: you have used the "Fast" keyword in your DllCall, why are you using it. What are the benefits?

You could read about it here.
Perhaps, it this case it's safer not to use fast mode, although for me it doesn't cause any issues.

I am still interested in the WindowsHookEx though but id does seem very complex.

You need someone, who will write the dll for you in c++.

[DRocks]

hehe
the so awesome c++ (wish I would know that language)
Thanks for the help! it is already like 50% more efficient with your addition

[teadrinker]

You need someone, who will write the dll for you in c++

I found for you one person. For me his code works.

[DRocks]

I read through most it and it looks to be perfect !
Ill try it out. Thanks again @teadrinker - very nice of you