How to make a GUI act like Rainmeter skin?

[capeably]

I'm wondering, is it possible to make an AutoHotkey GUI act like a Rainmeter skin, or a desktop widget?

Specifically:
1) always stays on bottom of all other windows
2) doesn't hide when you show desktop (Win+d)
3) doesn't show in taskbar

[expert_vision]

This complies with 2) and 3):

Code: Select all

Gui, Gadget:+ToolWindow
Gui, Gadget:Add, Text, , Gadget
Gui, Gadget:Show, w150 h50, Gadget window
Gui, Gadget:+LastFound
hGadgetGui := WinExist()
SetTimer, DesktopIntegration
return

DesktopIntegration:
WinGetClass, ahk_class, A
If (ahk_class == "WorkerW") and (LastClass != "WorkerW") ;and (LastClass != "AutoHotkeyGUI")
	WinActivate, % "ahk_id " . hGadgetGui
LastClass := ahk_class
return

GadgetGuiClose:
ExitApp

[capeably]

Thanks so much for the response!

My apologies, can you possibly explain a little bit about what the code is doing? I'm an AutoHotkey noob, so trying to learn about how the code works.

Particularly, what does the "Gadget:" part of the GUI code do? Is that window title?

My goal is to figure out how to adapt the following template to behave that way.

Thanks again!

Spoiler

---

SetTitleMatchMode, 2






; GUI style template coded by just me - http://www.autohotkey.com/board/topic/90723-ac ... /?p=573445
; posted to gui exaples by kon - http://ahkscript.org/boards/viewtopic.php?f=6&t=3851#p12351
Width := 210
Gui, +LastFound
WinSet, Transparent, 220
Gui, Color, 808080
Gui, Margin, 0, 0
Gui, Font,, Verdana
Gui, Font, s12 cFFFFFF Bold
Gui, Add, Progress, % "x-1 y-1 w" (Width+2) " h31 Background8CC73E Disabled hwndHPROG"
Control, ExStyle, -0x20000, , ahk_id %HPROG% ; propably only needed on Win XP
Gui, Add, Text, % "x0 y0 w" Width " h30 BackgroundTrans Center 0x200 gGuiMove vCaption", Evernote Search Box
Gui, Font, s9 c808080
Gui, add, edit, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX1" varSearch
Gui, Font, s9 cFFFFFF Bold
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX2 gAllTitle", &1 Search Title: All Notebooks
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX3 gTagSearch", &2 All Notes Tagged...
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX4 gRecent", &3 Recent Notes (2d)
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX5 gRecent2", &4 Recent Notes (7d)
Gui, Add, Text, % "x7 y+13 w" (Width-14) "r1 +0x4000 vTX6 gClose", CLOSE
Gui, Add, Text, % "x7 y+10 w" (Width-14) "h5 vP"
GuiControlGet, P, Pos
H := PY + PH
Gui, -Caption
WinSet, Region, 0-0 w%Width% h%H% r6-6
Gui, Show,, Evernote Search Box ; Name Window Title
Gui, Show, x0 y0 ; Position at top left of screen


TotalControls := 6
Selection := 1 ; when tab is first pressed, selection will be changed to 2, and TX2 will be selected
return






