[SOLVED]Confine mouse cursor to a circular shape?

[ChrisMiller]

Good morning AHK friends,
I ran into a small problem and I’m not sure how I, or if it is even possible to solve this.
As the title suggests I want to confine my mouse cursor to a certain part of the desktop.
I do that with the help of this at the beginning of the script:

Code: Select all

ClipCursor( Confine=True, x1=0 , y1=0, x2=1, y2=1 ) {
 VarSetCapacity(R,16,0),  NumPut(x1,&R+0),NumPut(y1,&R+4),NumPut(x2,&R+8),NumPut(y2,&R+12)
Return Confine ? DllCall( "ClipCursor", UInt,&R ) : DllCall( "ClipCursor" )
}

So when I call my GUI I put this after the <Gui, Show> command:

Code: Select all

 WinGetPos, VarX, VarY, Width, Height, A
		VarX2 := VarX + Width - 15
		VarY2 := VarY + Height - 15
		ClipCursor( True, VarX, VarY, VarX2, VarY2)

This works perfectly fine! My problem is the shape. It obviously confines the mouse to a rectangle.
The GUI I want to confine the mouse in looks like this:

So long story short, can I confine my mouse cursor to a circular shape?
Bit of a luxurious problem I know, but I cant let it go

Thanks in advance guys and have a nice day.

[waetherman]

That would be my approach:

Code: Select all

smoothness := .8 ;should be between 0 and 1
radius := 135

RButton::
	CoordMode, Mouse, Screen
	MouseGetPos, x, y
	While ( 1 ) {
		GetKeyState, rmb, Rbutton,P
		if ( rmb = "U" ) {
			break
		}
		MouseGetPos, nx, ny
		dx := nx - x
		dy := ny - y
		dist := sqrt( (dx ** 2) + (dy ** 2) )
		
		if ( dist > radius ) {
			dist := radius / dist
			dx *= dist
			dy *= dist
			
			a := smoothness
			b := 1 - smoothness
			nx := a*nx + b*(x + dx)
			ny := a*ny + b*(y + dy)
			MouseMove, nx, ny, 0
		}
	}
	return

 ~#q::ExitApp

[Nextron]

Applying waetherman' code to a hook makes sure the cursor never leaves the target area:

Code: Select all

RButton::
	CircleClip(135)
	KeyWait,RButton
	CircleClip()
Return


CircleClip(radius=0, x:="", y:=""){
	global CircleClipRadius, CircleClipX, CircleClipY
	static hHookMouse, _:={base:{__Delete: "CircleClip"}}
	If (radius>0)
		CircleClipRadius:=radius
		, CircleClipX:=x
		, CircleClipY:=y
		, hHookMouse := DllCall("SetWindowsHookEx", "int", 14, "Uint", RegisterCallback("CircleClip_WH_MOUSE_LL", "Fast"), "Uint", 0, "Uint", 0)
	Else If (!radius && hHookMouse){
		DllCall("UnhookWindowsHookEx", "Uint", hHookMouse)
		CircleClipX:=CircleClipY:=""
	}
}

CircleClip_WH_MOUSE_LL(nCode, wParam, lParam){
	global CircleClipRadius, CircleClipX, CircleClipY
	Critical

	if !nCode && (wParam = 0x200){ ; WM_MOUSEMOVE 
		nx := NumGet(lParam+0, 0, "Int") ; x-coord
		ny := NumGet(lParam+0, 4, "Int") ; y-coord

		If (CircleClipX="" || CircleClipY="")
			CircleClipX:=nx, CircleClipY:=ny
		  
		dx := nx - CircleClipX
		dy := ny - CircleClipY
		dist := sqrt( (dx ** 2) + (dy ** 2) )

		if ( dist > CircleClipRadius ) {
			dist := CircleClipRadius / dist
			dx *= dist
			dy *= dist
			
			nx := CircleClipX + dx
			ny := CircleClipY + dy
		}

		DllCall("SetCursorPos", "Int", nx, "Int", ny)
		Return 1
		
	}else Return DllCall("CallNextHookEx", "Uint", 0, "int", nCode, "Uint", wParam, "Uint", lParam) 
} 

 ~#q::ExitApp

Edit: Applied correction below.

[waetherman]

That's awesome!
EDIT: It works on my Windows 10, apparently it doesn't work elsewhere, so it's less awesome now.
EDIT: Apparently it was fixed, so still pretty awesome.

[Masonjar13]

@Nextron, your code doesn't work (on Windows 8.1, 64-bit AHK); SetWindowsHookEx returns null, consistently. Haven't tried it on Windows 7 yet. Much too little sleep to figure out why right now, apparently.

[ChrisMiller]

Thank you both for your answers guys! I really appreciate it.
Sadly I dont get it

As far as I see waetherman's script is included in yours, Nextron. But Nextron's script does nothing for me. I dont get an error message but it also doesnt confine the cursor.
What am I doing wrong?

EDIT: @Masonjar13 Thanks for confirming, didnt know SetWindowsHookEx is the issue. I'm on Win7x64 fyi.

[Nextron]

I've kept the example the same as waetherman' script, that when holding down the right mouse button, the cursor should be confined (and Win+q to quit). For me it works with Win7, AHK 32-bit unicode. For 64 bit it's probably getting a 64-bit pointer to the callback function whereas the code uses only 32bits of it?

[qwerty12]

Replacing DllCall("GetModuleHandle", "Uint", 0) with 0 is enough to get it working on Windows 10 64-bit. Thanks for sharing, waetherman and Nextron.

[ChrisMiller]

Works perfectly on Windows 7 64bit aswell!

Big thanks to everyone!

[ItsGooglesFault]

How do you make this code run forever until the win+r key is hit?