Get the height / width of an image - to an array (object) Topic is solved

[Albireo]

Intending to display an image with a AHK-GUI
Since I do not know how to scale an image with AHK GUI (I think it's impossible), I need to know the width and height of the image to be displayed to get structure on the entire GUI.

One way to get the size is to use IrfanView - Command line
Another way is to use gdip_all
Maybe there are better ways to do this on?

My wish is to create an object (selLogo) that contains information about the image. (eg. selLogo.name, selLogo.width, selLogo.height ...)
Tried to write a program below, but failed (in a way)
(selLogo is changed after the function call getImageSize(selLogo.name) and the selLogo.name is gone!)

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance force

#include gdip_all.ahk  ;  If it is not in your lib http://www.autohotkey.com/forum/topic32238.html

selLogo := []

FileSelectFile Logo, 3, C:\Users...\images, Select a imagefile, Images (*.jpg)
selLogo.name := Logo

selLogo := getImageSize(selLogo.name)
MsgBox ,, %A_ScriptName% - Row %A_LineNumber%, % "- " selLogo.Count() "`n- " selLogo.name "`n`nheight .: " selLogo.height "`nwidth .: " selLogo.width

ExitApp

getImageSize(imageFile)
{	; https://autohotkey.com/board/topic/61076-get-image-height-property-from-file-property-details/
	; lib .: gdip_all.ahk
	aImage := []
	
	If !pToken := Gdip_Startup()
	{	MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
		ExitApp
	}
	
	pBitmap := Gdip_CreateBitmapFromFile(imageFile)
	Gdip_GetDimensions(pBitmap, width, height)
	Gdip_DisposeImage(pBitmap)
	Gdip_Shutdown(pToken)
	
	aImage.width := width
	aImage.height := height

	Return % aImage
}

[mikeyww]

GUI does scale. You can specify one dimension, and it will adjust the other.

To shrink or enlarge the image while preserving its aspect ratio, specify -1 for one of the dimensions and a positive number for the other. For example, specifying w200 h-1 would make the image 200 pixels wide and cause its height to be set automatically.

A little trick to find an image's size is below.

Code: Select all

imgWidth(img, ByRef height) { ; Get image's dimensions
 If FileExist(img) {
  GUI, Add, Picture, hwndpic, %img%
  ControlGetPos,,, width, height,, ahk_id %pic%
  Gui, Destroy
 } Else height := width := 0
 Return width
}

[teadrinker]

Code: Select all

filePath := "D:\MyImage.jpg"
size := GetImageSize(filePath)
MsgBox, % size.W . "`n" size.H

GetImageSize(imageFilePath) {
   if !hBitmap := LoadPicture(imageFilePath, "GDI+")
      throw "Failed to load the image"
   VarSetCapacity(BITMAP, size := 4*4 + A_PtrSize*2, 0)
   DllCall("GetObject", "Ptr", hBitmap, "Int", size, "Ptr", &BITMAP)
   DllCall("DeleteObject", "Ptr", hBitmap)
   Return { W: NumGet(BITMAP, 4, "UInt"), H: NumGet(BITMAP, 8, "UInt") }
}

[mikeyww]

Very nice as well! It's handy to have the dimensions in an array.

[Albireo]

Thank you! (Nice solution)

My result

Code: Select all

#NoEnv  		; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input 			; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  	; Ensures a consistent starting directory.
#SingleInstance force

Logo := []

FileSelectFile LogoName, 3, C:\Users\...\images, Select a PDF-file, Images (*.jpg)
Logo.name := LogoName

Logo.width := imgWidth(Logo.name, height)
Logo.height := height

MsgBox ,, %A_ScriptName% - Row %A_LineNumber%, % "Logo.name .: " Logo.name "`nLogo.height .: " Logo.height "`nLogo.width .: " Logo.width
ExitApp

imgWidth(img, ByRef height) { ; Get image's dimensions
 If FileExist(img) {
  GUI, Add, Picture, hwndpic, %img%
  ControlGetPos,,, width, height,, ahk_id %pic%
  Gui, Destroy
 } Else height := width := 0
 Return width
}

About scale GUI (thank you! - again!)

a scale test of an image

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance force
SetWorkingDir %A_ScriptDir%

FileSelectFile Logo, 3, %A_ScriptDir%\.., Select a PDF-file, Images (*.jpg)

Gui Color, White
Gui Add, Picture, x50 y50 w150 h-1, %Logo%
Gui Show, w300 h300, Logo view

[mikeyww]

Good! Here's the array version in case you like that.

Code: Select all

FileSelectFile LogoName, 3, C:\Users\...\images, Select an image file, Images (*.jpg; *.tif; *.bmp; *.jpeg; *.png; *.gif; *.tiff)
If FileExist(LogoName)
 MsgBox, 64, %A_ScriptName% - Row %A_LineNumber%
  , % Format("Name:  {}`nSize:    {} x {}", LogoName, (logo := imgSize(LogoName)).w, logo.h)
ExitApp

imgSize(img) { ; Get image's dimensions
 If FileExist(img) {
  GUI, Add, Picture, hwndpic, %img%
  ControlGetPos,,, width, height,, ahk_id %pic%
  Gui, Destroy
 }
 Return {w: width, h: height}
}

[Albireo]

the solution from @teadrinker
(easy to handle with an array)

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance force

Logo := []

FileSelectFile filePath, 3, A_ScripDir "\..", Select a PDF-file, Images (*.jpg)

size := GetImageSize(filePath)
MsgBox, % size.W . "`n" size.H

GetImageSize(imageFilePath) {
   if !hBitmap := LoadPicture(imageFilePath, "GDI+")
      throw "Failed to load the image"
   VarSetCapacity(BITMAP, size := 4*4 + A_PtrSize*2, 0)
   DllCall("GetObject", "Ptr", hBitmap, "Int", size, "Ptr", &BITMAP)
   DllCall("DeleteObject", "Ptr", hBitmap)
   Return { W: NumGet(BITMAP, 4, "UInt"), H: NumGet(BITMAP, 8, "UInt") }
}

[Albireo]

Good! Here's the array version in case you like that.
...

Also works well (you are good at handling Format())

[BoBo]

Stolen from here: http://autohotkey.com/board/topic/56987-com-object-reference-autohotkey-v11/?p=387238 (by sbc/@sbcglobal?)

Code: Select all

SplitPath,% USERPROFILE "\Pictures\DunningKruger.jpg", FileName, DirPath,

objShell		:= ComObjCreate("Shell.Application")
objFolder		:= objShell.NameSpace(DirPath)								; set the directry path
objFolderItem	:= objFolder.ParseName(FileName)							; set the file name
MsgBox % objFolder.GetDetailsOf(objFolderItem, 31)							; 31	= 'width x height'
MsgBox % StrSplit(objFolder.GetDetailsOf(objFolderItem, 176), A_Space).1	; 176	= '<width> Pixel'
MsgBox % StrSplit(objFolder.GetDetailsOf(objFolderItem, 178), A_Space).1	; 178	= '<height> Pixel'

Here limited to width & height. BTW, the original script delivers 29 image properties (and its descriptions) for my image

[mikeyww]

Very impressive!

I compared times of GUI vs. ComObj. Perhaps as expected, larger images favored ComObj, whereas smaller images favored GUI. On some runs, the GUI time measured was zero!

38 x 42 image: 78 ms for ComObj, 31 ms for GUI

676 x 1200 image: 78 ms for ComObj, 125 ms for GUI

[BoBo]

I've edited the code to skip the loop that would check for 283 optional properties/items and directly access the items that are of interest instead: width&height/width/height
That way ComObj is acting instantaneously (at least for me, myself and I).
For testing, I used/downloaded this photo: https://upload.wikimedia.org/wikipedia/commons/4/41/Sunflower_from_Silesia2.jpg (2434x1697) = 31/32ms and if using SetBatchLines, -1 = 15/16ms.

[teadrinker]

The last code doesn't actually get the picture size, it just reads metadata and shows what is wriiten there.

[mikeyww]

Sunflower with default SetBatchLines:

ComObj: 78 ms; wins again!

GUI: 530 ms

[BoBo]

@teadrinker Valid point. I've edited/shrank the test image. The script returned the new measurements correctly. So ...?

[teadrinker]

Why not? It shows what you can see in file properties. 176 and 178 doesn't show width and hight for me, they show Folder Name and Location.

[mikeyww]

A puzzle.

Code: Select all

img = [pathToImage]
size := imgSize(img)
x := 10
n := size.w
sum := x + n
MsgBox, x='%x%' n='%n%' sum='%sum%'
ExitApp

imgSize(img) {
 SplitPath, img, fn, dir
 objShell := ComObjCreate("Shell.Application")
 objFolder := objShell.NameSpace(dir)
 objFolderItem := objFolder.ParseName(fn)
 scale := StrSplit(objFolder.GetDetailsOf(objFolderItem, 31), " x ")
 Return {w: scale.1, h: scale.2}
}

Yields:

x='10' n='‪58' sum=''

The GUI version does not have this issue. If I hard code the GetDetailsOf with something like "58 x 9", it works. It's especially bizarre because both x and n are correct. Further: Round(n) is 0. It's like it's showing "58", but it's not really 58; it's a different character set.

What is happening with the blank sum?

[mikeyww]

Fixed.

Code: Select all

imgSize(img) {
 SplitPath, img, fn, dir
 objShell := ComObjCreate("Shell.Application")
 objFolder := objShell.NameSpace(dir)
 objFolderItem := objFolder.ParseName(fn)
 scale := StrSplit(RegExReplace(objFolder.GetDetailsOf(objFolderItem, 31), ".(.+).", "$1"), " x ")
 Return {w: scale.1, h: scale.2}
}

Interesting to see the size flanked by control codes: ASCII 8234 and 8236.

[SKAN]

I compared times of GUI vs. ComObj. Perhaps as expected, larger images favored ComObj, whereas smaller images favored GUI. On some runs, the GUI time measured was zero!

38 x 42 image: 78 ms for ComObj, 31 ms for GUI

676 x 1200 image: 78 ms for ComObj, 125 ms for GUI

 
Fastest: IsPicture()

[BoBo]

@teadrinker

176 and 178 doesn't show width and hight for me, they show Folder Name and Location.

My output:

1 Größe: 196 KB
2 Elementtyp: JPG-Datei
3 Änderungsdatum: 02.10.2020 00:32
4 Erstelldatum: 02.10.2020 00:31
5 Letzter Zugriff: 02.10.2020 09:46
6 Attribute: A
9 Erkannter Typ: Bild
10 Besitzer: DESKTOP-LV8UQOU\BoBo
11 Art: Bild
19 Bewertung: Nicht bewertet
31 Abmessungen: ?1000 x 697?
57 Gesamtgröße: 118 GB
61 Computer: DESKTOP-LV8UQOU (dieser PC)
164 Dateierweiterung: .jpg
165 Dateiname: Sunflower_from_Silesia1.jpg
169 Freier Speicherplatz: 17,3 GB
174 Bittiefe: 24
175 Horizontale Auflösung: ?72 dpi
176 Breite: ?1000 Pixel
177 Vertikale Auflösung: ?72 dpi
178 Höhe: ?697 Pixel
187 Freigegeben: Nein
190 Ordnername: Bilder
191 Ordnerpfad: C:\Benutzer\BoBo\Bilder
192 Ordner: Bilder (C:\Benutzer\BoBo)
194 Pfad: C:\Benutzer\BoBo\Bilder\Sunflower_from_Silesia1.jpg
196 Typ: JPG-Datei
202 Verknüpfungsstatus: Nicht aufgelöst
254 Verwendeter Speicherplatz: ?85%
270 Ausrichtung: Normal

... what sbc's script is doing.

1 Größe:
2 Elementtyp:
3 Änderungsdatum:
4 Erstelldatum:
5 Letzter Zugriff:
6 Attribute:
7 Offlinestatus:
8 Verfügbarkeit:
9 Erkannter Typ:
10 Besitzer:
11 Art:
12 Aufnahmedatum:
13 Mitwirkende Interpreten:
14 Album:
15 Jahr:
16 Genre:
17 Dirigenten:
18 Markierungen:
19 Bewertung:
20 Autoren:
21 Titel:
22 Betreff:
23 Kategorien:
24 Kommentare:
25 Copyright:
26 Titelnummer:
27 Länge:
28 Bitrate:
29 Geschützt:
30 Kameramodell:
31 Abmessungen:
32 Kamerahersteller:
33 Firma:
34 Dateibeschreibung:
35 Masterschlüsselwörter:
36 Masterschlüsselwörter:
37 :
38 :
39 :
40 :
41 :
42 Programmname:
43 Dauer:
44 Ist online:
45 Periodisch wiederkehrend:
46 Ort:
47 Adressen der optionalen Teilnehmer:
48 Optionale Teilnehmer:
49 Organisatoradresse:
50 Organisatorname:
51 Erinnerungszeit:
52 Adressen der erforderlichen Teilnehmer:
53 Erforderliche Teilnehmer:
54 Ressourcen:
55 Besprechungsstatus:
56 Status frei/besetzt:
57 Gesamtgröße:
58 Kontoname:
59 :
60 Aufgabenstatus:
61 Computer:
62 Jahrestag:
63 Name des Assistenten:
64 Telefonnummer des Assistenten:
65 Geburtstag:
66 Geschäftsadresse:
67 Ort (geschäftlich):
68 Land/Region (geschäftlich):
69 Postfach (geschäftlich):
70 Postleitzahl (geschäftlich):
71 Bundesland/Kanton (geschäftlich):
72 Straße (geschäftlich):
73 Fax (geschäftlich):
74 Homepage (geschäftlich):
75 Rufnummer (geschäftlich):
76 Rückrufnummer:
77 Autotelefon:
78 Kinder:
79 Zentrale Firmenrufnummer:
80 Abteilung:
81 E-Mail-Adresse:
82 E-Mail2:
83 E-Mail3:
84 E-Mail-Liste:
85 E-Mail-Anzeigename:
86 Speichern unter:
87 Vorname:
88 Vollständiger Name:
89 Geschlecht:
90 Gegebener Name:
91 Hobbies:
92 Privatadresse:
93 Ort (privat):
94 Land/Region (privat):
95 Postfach (privat):
96 Postleitzahl (privat):
97 Bundesland/Kanton (privat):
98 Straße (privat):
99 Fax (privat):
100 Rufnummer (privat):
101 Adressen für Chats:
102 Initialen:
103 Position:
104 Bezeichnung:
105 Nachname:
106 Adresse:
107 Zweiter Vorname:
108 Mobiltelefon:
109 Spitzname:
110 Bürostandort:
111 Weitere Adresse:
112 Andere Stadt:
113 Anderes Land/Region:
114 Anderes Postfach:
115 Andere Postleitzahl:
116 Anderes Bundesland bzw. Kanton:
117 Andere Straße:
118 Pager:
119 Persönlicher Titel:
120 Stadt:
121 Land/Region:
122 Postfach:
123 Postleitzahl:
124 Bundesland/Kanton:
125 Straße:
126 Primäre E-Mail:
127 Primäre Telefonnummer:
128 Beruf:
129 Ehepartner/Partner:
130 Suffix:
131 TTY/TTD-Telefon:
132 Telex:
133 Webseite:
134 Inhaltstatus:
135 Inhaltstyp:
136 Erfassungsdatum:
137 Archivierungsdatum:
138 Vollendungsdatum:
139 Gerätekategorie:
140 Verbindung hergestellt:
141 Erkennungsmethode:
142 Anzeigename:
143 Lokaler Computer:
144 Hersteller:
145 Modell:
146 Gekoppelt:
147 Klassifizierung:
148 Status:
149 Gerätestatus:
150 Clientkennung:
151 Mitwirkende:
152 Inhalt erstellt:
153 Zuletzt gedruckt:
154 Letzte Speicherung:
155 Hauptabteilung:
156 Dokument-ID:
157 Seiten:
158 Folien:
159 Gesamtbearbeitungszeit:
160 Wortanzahl:
161 Fällig am:
162 Enddatum:
163 Dateianzahl:
164 Dateierweiterung:
165 Dateiname:
166 Dateiversion:
167 Kennzeichnungsfarbe:
168 Kennzeichnungsstatus:
169 Freier Speicherplatz:
170 :
171 :
172 Gruppe:
173 Freigabetyp:
174 Bittiefe:
175 Horizontale Auflösung:
176 Breite:
177 Vertikale Auflösung:
178 Höhe:
179 Wichtigkeit:
180 Anlage?:
181 Ist gelöscht:
182 Verschlüsselungsstatus:
183 Kennzeichnung vorhanden:
184 Wurde beendet:
185 Unvollständig:
186 Lesestatus:
187 Freigegeben:
188 Ersteller:
189 Datum:
190 Ordnername:
191 Ordnerpfad:
192 Ordner:
193 Teilnehmer:
194 Pfad:
195 Nach Ort:
196 Typ:
197 Kontaktnamen:
198 Eintragstyp:
199 Sprache:
200 Letzter Besuch:
201 Beschreibung:
202 Verknüpfungsstatus:
203 Verknüpfungsziel:
204 URL:
205 :
206 :
207 :
208 Medium erstellt:
209 Veröffentlichungsdatum:
210 Codiert durch:
211 Folgennummer:
212 Produzenten:
213 Herausgeber:
214 Staffelnummer:
215 Untertitel:
216 Benutzerweb-URL:
217 Texter:
218 :
219 Anlagen:
220 BCC-Adressen:
221 BCC:
222 CC-Adressen:
223 CC:
224 Unterhaltungs-ID:
225 Empfangsdatum:
226 Absendungsdatum:
227 Von Adressen:
228 Von:
229 Hat Anlagen:
230 Absenderadresse:
231 Absendername:
232 Speicher:
233 Empfängeradressen:
234 Arbeitstitel:
235 An:
236 Laufzeit:
237 Albuminterpret:
238 Sortierung nach Albuminterpret:
239 Album-ID:
240 Sortierung nach Album:
241 Sortierung nach mitwirkenden Interpreten:
242 Beats pro Minute:
243 Komponisten:
244 Sortierung nach Komponist:
245 Disc:
246 Ursprünglicher Schlüssel:
247 Bestandteil einer Kompilation:
248 Stimmung:
249 Teil eines Satzes:
250 Zeitraum:
251 Farbe:
252 Jugendschutz:
253 Grund für Jugendschutzeinstufung:
254 Verwendeter Speicherplatz:
255 EXIF-Version:
256 Ereignis:
257 Lichtwert:
258 Belichtungsprogramm:
259 Belichtungszeit:
260 Blendenzahl:
261 Blitzlichtmodus:
262 Brennweite:
263 35mm Brennweite:
264 ISO-Filmempfindlichkeit:
265 Objektivhersteller:
266 Objektivmodell:
267 Lichtquelle:
268 Maximale Blende:
269 Messmodus:
270 Ausrichtung:
271 Kontakte:
272 Programmmodus:
273 Sättigung:
274 Abstand:
275 Weißausgleich:
276 Priorität:
277 Projekt:
278 Kanal:
279 Folgenname:
280 Untertitel (Closed Captions):
281 Wiederholung:
282 Zweikanalton:
283 Sendungsdatum:

... after removing the condition. So in both cases it'll return 'Breite'/'width' at 176 and 'Höhe'/'height' at 178
That's WIS + WIG .

@mikeyww - Confirmed that this sporadically has returned '0' for the same image + the output (if copied to clipboard, see my spoilered examples above) is showing/contains those characters, interestingly only for a few of its properties?!

[mikeyww]

Thanks for those test results and output!

I tested IsPicture(). It was initially impressive with a run time of zero ms. On further testing, it retrieved the wrong dimensions for one of my JPG files, so I'm not able to use it.