Scroll volume when over Gui. Topic is solved

[V0RT3X]

I came across this little script that detects when mouse cursor is over a script's Gui and when it leaves a script's Gui.
What I can't figure out is how to put hotkeys inside a function for simple volume up and down. What I'm attempting to do
is I have a volume script that display the volume percentage in a small Gui in the bottom right corner of my screen next to the clock.
I would like to be able to simply hover over that small Gui and adjust the volume with my scroll wheel. I know documentation
for #If shows in example 1 how to hover over the taskbar and scroll volume, but I am only wanting the area of the Gui to be the trigger.

image.png (14.21 KiB) Viewed 105 times

I would greatly appreciate if anyone can show me how to insert this...

Code: Select all

WheelUp::Send {Volume_Up 2}
WheelDown::Send {Volume_Down 2}

...into the below script to accomplish my end goal!!

Code: Select all

;;----------------Test Gui----------------
Gui Hover: Color, Silver
Gui Hover: 
    +AlwaysOnTop
    +Resize
    
Gui Hover: Show, x300 y300 w400 h300
    OnMessage(0x200, "OnMouseMoveHover")
    OnMessage(0x0201, "WM_LBUTTONDOWNdrag") 
Return
;;--------------------------------------------


OnMouseMoveHover()
    {
    MouseGetPos mx, my, IdWindow
    WinGetTitle, WinT, ahk_id %IdWindow%
    Title_buffer := WinT
    ToolTip The cursor is in Gui window %WinT%, 150, 3
    Loop, 
        {
        MouseGetPos mx, my, IdWindow  
            WinGetTitle, WinT, ahk_id %IdWindow%
                if !("" . Title_buffer = "" . WinT)
            {
        ToolTip 	 ; TooltipOff
        MsgBox, , , The cursor is now out of the`nGui window of %Title_buffer% GUI!, 2
                break
            }
        Sleep, 200
        }
    }
 
HoverGuiClose:
ExitApp

Thank You!!

[tabr3]

Code: Select all

groupadd, blocked_soft, ahk_exe game1.exe ; optional

~wheelup::
CoordMode , mouse, screen
mousegetpos xxx, yyy
if (a_screenwidth - xxx <=50) and (a_screenheight - yyy <=50) ;  and winactive!(ahk_group blocked_soft)
Send {Volume_Up 2}
return

~wheeldown::
CoordMode , mouse, screen
mousegetpos xxx, yyy
if (a_screenwidth - xxx <=50) and (a_screenheight - yyy <=50)
Send {Volume_Down 2}
return

I will just do it this way , don't know how to deal with #if...

[V0RT3X]

Thanks for this @tabr3. It works, but also works across the entire taskbar on my second monitor. I'll have to see if I can figure out
if this can be fine tuned to only be a 50x40 pixel area. But for the time being it's a lot better than what I had going!! Thank you!!

EDIT: This actually turned out to be exactly what I needed! Thank you @tabr3!!
My modification below using Soundset instead of sending Volume_Up/Down as the latter shows a built in display while scrolling.
With your code I was able to use just the selected area of the taskbar I wanted. Not using the volume Gui as I was originally attempting,
but considering I'm keeping my volume Gui where it is, this is perfect, and will definitely find future uses.

Code: Select all

TaskbarAreaX := A_ScreenWidth - 153  ; Pixels from the right side of the screen.
TaskbarAreaY := A_ScreenHeight - 39  ; Pixels from the right side of the screen.

;;--------------------------------- 
~WheelUp:: 
CoordMode, Mouse, Screen
MouseGetPos, xPos, yPos

if (xPos >= TaskbarAreaX && yPos >= TaskbarAreaY && xPos <= (TaskbarAreaX + 150) && yPos <= (TaskbarAreaY + 40))
{
SoundSet +2
}
Return
;;--------------------------------- 
~WheelDown:: 
CoordMode, Mouse, Screen
MouseGetPos, xPos, yPos

if (xPos >= TaskbarAreaX && yPos >= TaskbarAreaY && xPos <= (TaskbarAreaX + 150) && yPos <= (TaskbarAreaY + 40))
{
SoundSet -2
}
Return

-the dotted line box is for illustration only...

image.png (8.48 KiB) Viewed 74 times

My final Volume Gui script. Covers the Notification Center, but still accessible through click-through. (I never use it)
Volume is scrollable from the Speakers icon through the system clock, and over the Notification Center as shown above.

Spoiler

Code: Select all

;∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙ 
#NoEnv 
#NoTrayIcon
#Persistent 
#SingleInstance, Force 
SetBatchLines -1 
;;--------------------------------------------- 
SetTimer, ShowVol, 500 	 ;; Keeps above taskbar in z-order.
;;--------------------------------------------- 
SoundSet, 7 	 ; Set to prefered default volume level.
;;--------------------------------------------- 
;∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙ 
;;------------- VOLUME GUI ------------- 
;;----- Volume Gui Positioning.
SWide := A_ScreenWidth - 53
SHigh := A_ScreenHeight - 40
GWidth := 48
GHeight := 41
;;----- Location for Cursor to Scroll Volume. 
TaskbarAreaX := A_ScreenWidth - 153  ; Pixels from the right side of the screen.
TaskbarAreaY := A_ScreenHeight - 39  ; Pixels from the bottom of the screen.
;;--------------------------------------------- 
Gui, 
    +AlwaysOnTop
    -Caption
    +E0x20 			 ;; Comment out to stop click-through ability.
    +LastFound
    +ToolWindow
 WinSet Transparent, 255 	 ;; Full Opaqueness (click-through)

Gui, Color, 1B1F21
GUI, Margin, 3, 2

Gui, Font, s6 w600 cAQUA q5, VERDANA 		 ;; Aqua Volume Label.
Gui, Add, Text, x3 y6 gVolume, VOLUME

Gui, Font, s12 w400 cLIME q5, CALIBRI 		 ;; Lime % Volume Value.
Gui, Add, Text, x5 y16 w%GWidth% BackgroundTrans vVolumeText, 

Gui, Show, x%SWide% y%SHigh% w%GWidth% h%GHeight% NA, Vol-Level
    SetTimer, UpdateVolume, 500
Return
;;--------------------------------------------- 
;∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙ 
;;-------------- FUNCTIONS -------------- 
UpdateVolume:
    SoundGet, Volume
    VolumePercentage := Round(Volume)
    if (Volume == 0) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s6 w600 cC0C0C0 q5, VERDANA 	 ;; SILVER > MUTED VOLUME.
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, MUTE 		 ;; MUTED VOLUME.  BOLD
    }
    else if (Volume == 100) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s10 w600 cFF0000 q5, VERDANA 	;; RED > MAX VOLUME.
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, MAX 		 ;; MAXED VOLUME.  BOLD
    }
    else if (Volume >= 25 && Volume <= 35) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cBFFF00 q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Lime/Yellow Zone.	25-35
    }
    else if (Volume >= 35 && Volume <= 50) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cFFFF00 q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Yellow Zone.	35-50
    }
    else if (Volume >= 50 && Volume <= 65) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cFFBE00 q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Yellow/Orange Zone.	50-65
    }
    else if (Volume >= 65 && Volume <= 80) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cFF8000 q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Orange Zone.	65-80
    }
    else if (Volume >= 80 && Volume <= 90) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cFF5500 q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Orange/Red Zone.	80-90
    }
    else if (Volume >= 90 && Volume <= 99) {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cFF1111 q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Red Zone.	90-99
    }
    else {
        GuiControl, -Redraw, VolumeText
            Gui, Font, s12 w400 cLIME q5, CALIBRI 
            GuiControl, Font, VolumeText
        GuiControl, +Redraw, VolumeText
        GuiControl,, VolumeText, %VolumePercentage%`% 	 ;; Lime > Comfort Zone Volume. 1-24
    }
Return
;;--------------------------------------------- 
ShowVol:
Gui, Show, NA, Vol-Level
Return
;;--------------------------------------------- 
; If +E0x20 is commented out, the Volume Label on the Volume Gui will set the volume level to the below percentage when clicked.
Volume: 	 
SoundSet, 3 	 ; Set to prefered default volume level.
Return
;;--------------------------------------------- 

;∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙ 
;;----------- VOLUME SCROLL ----------- 
;;---------------- UP 
~WheelUp:: 
CoordMode, Mouse, Screen
MouseGetPos, xPos, yPos

if (xPos >= TaskbarAreaX && yPos >= TaskbarAreaY && xPos <= (TaskbarAreaX + 150) && yPos <= (TaskbarAreaY + 40))
{
SoundSet +2
}
Return
;;---------------- DOWN 
~WheelDown:: 
CoordMode, Mouse, Screen
MouseGetPos, xPos, yPos
if (xPos >= TaskbarAreaX && yPos >= TaskbarAreaY && xPos <= (TaskbarAreaX + 150) && yPos <= (TaskbarAreaY + 40))
{
SoundSet -2
}
Return
;;------------------- END ------------------- 
;∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙=∙