Arrange menu Topic is solved

[hemsith14_]

Hey,

Is it possible to arrange a menu so each category will have it's own column, instead of having to hover or click over the categories to see what's inside?
I basically want to see the entire menu when it's opened, instead of having to click on the categories. The problem is that if I try to do that now without the categories, it's just gets all the items into 1 big column that doesn't fit into my screen.

Appreciate your help, thank you

[boiler]

Then just make a GUI with a bunch of buttons in several columns. There doesn’t seem to be any reason to make it a menu per your description. Just have your script invoke the GUI instead of a menu. You can implement the equivalent of check marks if that’s one reason for using a menu.

[hemsith14_]

Just not sure how to work with GUIs..

I only want a simple menu that will be displayed like I said, nothing more..

[boiler]

Just not sure how to work with GUIs..

Not sure what to tell you if you’re not interested in learning the solution to your problem.

[hemsith14_]

Could you make a simple GUI that will work like a menu?

[boiler]

What you described doesn’t work like a menu because all the options are always visible. It’s more like what I described, which is a GUI with a bunch of buttons. Yes, that’s standard GUI operation.

[hemsith14_]

Could you show me an example script?

[boiler]

See Example #2 from the GUI documentation page. Just make a bunch of buttons and none of the other stuff.

[Hellbent]

Could you show me an example script?

Code: Select all

Gui, 1:+AlwaysOnTop
Index := 0
Loop, 10	{
	Gui, 1:Add, Button, xm y+10 w110 , % "Button " ++Index
	Loop, 9	{
		Gui, 1:Add, Button, x+10 yp wp , % "Button " ++Index
	}
}
Gui, 1:Show

[hemsith14_]

Is it possible to just simply turn my existing menu into something like this?

Also, how do I get it to behave like a menu, so it would be opened from where my mouse is?

[Hellbent]

Is it possible to just simply turn my existing menu into something like this?

YES? NO? MAYBE?

Also, how do I get it to behave like a menu, so it would be opened from where my mouse is?

A variation of this.

Code: Select all

GuiClose:
	Gui, 1:Hide
	return

F1::
	CoordMode, Mouse, Screen
	MouseGetPos, x, y
	Gui, 1:Show, % "x" x " y" y
	return

[boiler]

YES? NO? MAYBE?

I vote NO. What you showed is easier than trying to force a menu to do something it is not meant to do, so OP should follow your example.

[hemsith14_]

I currently have this:

Code: Select all

^1::
MouseGetPos, X1, Y1
Gui, New,,Test
Gui, Font, s30, Verdana
Gui, +AlwaysOnTop -SysMenu +Owner
Gui, Add, Button, Y+10 W110 , TEST
Gui, Show
Return

ButtonTEST:
Send, {LWin}
Gui, Hide
Return

Couldn't get it to follow my mouse yet, and I also want it to be closed if I click on any other place rather than on the GUI (like a menu).

Also, not sure how to get the buttons to be aligned side by side.

Could you help me with that?

[boiler]

Hellbent showed examples of how to align buttons in columns and how to have it appear where the mouse is.

To get it to close when you click, make a hotkey ~LButton:: that is active only when your GUI exists, and if the click is outside of your GUI, then it would close the GUI.

[hemsith14_]

I figured everything out but how to get it to follow the mouse and the exit function.

Do you mind helping me with that?

Code: Select all

^1::
CoordMode, Mouse, Screen
MouseGetPos, x, y
Gui, 1:New,,Test
Gui, 1:Font, s30, Verdana
Gui, 1:+AlwaysOnTop -SysMenu +Owner
Gui, 1:-Caption
Gui, 1:Add, Button, y+10 W110 , TEST
Gui, 1:Add, Button, x+10 W110 , TEST2
Gui, 1:Show
Return

ButtonTEST:
Send, {LWin}
Gui, Hide
Return

ButtonTEST2:
Send, {LWin}
Gui, Hide
Return

[boiler]

As Hellbent showed:

Code: Select all

Gui, 1:Show, % "x" x " y" y

[hemsith14_]

Oh yea I got confused with the ordering there, it works now. Thank you!

Now would you mind helping me with the ~LButton solution you suggested?

[boiler]

Sure. Try this:

Code: Select all

^1::
CoordMode, Mouse, Screen
MouseGetPos, x, y
Gui, 1:New,,Test
Gui, 1:Font, s30, Verdana
Gui, 1:+AlwaysOnTop -SysMenu +Owner
Gui, 1:-Caption
Gui, 1:Add, Button, y+10 W110 , TEST
Gui, 1:Add, Button, x+10 W110 , TEST2
Gui, 1:Show, % "x" x " y" y
Return

ButtonTEST:
Send, {LWin}
Gui, Hide
Return

ButtonTEST2:
Send, {LWin}
Gui, Hide
Return

#If WinExist("Test ahk_class AutoHotkeyGUI")
~LButton::
	MouseGetPos,,, WinID
	if (WinExist("Test ahk_class AutoHotkeyGUI") != WinID)
		Gui, Hide
return

[flyingDman]

Have you considered using menu with barbreak ?

Code: Select all

loop, 15
	Menu, scripts, Add, test%a_index%, Execute, % !mod(a_index - 1,5) ? "+barbreak" : ""
Menu, scripts, Show
return

execute:
return

[boiler]

@flyingDman