Detecting double-click on ListView's column header

[think]

Hi, is it possible to detect when ListView column header is double-clicked?
In the code below I can detect double click on the content but only single view on the header.
Any tip is greatly appreciated.

Code: Select all

gui, Add, ListView, w200 h100 -LV0x10 NoSort gClick, Column 1|Column 2
gui, show
return

Click:
if (A_GuiEvent = "ColClick")
	msgbox % "Column clicked: " A_EventInfo
if (A_GuiEvent = "DoubleClick")
   msgbox Double clicked
return

[neovis]

As far as I know, it is not supported in basic commands.

This is using OnMessage.

Code: Select all

OnMessage(0x203, "WM_LBUTTONDBLCLK")

WM_LBUTTONDBLCLK(wparam, lparam, msg, hwnd) {
    WinGetClass class, % "ahk_id" hwnd
    if (class == "SysHeader32") {
        hwnd := DllCall("GetParent", "ptr",hwnd, "ptr") ; hListView from hHeader
        
        VarSetCapacity(hti, 24, 0)
        DllCall("GetCursorPos", "ptr",&hti)
        DllCall("ScreenToClient", "ptr",hwnd, "ptr",&hti)
        
        ; LVM_SUBITEMHITTEST
        DllCall("SendMessage", "ptr",hwnd, "uint",0x1039, "uptr",0, "ptr",&hti)
        column := NumGet(hti, 16, "int")+1 ; iSubItem
        
        ToolTip % "Column: " column
    }
}