Access next key/value pair in For ..in loop

[pramach]

Hi

Assuming I have an associative array with n key/value pairs.

While looping through, I want to know the Key/value pair of the next element in the array.

Something like ...:

Code: Select all

for k, v in myArray
{
	if (k = "ABC")
		msgbox % myArrayNextKey
}

I tried with myArray.Next(k2,v2) but did not get any value inside k2 and v2.

I know I can use a flag, do Continue and check the flag on next loop.
But I think (or hope) there is a better way.

Any help welcome.

[mikeyww]

Code: Select all

arr := {a: "b", abc: "x", 9: "f", d: 44} ; 9, a, abc, d
MsgBox, 64, ABC, % next(arr, "ABC")
MsgBox, 64,   a, % next(arr, "a"  )
MsgBox, 64,   9, % next(arr, 9    )

next(arr, item) {
 keyList := [], index := []
 For k in arr
  keyList.Push(k), index[k] := A_Index
 Return keyList[index[item] + 1]
}

[pramach]

thanks a lot-

So the solution is to put first all key's into a simple array in order to access than the simple array by index.

But, to be honest, does this makes sense for big arrays with several hundred or thousands of items ?
From a memory usage point of view I would say no

OK, it depends.
When I need the next key only once, my "flag-continue-check flag" proposal makes more sense.
If I need the value of the next item several times within my loop, your simple array solution is better.

Thanks anyway as I just learned something new.

[mikeyww]

I can't say that my approach is better, though it's different! I agree with your comments.

There could be a trick that accesses the memory directly, but it's beyond my knowledge. In terms of an associative array itself using the native AHK, so to speak, one has to loop to get to the next key.

If your array does not change, you can index it once at the start, instead of each time inside the function.

Code: Select all

arr  := {a: "b", abc: "x", 9: "f", d: 44}
next := {}
For k in arr ; 9, a, abc, d
 last := next[last] := k
For each, item in ["ABC", "a", 9]
 MsgBox, 64, %item%, % next[item]

[pramach]

Sorry for late reply.

Creating the index outside was of sure my assumption

[swagfag]

Code: Select all

myArraysEnum := myArray._NewEnum()
while myArraysEnum.Next(k, v) 
{
	if (k = "ABC")
	{
		; get next element, if there was one
		if myArraysEnum.Next(myArrayNextKey, myArrayNextValue)
		{
			msgbox % myArrayNextKey
		}

		; unconditionally decrement mOffset back down once
		static offsetof_mOffset := 3 * A_PtrSize
		NumPut(NumGet(&myArraysEnum, offsetof_mOffset, "Int") - 1, &myArraysEnum, offsetof_mOffset, "Int")
	}
}