File text array to actual array? Topic is solved

[jkmgme]

Is it at all possible to make an array from an array structure in a text file?

example.txt includes:

Code: Select all

[{"container":{"spec1":"this is spec 1", "spec2":"this is spec2"}}]

Code: Select all

FileRead, exampleFile, ../example.txt
MsgBox % exampleFile

Is there any way I can use exampleFile variable as an array via conversion or some of the sort??

[aifritz]

Interesting question, but seems to be not so easy in a few lines...
I've found this old threadhttps://autohotkey.com/board/topic/104854-string-object-file-data-structures-in-yaml-like-style/

May be there is a more actual one

[aifritz]

Here another one, concerning this topic
https://www.autohotkey.com/boards/viewtopic.php?f=76&t=49997&p=221962&hilit=Yaml#p221962

[gregster]

Since this looks like a JSON-formatted string, I would use Coco's Jxon_Load() function: https://www.autohotkey.com/boards/viewtopic.php?t=627 or use his JSON class (see same post). Here is the Jxon_Load() version:

Code: Select all

Fileread, var, example.txt
msgbox % var						; var contains a string
obj := Jxon_load(var)				; Jxon_Load loads the string into an AHK object
msgbox % obj[1].container.spec1 " , but " obj[1].container.spec2	

; Coco's Jxon_Load function: https://github.com/cocobelgica/AutoHotkey-JSON/blob/master/Jxon.ahk
Jxon_Load(ByRef src, args*)
{
	static q := Chr(34)

	key := "", is_key := false
	stack := [ tree := [] ]
	is_arr := { (tree): 1 }
	next := q . "{[01234567890-tfn"
	pos := 0
	while ( (ch := SubStr(src, ++pos, 1)) != "" )
	{
		if InStr(" `t`n`r", ch)
			continue
		if !InStr(next, ch, true)
		{
			ln := ObjLength(StrSplit(SubStr(src, 1, pos), "`n"))
			col := pos - InStr(src, "`n",, -(StrLen(src)-pos+1))

			msg := Format("{}: line {} col {} (char {})"
			,   (next == "")      ? ["Extra data", ch := SubStr(src, pos)][1]
			  : (next == "'")     ? "Unterminated string starting at"
			  : (next == "\")     ? "Invalid \escape"
			  : (next == ":")     ? "Expecting ':' delimiter"
			  : (next == q)       ? "Expecting object key enclosed in double quotes"
			  : (next == q . "}") ? "Expecting object key enclosed in double quotes or object closing '}'"
			  : (next == ",}")    ? "Expecting ',' delimiter or object closing '}'"
			  : (next == ",]")    ? "Expecting ',' delimiter or array closing ']'"
			  : [ "Expecting JSON value(string, number, [true, false, null], object or array)"
			    , ch := SubStr(src, pos, (SubStr(src, pos)~="[\]\},\s]|$")-1) ][1]
			, ln, col, pos)

			throw Exception(msg, -1, ch)
		}

		is_array := is_arr[obj := stack[1]]

		if i := InStr("{[", ch)
		{
			val := (proto := args[i]) ? new proto : {}
			is_array? ObjPush(obj, val) : obj[key] := val
			ObjInsertAt(stack, 1, val)
			
			is_arr[val] := !(is_key := ch == "{")
			next := q . (is_key ? "}" : "{[]0123456789-tfn")
		}

		else if InStr("}]", ch)
		{
			ObjRemoveAt(stack, 1)
			next := stack[1]==tree ? "" : is_arr[stack[1]] ? ",]" : ",}"
		}

		else if InStr(",:", ch)
		{
			is_key := (!is_array && ch == ",")
			next := is_key ? q : q . "{[0123456789-tfn"
		}

		else ; string | number | true | false | null
		{
			if (ch == q) ; string
			{
				i := pos
				while i := InStr(src, q,, i+1)
				{
					val := StrReplace(SubStr(src, pos+1, i-pos-1), "\\", "\u005C")
					static end := A_AhkVersion<"2" ? 0 : -1
					if (SubStr(val, end) != "\")
						break
				}
				if !i ? (pos--, next := "'") : 0
					continue

				pos := i ; update pos

				  val := StrReplace(val,    "\/",  "/")
				, val := StrReplace(val, "\" . q,    q)
				, val := StrReplace(val,    "\b", "`b")
				, val := StrReplace(val,    "\f", "`f")
				, val := StrReplace(val,    "\n", "`n")
				, val := StrReplace(val,    "\r", "`r")
				, val := StrReplace(val,    "\t", "`t")

				i := 0
				while i := InStr(val, "\",, i+1)
				{
					if (SubStr(val, i+1, 1) != "u") ? (pos -= StrLen(SubStr(val, i)), next := "\") : 0
						continue 2

					; \uXXXX - JSON unicode escape sequence
					xxxx := Abs("0x" . SubStr(val, i+2, 4))
					if (A_IsUnicode || xxxx < 0x100)
						val := SubStr(val, 1, i-1) . Chr(xxxx) . SubStr(val, i+6)
				}

				if is_key
				{
					key := val, next := ":"
					continue
				}
			}

			else ; number | true | false | null
			{
				val := SubStr(src, pos, i := RegExMatch(src, "[\]\},\s]|$",, pos)-pos)
			
			; For numerical values, numerify integers and keep floats as is.
			; I'm not yet sure if I should numerify floats in v2.0-a ...
				static number := "number", integer := "integer"
				if val is %number%
				{
					if val is %integer%
						val += 0
				}
			; in v1.1, true,false,A_PtrSize,A_IsUnicode,A_Index,A_EventInfo,
			; SOMETIMES return strings due to certain optimizations. Since it
			; is just 'SOMETIMES', numerify to be consistent w/ v2.0-a
				else if (val == "true" || val == "false")
					val := %value% + 0
			; AHK_H has built-in null, can't do 'val := %value%' where value == "null"
			; as it would raise an exception in AHK_H(overriding built-in var)
				else if (val == "null")
					val := ""
			; any other values are invalid, continue to trigger error
				else if (pos--, next := "#")
					continue
				
				pos += i-1
			}
			
			is_array? ObjPush(obj, val) : obj[key] := val
			next := obj==tree ? "" : is_array ? ",]" : ",}"
		}
	}

	return tree[1]
}

Sure, a lot of code, but usually this is not a one-time operation . To reverse this (AHK object to JSON string) there is also the Jxon_Dump() function (or the class equivalent).

But yeah, there are also similar implementations on the forum, like aifritz pointed out. You could also make use of javascript, like teadrinker demonstrated and discussed here with others: https://www.autohotkey.com/boards/viewtopic.php?f=76&t=65631

[teadrinker]

Another approach:

Code: Select all

JSON = [{"container":{"spec1":"this is spec 1", "spec2":"this is spec2"}}]
arr := JsonToAhkObj(JSON)
MsgBox, % arr[1].container.spec2

JsonToAhkObj(json, flag := "") {
   static doc, JS := JsonToAhkObj("")
   if (json = "") {
      doc := ComObjCreate("htmlfile")
      doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
      JS := doc.parentWindow
      JScript =
      (
         Object.prototype.GetKeys = function () {
            var keys = []
            for (var k in this)
               if (this.hasOwnProperty(k))
                  keys.push(k)
            return keys
         }
         Object.prototype.IsArray = function () {
            var toStandardString = {}.toString
            return toStandardString.call(this) == '[object Array]'
         }
      )
      JS.eval.(JScript)
      Return JS
   }
   else if !flag {
      try jsObj := JS.eval("(" json ")")
      catch {
         MsgBox, Wrong JSON string:`n`n%json%
         Return
      }
      Return JsonToAhkObj(jsObj, true)
   }
   else {
      res := json.IsArray()
      if (res = "")
         Return json
      else if (res = -1) {
         obj := []
         Loop % json.length
            obj[A_Index] := JsonToAhkObj(json[A_Index - 1], true)
      }
      else if (res = 0) {
         obj := {}
         keys := json.GetKeys()
         Loop % keys.length
            k := keys[A_Index - 1], obj[k] := JsonToAhkObj(json[k], true)
      }
      Return obj
   }
}

[rommmcek]

@teadrinker: Isn't there a bug/typo/pasteEror? For me doesn't work for "flat" (non associative) arrays. Don't know Java, but I guess the condition should check for Object not for String... Could you take a look please!

Spoiler

Run script, Esc: next exemp, ^Esc or Close Gui: Exit script.

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

Gui add, Edit, w500 h500 vEdt T.5
Gui show

JSON = [{"container":{"spec1":"this is spec 1", "spec2":"this is spec 2"}}]

arr := JsonToAhkObj(JSON)
GuiControl,, Edt, % txtArr(arr)
;GuiControl,, Edt, % prnArr(arr)
KeyWait Esc, D
KeyWait Esc

;============================================================

json=
(
[[["schlank","slim",null,null,2]
,[null,null,null,"slim"]
]
,[["adjective",["schlank","schmal","gering"]
,[["schlank",["slim","slender"]
,null,0.10874496]
,["schmal",["narrow","small","slim","thin","slender","lean"]
,null,0.020754337]
,["gering",["low","small","slight","little","minor","slim"]
,null,0.009354713]
]
,"slim",3]
,["verb",["schrumpfen","schlank machen"]
,[["schrumpfen",["shrink","shrivel","dwindle","atrophy","slim","depreciate"]
,null,7.722788E-5]
,["schlank machen",["slim","slenderize"]
,null,7.485183E-5]
]
,"slim",2]
]
,"en",null,null,[["slim",null,[["schlank",1000,true,false]
]
,[[0,4]
]
,"slim",0,0]
]
,0.86985385,[]
,[["en"]
,null,[0.86985385]
,["en"]
]
,null,null,[["verb",[[["lose weight","get thinner","lose/shed some pounds","lose some inches","get into shape","shape up","reduce","diet","go on a diet","slenderize"]
,"m_en_gbus0955300.022"]
,[["reduce","cut","cut down/back","make cutbacks in","scale down","trim","decrease","diminish","pare down","whittle away","prune","rationalize","downsize"]
,"m_en_gbus0955300.029"]
]
,"slim"]
,["adjective",[[["narrow","slender","slimline"]
,"m_en_gbus0955300.012"]
,[["slender","lean","willowy","sylphlike","svelte","lissom","graceful","snake-hipped","rangy","clean-limbed","trim","slight","slightly built","thin","as thin as a reed","skinny","size-zero","spare","attenuated","lanky","spindly"]
,"m_en_gbus0955300.008"]
,[["gracile","attenuate"]
,"m_en_gbus0955300.008"]
,[["slight","small","slender","faint","feeble","poor","flimsy","tenuous","fragile","negligible","marginal","minimal","outside","remote","distant","unlikely","improbable"]
,"m_en_gbus0955300.016"]
]
,"slim"]
]
,[["verb",[["make oneself thinner, especially by dieting.","m_en_gbus0955300.022","I need to slim down a bit"]
]
,"slim"]
,["adjective",[["(of a person or their build) gracefully thin; slenderly built (used approvingly).","m_en_gbus0955300.008","her slim figure"]
,["(of something abstract, especially a chance or margin) very small.","m_en_gbus0955300.016","there was just a slim chance of success"]
]
,"slim"]
,["noun",[["a course or period of slimming.","m_en_gbus0955300.032","a sponsored slim"]
,["a term used in parts of Africa to refer to AIDS.","m_en_gbus0955300.035"]
]
,"slim"]
]
,[[["the evidence is \u003cb\u003eslim\u003c/b\u003e",null,null,null,3,"m_en_gbus0955300.016"]
,["the girls were tall and \u003cb\u003eslim\u003c/b\u003e",null,null,null,3,"m_en_gbus0955300.008"]
,["a pair of \u003cb\u003eslim\u003c/b\u003e, immaculately cut slacks",null,null,null,3,"m_en_gbus0955300.013"]
,["her \u003cb\u003eslim\u003c/b\u003e figure",null,null,null,3,"m_en_gbus0955300.008"]
,["I need to \u003cb\u003eslim\u003c/b\u003e down a bit",null,null,null,3,"m_en_gbus0955300.022"]
,["a sponsored \u003cb\u003eslim\u003c/b\u003e",null,null,null,3,"m_en_gbus0955300.032"]
,["how can I \u003cb\u003eslim\u003c/b\u003e down my hips?",null,null,null,3,"m_en_gbus0955300.028"]
,["there was just a \u003cb\u003eslim\u003c/b\u003e chance of success",null,null,null,3,"m_en_gbus0955300.016"]
,["a \u003cb\u003eslim\u003c/b\u003e gold band encircled her wrist",null,null,null,3,"m_en_gbus0955300.012"]
]
]
]
)

arr := JsonToAhkObj(JSON)
GuiControl,, Edt, % txtArr(arr)
KeyWait Esc, D
KeyWait Esc
;============================================================

json= 
(
[[["schlank os gut","slim os good",null,null,3,null,null,[[],[]],[[["1814a2c300f02f227bcb04312cd2671a","tea_pt_en_2019q4.md"]]
,[["4d5e201a34474a12730540dc3bfae9fd","tea_en_de_2020q1.md"]]]]]
,null,"pt",null,null,[["slim os good",null,[["schlank os gut",0,true,false]]
,[[0,12]],"slim os good",0,0]],0.6054487,[],[["pt"],null,[0.6054487],["pt"]]]
)

arr := JsonToAhkObj(JSON)
GuiControl,, Edt, % txtArr(arr)
;GuiControl,, Edt, % prnArr(arr)
KeyWait Esc, D
KeyWait Esc
;============================================================

json=
(
[[["英語","English",null,null,2]
,[null,null,"Eigo","ˈiNG(ɡ)liSH"]
]
,[["noun",["英語","英国人"]
,[["英語",["English","English language"]
,null,0.47980523]
,["英国人",["English","Englishman"]
]
]
,"English",1]
,["adjective",["英国の","英語の"]
,[["英国の",["English","British"]
]
,["英語の",["English"]
]
]
,"English",3]
]
,"en",null,null,[["English",null,[["英語",1000,true,false]
]
,[[0,7]
]
,"English",0,0]
]
,1.0,[]
,[["en"]
,null,[1.0]
,["en"]
]
,null,null,null,[["adjective",[["relating to England or its people or language.","m_en_gbus0324780.005"]
]
,"English"]
,["noun",[["the language of England, widely used in many varieties throughout the world.","m_en_gbus0324780.010"]
,["the people of England.","m_en_gbus0324780.014"]
]
,"English"]
]
,[[["an \u003cb\u003eEnglish\u003c/b\u003e book",null,null,null,3,"neid_6195"]
,["her \u003cb\u003eEnglish\u003c/b\u003e is very good",null,null,null,3,"neid_6197"]
,["put that into \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["how do you say that in \u003cb\u003eEnglish\u003c/b\u003e?",null,null,null,3,"neid_6197"]
,["he's doing \u003cb\u003eEnglish\u003c/b\u003e at university",null,null,null,3,"neid_6197"]
,["say that in \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["she's \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6196"]
,["he speaks \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["\u003cb\u003eEnglish\u003c/b\u003e class",null,null,null,3,"neid_6195"]
,["\u003cb\u003eEnglish\u003c/b\u003e dictionary",null,null,null,3,"neid_6195"]
,["the \u003cb\u003eEnglish\u003c/b\u003e language",null,null,null,3,"neid_6195"]
,["\u003cb\u003eEnglish\u003c/b\u003e teacher",null,null,null,3,"neid_6195"]
,["they're speaking \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["what's the \u003cb\u003eEnglish\u003c/b\u003e for 'bia'?",null,null,null,3,"neid_6197"]
,["a film in \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["an \u003cb\u003eEnglish\u003c/b\u003e word",null,null,null,3,"neid_6195"]
,["she has a degree in \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["\u003cb\u003eEnglish\u003c/b\u003e exam",null,null,null,3,"neid_6195"]
]
]
]
)

arr := JsonToAhkObj(JSON)
GuiControl,, Edt, % txtArr(arr)
;GuiControl,, Edt, % prnArr(arr)

Return

GuiClose:
  ^Esc:: ExitApp

JsonToAhkObj(json, flag := "") {
   static doc, JS := JsonToAhkObj("")
   ;if (json = "") { ; /
   ;if !IsObject(Js.json) { ; \/
   if !Js.json { ; \/
      doc := ComObjCreate("htmlfile")
      doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
      JS := doc.parentWindow
      JScript =
      (
         Object.prototype.GetKeys = function () {
            var keys = []
            for (var k in this)
               if (this.hasOwnProperty(k))
                  keys.push(k)
            return keys
         }
         Object.prototype.IsArray = function () {
            var toStandardString = {}.toString
            return toStandardString.call(this) == '[object Array]'
         }
      )
      JS.eval.(JScript)
      Return JS
   }
   else if !flag {
      try jsObj := JS.eval("(" json ")")
      catch {
         MsgBox, Wrong JSON string:`n`n%json%
         Return
      }
      Return JsonToAhkObj(jsObj, true)
   }
   else {
      try res := json.IsArray()
      if (res = "")
         Return json
      else if (res = -1) {
         obj := []
         Loop % json.length
            obj[A_Index] := JsonToAhkObj(json[A_Index - 1], true)
      }
      else if (res = 0) {
         obj := {} ; \/
         ;obj := [] ; \/
         keys := json.GetKeys()
         Loop % keys.length
            k := keys[A_Index - 1], obj[k] := JsonToAhkObj(json[k], true)
      }
      Return obj
   }
}

txtArr(r, i:="   ", d:=0, b:="") { ; by RRR inspired by unknown's ArrayToText & SKAN's condensation
	try For k, v in r
		c.= IsObject(v)? b k ":`n" txtArr(v, i, d+1, b i): b k ": " v "`n", d>0? "": t:=c
    Return d>0? c: t
}

prnArr(r, i:="   ", d:=50, b:="") { ; by RRR inspired by tidbit's st_printArr & SKAN's condensation
    try for k, v in r
        l.= b k ": ", (IsObject(v) && d>1)? l.=(t:=prnArr(v, i, d-1, b i))? "`n" t: "": l.=v, l.= "`n"
    return RTrim(l, "`n")
}

/* Original ArrayToText() function. To anybody: Please post the link if you happen to know it.
; -----
; This silly little function just makes a 2D hierarchical layout of
; an associative array, similar to a tree view.  So you can see the
; before and after when playing with XML conversion.  If all goes
; well, the first and second breakdown should be identical, showing
; that you can save an associative array of any structure or depth
; to XML and load it with the corresponding 1-liner functions.
; -----
ArrayToText(array,depth:=0) {
	tabs := ""
	If (depth > 0)
		Loop % depth ; AHKv2 = Loop depth   /   AHKv1 = Loop % depth
			tabs .= "`t"
		
	For k, v in array {
		If (IsObject(v))
			curIt .= tabs . k . "`n" . ArrayToText(v,depth+1)
		Else
			curIt .= tabs . k . " = " . v . "`r`n"
		
		If (depth = 0)
			outText := curIt
	}
	
	If (depth = 0)
		return outText
	Else
		return curIt
}

[teadrinker]

Isn't there a bug/typo/pasteEror?

Can you provide a more simple example to demonstrate an error?
Anyway, the current version of JsonToAhk() is

Code: Select all

JsonToAHK(json, rec := false) {
   static doc := ComObjCreate("htmlfile")
         , __ := doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
         , JS := doc.parentWindow
   if !rec
      obj := %A_ThisFunc%(JS.eval("(" . json . ")"), true)
   else if !IsObject(json)
      obj := json
   else if JS.Object.prototype.toString.call(json) == "[object Array]" {
      obj := []
      Loop % json.length
         obj.Push( %A_ThisFunc%(json[A_Index - 1], true) )
   }
   else {
      obj := {}
      keys := JS.Object.keys(json)
      Loop % keys.length {
         k := keys[A_Index - 1]
         obj[k] := %A_ThisFunc%(json[k], true)
      }
   }
   Return obj
}

[rommmcek]

Now you have new function. Doesn't work neither, except does not throw an error.

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

JSON = [{"container":{"spec1":"this is spec 1", "spec2":"this is spec2"}}]
arr := JsonToAhkObj(JSON)
MsgBox, % arr[1].container.spec2

json= [[["schlank os gut","slim os good",null,null,3,null,null,[[],[]],[[["1814a2c300f02f227bcb04312cd2671a","tea_pt_en_2019q4.md"]],[["4d5e201a34474a12730540dc3bfae9fd","tea_en_de_2020q1.md"]]]]],null,"pt",null,null,[["slim os good",null,[["schlank os gut",0,true,false]],[[0,12]],"slim os good",0,0]],0.6054487,[],[["pt"],null,[0.6054487],["pt"]]]
arr := JsonToAhkObj(JSON)
MsgBox, % arr.1.1.1

JsonToAhkObj(json, flag := "") {
   static doc, JS := JsonToAhkObj("")
   if (json = "") {
      doc := ComObjCreate("htmlfile")
      doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
      JS := doc.parentWindow
      JScript =
      (
         Object.prototype.GetKeys = function () {
            var keys = []
            for (var k in this)
               if (this.hasOwnProperty(k))
                  keys.push(k)
            return keys
         }
         Object.prototype.IsArray = function () {
            var toStandardString = {}.toString
            return toStandardString.call(this) == '[object Array]'
         }
      )
      JS.eval.(JScript)
      Return JS
   }
   else if !flag {
      try jsObj := JS.eval("(" json ")")
      catch {
         MsgBox, Wrong JSON string:`n`n%json%
         Return
      }
      Return JsonToAhkObj(jsObj, true)
   }
   else {
      res := json.IsArray()
      if (res = "")
         Return json
      else if (res = -1) {
         obj := []
         Loop % json.length
            obj[A_Index] := JsonToAhkObj(json[A_Index - 1], true)
      }
      else if (res = 0) {
         obj := {}
         keys := json.GetKeys()
         Loop % keys.length
            k := keys[A_Index - 1], obj[k] := JsonToAhkObj(json[k], true)
      }
      Return obj
   }
}

[Edit]: Sorry the new function works!

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

JSON = [{"container":{"spec1":"this is spec 1", "spec2":"this is spec2"}}]
arr := JsonToAhk(JSON)
MsgBox, % arr[1].container.spec2

json= [[["schlank os gut","slim os good",null,null,3,null,null,[[],[]],[[["1814a2c300f02f227bcb04312cd2671a","tea_pt_en_2019q4.md"]],[["4d5e201a34474a12730540dc3bfae9fd","tea_en_de_2020q1.md"]]]]],null,"pt",null,null,[["slim os good",null,[["schlank os gut",0,true,false]],[[0,12]],"slim os good",0,0]],0.6054487,[],[["pt"],null,[0.6054487],["pt"]]]
arr := JsonToAhk(JSON)
MsgBox, % arr.1.1.1

JsonToAHK(json, rec := false) {
   static doc := ComObjCreate("htmlfile")
         , __ := doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
         , JS := doc.parentWindow
   if !rec
      obj := %A_ThisFunc%(JS.eval("(" . json . ")"), true)
   else if !IsObject(json)
      obj := json
   else if JS.Object.prototype.toString.call(json) == "[object Array]" {
      obj := []
      Loop % json.length
         obj.Push( %A_ThisFunc%(json[A_Index - 1], true) )
   }
   else {
      obj := {}
      keys := JS.Object.keys(json)
      Loop % keys.length {
         k := keys[A_Index - 1]
         obj[k] := %A_ThisFunc%(json[k], true)
      }
   }
   Return obj
}

Thanks!