Add Multiple Data in Single ListView Topic is solved

[Spark]

hello all and good day,
I want to add multiple data in 1 list view but not working properly(Data1 on the left, Data2 on the right in 1 Row), any help will be appreciated.

here's my code so far

Code: Select all

Gui Add, ListView, x5 y5 w1000 h500, Data1|Data2

Loop,%A_Desktop%\*.*	; example
    LV_Add("",, A_LoopFileName)
Loop,%A_MyDocuments%\*.*	; example
    LV_Add("", A_LoopFileName)

LV_ModifyCol(1)  ; Data1
LV_ModifyCol(2)  ; Data2
Gui, Show
Return

GuiEscape:
GuiClose:
    ExitApp

Thank You

[just me]

Code: Select all

#NoEnv
Gui Add, ListView, x5 y5 w1000 h500, Data1|Data2
Loop,%A_Desktop%\*.*		; example Data1
   LV_Add("", A_LoopFileName)
Data1Rows := LV_GetCount()
Loop,%A_MyDocuments%\*.*	; example Data2
   If (A_Index <= Data1Rows)
      LV_Modify(A_Index, "Col2", A_LoopFileName)
   Else
      LV_Add("", , A_LoopFileName)
LV_ModifyCol(1)  ; Data1
LV_ModifyCol(2)  ; Data2
Gui, Show, , LV Test
Return

GuiEscape:
GuiClose:
ExitApp

[Odlanir]

Or, using an Array:

Code: Select all

Gui Add, ListView, x5 y5 w1000 h500, Data1|Data2
lst := []
Loop,%A_Desktop%\*.*		
   lst[A_Index,1] := A_LoopFileName
Loop,%A_MyDocuments%\*.* 
   lst[A_Index,2] := A_LoopFileName
Loop, % lst.MaxIndex() {
   LV_Add("",lst[A_Index]*)
}
LV_ModifyCol()
Gui, Show
Return

GuiEscape:
GuiClose:
ExitApp

[Spark]

@just me and @Odlanir

Thank you very much, all your code works very well