[background=#ffff99]ChangeSelection:[/background]
TotalLoops := TotalControls - 1
Loop, %TotalLoops% ; loop once for each control (TX2-TX5)
{
i := A_Index + 1
if (i = Selection) ; If this is the selected control change its font
{
Gui, Font, cFFAAAA bold
GuiControl, Font, TX%i%
}
else ; else use the normal font
{
Gui, Font, cFFFFFF bold
GuiControl, Font, TX%i%
}
}
return


[background=#ffff99]GuiMove:[/background]
PostMessage, 0xA1, 2
return


[background=#ffff99]AllTitle:[/background]
Selection := 2
Gui, submit, nohide
gosub, ChangeSelection
MsgBox, %TX1% AllTitle
return


[background=#ffff99]TagSearch:[/background]
Selection := 3
Gui, submit, nohide
gosub, ChangeSelection
MsgBox, %TX1% TagSearch
Return


[background=#ffff99]Recent:[/background]
Selection := 4
Gui, submit, nohide
gosub, ChangeSelection
MsgBox, %TX1% Recent
return


[background=#ffff99]Recent2:[/background]
Selection := 5
Gui, submit, nohide
gosub, ChangeSelection
MsgBox, %TX1% Recent2
return



#IfWinActive, Evernote Search Box ahk_class AutoHotkeyGUI
Enter::
Select := {2: "AllTitle", 3: "TagSearch", 4: "Recent", 5: "Close", 6: "Recent2"} ; the selection numbers and the labels they correspond to
if (Selection != 1)
{
gosub, % Select[Selection]
}
return


Tab::
Selection++
if (Selection > TotalControls)
{
Selection := 2
}
gosub, ChangeSelection
return


+Tab::
Selection--
if (Selection < 2)
{
Selection := TotalControls
}
gosub, ChangeSelection
return


[background=#ffff99]Close:[/background]
ExitApp

---

[/color]

Highlighting by Highlite

[expert_vision]

Gui, Gadget:+ToolWindow get's rid of the taskbar icon and gives a narrower title bar. Read GUI options.
DesktopIntegration: label activates the gadget window (brings it to the front) whenever the current active window class is "WorkerW" (desktop when you press Win+D)
Gadget: is the name I chose for the window label (not title). You don't have to use it if you have only one GUI. It's useful when you have multiple GUI windows. Then if you want to change a control in a particular window you use:
GuiControl, [window label]:[command], [control variable name], [param3]

[capeably]

Oh I see. Thanks so much for that explanation. Very cool!

[empardopo]

Try to change the first line of the script
from

Code: Select all

Gui, Gadget:+ToolWindow

to

Code: Select all

Gui, Gadget:+ToolWindow AlwaysOnTop

Greetings.

[just me]

Code: Select all

#NoEnv
#NoTrayIcon ; <<<<< if you want
SetTitleMatchMode, 2

; GUI style template coded by just me - http://www.autohotkey.com/board/topic/90723-achieve-rainmeter-style-gui-via-gdip-library/?p=573445
; posted to gui exaples by kon - http://ahkscript.org/boards/viewtopic.php?f=6&t=3851#p12351
HACTIVE := WinExist("A") ; <<<<< added
HOWNER := DllCall("GetShellWindow", "Ptr") ; <<<<< added
Width := 210
Gui, +LastFound +Owner%HOWNER% ; <<<<< changed
WinSet, Transparent, 220
Gui, Color, 808080
Gui, Margin, 0, 0
Gui, Font,, Verdana
Gui, Font, s12 cFFFFFF Bold
Gui, Add, Progress, % "x-1 y-1 w" (Width+2) " h31 Background8CC73E Disabled hwndHPROG"
Control, ExStyle, -0x20000, , ahk_id %HPROG% ; propably only needed on Win XP
Gui, Add, Text, % "x0 y0 w" Width " h30 BackgroundTrans Center 0x200 gGuiMove vCaption", Evernote Search Box
Gui, Font, s9 c808080
Gui, add, edit, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX1" varSearch
Gui, Font, s9 cFFFFFF Bold
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX2 gAllTitle", &1 Search Title: All Notebooks
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX3 gTagSearch", &2 All Notes Tagged...
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX4 gRecent", &3 Recent Notes (2d)
Gui, Add, Text, % "x7 y+10 w" (Width-14) "r1 +0x4000 vTX5 gRecent2", &4 Recent Notes (7d)
Gui, Add, Text, % "x7 y+13 w" (Width-14) "r1 +0x4000 vTX6 gClose", CLOSE
Gui, Add, Text, % "x7 y+10 w" (Width-14) "h5 vP"
GuiControlGet, P, Pos
H := PY + PH
Gui, -Caption
WinSet, Region, 0-0 w%Width% h%H% r6-6
Gui, Show, x0 y0, Evernote Search Box ; Position at top left of screen, Name Window Title ; <<<<< changed
WinActivate, ahk_id %HACTIVE% ; <<<<< added
; ...
; ...
; ...

Maybe?

[empardopo]

@just me, very nice!