List of all current hotkeys in Windows
List of all current hotkeys in Windows
Is there any way to find all hotkeys that are registered in Windows?
Re: List of all current hotkeys in Windows
Perfect, thanks!
-
- Posts: 4373
- Joined: 29 Mar 2015, 09:41
- Contact:
Re: List of all current hotkeys in Windows
Code: Select all
SetBatchLines, -1
list := ""
Loop 255 {
vk := A_Index
if ((keyName := GetKeyName(Format("vk{:x}", vk))) = "")
continue
if RegExMatch(keyName, "^Numpad\K.+", key) && GetKeyVK(key) = vk
keyName := key
Loop 16 {
modifiers := A_Index - 1
if DllCall("RegisterHotKey", "Ptr", A_ScriptHwnd, "Int", 1, "UInt", modifiers, "UInt", vk)
DllCall("UnregisterHotKey", "Ptr", A_ScriptHwnd, "Int", 1)
else {
for k, v in {1: "Alt", 2: "Ctrl", 4: "Shift", 8: "Win"} {
if (modifiers & k)
list .= v . "+"
}
list .= keyName . "`n"
}
}
}
Sort, list
MsgBox, % Clipboard := list
Re: List of all current hotkeys in Windows
@teadrinker thank you , have always a solution
here meaning to windows shortcuts
https://support.microsoft.com/en-us/windows/keyboard-shortcuts-in-windows-dcc61a57-8ff0-cffe-9796-cb9706c75eec
here meaning to windows shortcuts
https://support.microsoft.com/en-us/windows/keyboard-shortcuts-in-windows-dcc61a57-8ff0-cffe-9796-cb9706c75eec
Who is online
Users browsing this forum: feiy and 198 guests