sorting files by folder path Topic is solved

[haomingchen1998]

viewtopic.php?t=95352

I got the code below from the above link, and I'm just wondering if I can make it to apply this sorting for 2 specific folders upon launching the script instead of needing a hotkey to trigger? I'm thinking of using a winactive title, but I still prefer to specify a path for reliability. Are there better ideas that I'm not thinking of? Thanks!

Code: Select all

#IfWinActive ahk_class CabinetWClass ahk_exe explorer.exe
    F1::
    For oWin in ComObjCreate("Shell.Application").Windows {
    If WinActive() != oWin.HWND
    Continue
    oWin.Document.GroupBy     := "System.ItemTypeText"
    oWin.Document.SortColumns := "prop:-System.ItemNameDisplay;"
    Return
    }
    Return
#IfWinActive

[mikeyww]

Ideas are below.

Code: Select all

#Requires AutoHotkey v1.1.33
#SingleInstance
specialPath := "C:\Windows|C:\Windows\System32"
regEx       := "(" StrReplace(specialPath, "\", "\\") ")"
Loop {
 WinWaitActive ahk_class CabinetWClass
 hWnd := WinActive("A")
 SetTimer Check, 100
 SoundBeep 1500
 WinWaitNotActive
 SetTimer Check, Off
 SoundBeep 1000
}

Check:
last := current, current := explorerGetPath()
If (current != last && current ~= regex)
 For oWin in ComObjCreate("Shell.Application").Windows
  If (hWnd = oWin.Hwnd) {
   oWin.Document.GroupBy     := "System.ItemTypeText"           ; Group by item type
   oWin.Document.SortColumns := "prop:-System.ItemNameDisplay;" ; Reverse sort by item name
   SoundBeep 2500
  }
Return

explorerGetPath(hwnd := 0){ ; https://www.autohotkey.com/boards/viewtopic.php?p=387113#p387113
 If hWnd
  explorerHwnd := WinExist( "ahk_class CabinetWClass ahk_id " . hwnd )
 Else If !explorerHwnd := WinActive("ahk_class CabinetWClass")
  explorerHwnd := WinExist("ahk_class CabinetWClass")
 If explorerHwnd
  For window in ComObjCreate("Shell.Application").Windows
   Try If (window && window.hwnd && window.hwnd==explorerHwnd)
    Return window.Document.Folder.Self.Path
 Return False
}

[haomingchen1998]

Ideas are below.

Code: Select all

#Requires AutoHotkey v1.1.33
#SingleInstance
specialPath := "C:\Windows|C:\Windows\System32"
regEx       := "(" StrReplace(specialPath, "\", "\\") ")"
Loop {
 WinWaitActive ahk_class CabinetWClass
 hWnd := WinActive("A")
 SetTimer Check, 100
 SoundBeep 1500
 WinWaitNotActive
 SetTimer Check, Off
 SoundBeep 1000
}

Check:
last := current, current := explorerGetPath()
If (current != last && current ~= regex)
 For oWin in ComObjCreate("Shell.Application").Windows
  If (hWnd = oWin.Hwnd) {
   oWin.Document.GroupBy     := "System.ItemTypeText"           ; Group by item type
   oWin.Document.SortColumns := "prop:-System.ItemNameDisplay;" ; Reverse sort by item name
   SoundBeep 2500
  }
Return

explorerGetPath(hwnd := 0){ ; https://www.autohotkey.com/boards/viewtopic.php?p=387113#p387113
 If hWnd
  explorerHwnd := WinExist( "ahk_class CabinetWClass ahk_id " . hwnd )
 Else If !explorerHwnd := WinActive("ahk_class CabinetWClass")
  explorerHwnd := WinExist("ahk_class CabinetWClass")
 If explorerHwnd
  For window in ComObjCreate("Shell.Application").Windows
   Try If (window && window.hwnd && window.hwnd==explorerHwnd)
    Return window.Document.Folder.Self.Path
 Return False
}

This is SO COOL, thank you!!!

[haomingchen1998]

Ideas are below.

Code: Select all

#Requires AutoHotkey v1.1.33
#SingleInstance
specialPath := "C:\Windows|C:\Windows\System32"
regEx       := "(" StrReplace(specialPath, "\", "\\") ")"
Loop {
 WinWaitActive ahk_class CabinetWClass
 hWnd := WinActive("A")
 SetTimer Check, 100
 SoundBeep 1500
 WinWaitNotActive
 SetTimer Check, Off
 SoundBeep 1000
}

Check:
last := current, current := explorerGetPath()
If (current != last && current ~= regex)
 For oWin in ComObjCreate("Shell.Application").Windows
  If (hWnd = oWin.Hwnd) {
   oWin.Document.GroupBy     := "System.ItemTypeText"           ; Group by item type
   oWin.Document.SortColumns := "prop:-System.ItemNameDisplay;" ; Reverse sort by item name
   SoundBeep 2500
  }
Return

explorerGetPath(hwnd := 0){ ; https://www.autohotkey.com/boards/viewtopic.php?p=387113#p387113
 If hWnd
  explorerHwnd := WinExist( "ahk_class CabinetWClass ahk_id " . hwnd )
 Else If !explorerHwnd := WinActive("ahk_class CabinetWClass")
  explorerHwnd := WinExist("ahk_class CabinetWClass")
 If explorerHwnd
  For window in ComObjCreate("Shell.Application").Windows
   Try If (window && window.hwnd && window.hwnd==explorerHwnd)
    Return window.Document.Folder.Self.Path
 Return False
}

I know I can use the below code to group by type, but can I set groupby to none after I'm done? I wasn't able to find anything that either reset it, or group by none. Thanks!

Code: Select all

oWin.Document.GroupBy     := "System.ItemTypeText"  

[mikeyww]

Windows File Explorer Shell GroupBy Values for COM

System.ItemNameDisplay
System.DateModified
System.ItemTypeText
System.Size
System.DateCreated
System.Author
System.Keywords
System.Title
System.Null

[haomingchen1998]

Windows File Explorer Shell GroupBy Values for COM

System.ItemNameDisplay
System.DateModified
System.ItemTypeText
System.Size
System.DateCreated
System.Author
System.Keywords
System.Title
System.Null

Really appreciate it, worked as expected!