Does Edit box can be append text?

[Bral]

append text to the end of text box, like FileAppend, and always show last line.

[flyingDman]

try this:

Code: Select all

var := "some text"

gui, add, edit, x0 y0 w200 h200 vtxt, % var
gui, add, button, x0 y+5 gadd, add some more
gui, show
return

add:
gui, submit, nohide
txt .= " and some more"
guicontrol,, txt, %txt% 
guicontrol,focus,txt
send, ^{end}
return

[teadrinker]

Or like this:

Code: Select all

text := " add some more"

Gui, Add, Edit, w200 h200 hwndhEdit
Gui, Add, Button, xp y+5, Add Text
handler := Func("AppendText").Bind(text, hEdit)
GuiControl, +g, Button1, % handler
Gui, Show
Return

AppendText(text, hEdit) {
   static WM_GETTEXTLENGTH := 0x0E
        , EM_SETSEL        := 0xB1
        , EM_REPLACESEL    := 0xC2
   WinWait, ahk_id %hEdit%
   SendMessage, WM_GETTEXTLENGTH
   SendMessage, EM_SETSEL, ErrorLevel, ErrorLevel
   SendMessage, EM_REPLACESEL, true, &text
}

[Bral]

Or like this:

Code: Select all

text := " add some more"

Gui, Add, Edit, w200 h200 hwndhEdit
Gui, Add, Button, xp y+5, Add Text
handler := Func("AppendText").Bind(text, hEdit)
GuiControl, +g, Button1, % handler
Gui, Show
Return

AppendText(text, hEdit) {
   static WM_GETTEXTLENGTH := 0x0E
        , EM_SETSEL        := 0xB1
        , EM_REPLACESEL    := 0xC2
   WinWait, ahk_id %hEdit%
   SendMessage, WM_GETTEXTLENGTH
   SendMessage, EM_SETSEL, ErrorLevel, ErrorLevel
   SendMessage, EM_REPLACESEL, true, &text
}

Thank you very much, this is I need code.

[Bral]

try this:

Code: Select all

var := "some text"

gui, add, edit, x0 y0 w200 h200 vtxt, % var
gui, add, button, x0 y+5 gadd, add some more
gui, show
return

add:
gui, submit, nohide
txt .= " and some more"
guicontrol,, txt, %txt% 
guicontrol,focus,txt
send, ^{end}
return

This code is not the best, because it is reload all text every time, text box will flash 0.0001 secend :p

[flyingDman]

Add:

Code: Select all

#\::
a := A_TickCount
loop,100
	ControlClick, Button1, A,,,1
MsgBox, % A_TickCount - a    	
return

to both scripts. @teadrinker 's version will take about 12.5 seconds to complete adding 100 small strings of text. My simple script does it in 3.125 seconds. @Bral, the 0.0001 second flash (btw it does not flash here...) is insignificant compared to these numbers.
@teadrinker : nice script; I learned something new.

[teadrinker]

@flyingDman
I'm not sure that your test is correct. Try this:

Code: Select all

text := " add some more"

Gui, Add, Edit, w200 h200 hwndhEdit
Gui, Add, Button, xp y+5, Add Text
handler := Func("AppendText").Bind(text, hEdit)
GuiControl, +g, Button1, % handler
Gui, Show
Return

AppendText(text, hEdit) {
   static WM_GETTEXTLENGTH := 0x0E
        , EM_SETSEL        := 0xB1
        , EM_REPLACESEL    := 0xC2
   start := A_TickCount
   WinWait, ahk_id %hEdit%
   Loop 100 {
      SendMessage, WM_GETTEXTLENGTH
      SendMessage, EM_SETSEL, ErrorLevel, ErrorLevel
      SendMessage, EM_REPLACESEL, true, &text
   }
   MsgBox, % A_TickCount - start
}

Or this:

Code: Select all

text := " add some more"

Gui, Add, Edit, w200 h200 hwndhEdit
Gui, Add, Button, xp y+5, Add Text
handler := Func("AppendText").Bind(text, hEdit)
GuiControl, +g, Button1, % handler
Gui, Show
Return

AppendText(text, hEdit) {
   static WM_GETTEXTLENGTH := 0x0E
        , EM_SETSEL        := 0xB1
        , EM_REPLACESEL    := 0xC2
   start := A_TickCount
   Loop 100 {
      SendMessage, WM_GETTEXTLENGTH,,,, ahk_id %hEdit%
      SendMessage, EM_SETSEL, ErrorLevel, ErrorLevel,, ahk_id %hEdit%
      SendMessage, EM_REPLACESEL, true, &text,, ahk_id %hEdit%
   }
   MsgBox, % A_TickCount - start
}

WinWait was here just to shorten the code.

[flyingDman]

I think my test more accurately simulate the process of manually adding by clicking the button. I noticed the difference in speed when i was clicking myself. It felt sluggish.
But to make it an apple to apple comparison:

Code: Select all

gui, add, edit, w200 h200 vtxt,
gui, add, button, y+5 gadd, add some more
gui, show
return

add:
a := A_TickCount
gui, submit, nohide
Loop, 100
	{
	txt .= " add some more"
	guicontrol,, txt, %txt% 
	}
guicontrol,focus,txt
send, ^{end}
MsgBox, % A_TickCount - a    	
return

will result is very similar times. Mine minimally slower. But I don't want to make this a p... contest. Your code shows an impressive way of doing this.

[teadrinker]

Try your test several times without removing an existing text.

[Bral]

Try your test several times without removing an existing text.

I tested add 1000 times, your code is faster, But i don't know why need WM_GETTEXTLENGTH and EM_SETSEL? i delete that 2 line and code work fine.

[teadrinker]

It may work without these commands only if the caret is located at the end of the text.
WM_GETTEXTLENGTH gets the text length, EM_SETSEL sets the caret at the end, EM_REPLACESEL inserts the text at the caret position.

[just me]

GuiEditAppend() ?

[teadrinker]

@just me
Interesting idea about SendMessage, 0x00B1, -2, -1, but it doesn't speed up the code.