Help with InStr() always finding/not finding string Topic is solved

[Dystopia]

Hello, I'm trying to lock a script to a mac address (just trying as a small project of mine), and I've sort of hit a roadblock.

The code I have now is this:

Code: Select all

GetMacAddress(){
    tempfile = %A_Temp%\mac.txt
    RunWait, %ComSpec% /c getmac /NH > %tempfile%, , Hide ; ipconfig (slow)
    FileRead, mac, %tempfile%
	MsgBox, %mac%
}

GetMacAddress()

Password = "<Mac address>"
MsgBox, %Password%

If (InStr(mac, Password) > 0){
	MsgBox, found
}
Else {
	ExitApp
}

However, this code always returns false and exits the app. I've tried a number of different codes that should effectively be the same, such as directly placing the mac address as a literal string within InStr(), flipping the needle and haystack around (not sure why, but this always results in a positive, whether I enclosed each in % or not), and basically every thing I could think of that may have been preventing it from working. Any help is appreciated!

[SKAN]

This should work:

Code: Select all

GetMacAddress() {
Local
    tempfile := A_Temp . "\mac.txt"
    RunWait, %ComSpec% /c getmac /NH > %tempfile%,, Hide ; ipconfig (slow)
    FileRead, mac, %tempfile%
Return mac
}

mac      := GetMacAddress()
Password := "<Mac address>"

If InStr(mac, Password) {
	MsgBox, found
}
Else {
  MsgBox, not found
	ExitApp
}

[Xtra]

The var mac is not global and not accessible outside the function. (use return mac or use byref )
Give this a try (set password to match what you expect of course.)

Code: Select all

#NoEnv
#SingleInstance, Force
SetWorkingDir %A_ScriptDir%

GetMacAddress(mac)
MsgBox,,mac, %mac%

Password = "<Mac address>"
MsgBox,,Password, %Password%

If (InStr(mac, Password) > 0){
	MsgBox, found
}
Else {
	ExitApp
}

GetMacAddress(ByRef mac){
    tempfile = %A_Temp%\mac.txt
    RunWait, %ComSpec% /c getmac /NH > %tempfile%, , Hide ; ipconfig (slow)
    FileRead, mac, %tempfile%
}

[Dystopia]

Thanks, both of you! Wasn't expecting a response so quickly, and it's working perfectly now. Didn't know that variables declared within a function was only local, but now I do