Get last 50 lines

[roysubs]

I'd like to just get the last 50 lines of various log files, what's the easiest way to ignore the first few thousand lines and just get the last 50?

Code: Select all

Loop, Read, D:\0.log
{
    Line := A_LoopReadLine
    Lines .= Lines"`n"Line ; but ignore all lines except for the last 50 !
}

[Spark]

Hello,

Try This

Code: Select all

FilePath := "D:\0.log"

Loop, Read,% FilePath
	Total_Line := A_Index

StartLine := Total_Line - 50

Loop, Read, % FilePath
	if (A_Index > StartLine)
		Lines .= A_LoopReadLine "`n"

MsgBox, % Lines

HTH

[Xtra]

Code: Select all

FileRead, logLines, D:\0.log
lines := LastLines(logLines, 50)

LastLines(ByRef string, linecount, delimiter := "`n") {
    return SubStr(string, InStr(string, delimiter,, 0, linecount) + StrLen(delimiter))
}

[braunbaer]

Code: Select all

FileRead, logLines, D:\0.log
lines := LastLines(logLines, 50)

LastLines(ByRef string, linecount, delimiter := "`n") {
    return SubStr(string, InStr(string, delimiter,, 0, linecount) + StrLen(delimiter))
}

That omits the first n lines instead of returning the last n lines...

Hello,

Try This

Code: Select all

FilePath := "D:\0.log"

Loop, Read,% FilePath
	Total_Line := A_Index

StartLine := Total_Line - 50

Loop, Read, % FilePath
	if (A_Index > StartLine)
		Lines .= A_LoopReadLine "`n"

MsgBox, % Lines

If the files are not VERY big (bigger than the available memory), it is much more efficient to read the entire file into memory and then remove the starting lines

Code: Select all

fileread, text, %Filepath%
startpos:=instr(text,"`n",,-1,50)+1
text:=substr(text, startpos)

[roysubs]

All great, thanks!

[Xtra]

That omits the first n lines instead of returning the last n lines...

Did you even try it?

Easy example:

Spoiler

Code: Select all

logLines =
(join`r`n
line 1
line 2
line 3
line 4
line 5
line 6
line 7
line 8
line 9
line 10
)

;~ FileRead, logLines, D:\0.log
lines := LastLines(logLines, 5)
MsgBox % lines

LastLines(ByRef string, linecount, delimiter := "`n") {
    return SubStr(string, InStr(string, delimiter,, 0, linecount) + StrLen(delimiter))
}

[jNizM]

Did something with FileObject years ago -> https://github.com/jNizM/AHK_Scripts/blob/master/src/file_object/FileReadLastLines.ahk
But it is slow with really big files / logs

[braunbaer]

Did you even try it?

You are right, it works. I did not realize that instr with startingpos=0 performs a backward search. I thought startingpos has to be negative for that.

[sofista]

Try

Code: Select all

Loop, parse, text, `n, `r
{
	Line := A_LoopField
}

[Xtra]

Here is a variation of @jNizM post:

Code: Select all

FileReadLastLines(FileName, LastLines := 5, Delim := "`n")
{
    if (IsObject(file := FileOpen(FileName, "r-d", "UTF-8"))) {
        CountLines := 0
        Loop % file.Length {
            file.Seek("-" . i := A_Index)
            if (file.Read(1) = Delim)
                if (++CountLines = LastLines)
                    break
        }
        file.Seek("-" . i)
        return LTrim(file.Read(), Delim), file.Close()
    }
    return false
}

[rommmcek]

That one is fast even for very big files:
https://www.autohotkey.com/boards/viewtopic.php?f=6&t=3799