Using AHK to Stop a Window from closing

[canisdibellum]

I want Autohotkey to monitor an Excel 2010 window for the Close Command, intercept and cancel the command, run a script, and then finally close the window.

I understand that OnClose and BeforeClose are existing commands in vba, but I canNOT use .xlsm (Macro-Enabled) worksheets and this is on at least 5 different workstations so Personal.xlsb isn't an option either.

I've found several references that vba is "easy" to translate to COM which I'm just learning how to use, but I've been beating my head against the keyboard for a week now and I can come up with no syntax that will let me monitor a window for the "Close" command.

I was thinking most recently, using OnMessage to monitor for the WM_CLOSE, but I cannot come up with the syntax for that either and Google has been useless, I can't even find anyone else asking about this! Please Help!

[Blackholyman]

try something like this

Code: Select all

oExcel := ComObjActive("Excel.Application")
oWorkbook := oExcel.ActiveWorkbook
ComObjConnect(oWorkbook, Workbook_Events)
return

class Workbook_Events 
{
	BeforeClose(Cancel)
	{
		msgbox % "closing"
	}
}

more

Code: Select all

oExcel := ComObjActive("Excel.Application")
oWorkbook := oExcel.ActiveWorkbook
ComObjConnect(oWorkbook, Workbook_Events)
return

class Workbook_Events 
{
	BeforeClose(Cancel)
	{
		; 0 == FALSE, -1 == TRUE 
		; typedef short VARIANT_BOOL
		
		;You can store a "true" value like so:
		NumPut(-1, ComObjValue(Cancel), "short")
		
		msgbox lets count to 100
		Loop 100
		{
			ToolTip %A_index%
			sleep 10
		}
		ToolTip
		
		; Used settimer to start a new thread 
		SetTimer, CloseExcel, -100
	}
}

CloseExcel()
{
	global oExcel, oWorkbook
	ComObjConnect(oWorkbook)
	oExcel.Quit
}

[canisdibellum]

try something like this

Code: Select all

oExcel := ComObjActive("Excel.Application")
oWorkbook := oExcel.ActiveWorkbook
ComObjConnect(oWorkbook, Workbook_Events)
return

class Workbook_Events 
{
	BeforeClose(Cancel)
	{
		msgbox % "closing"
	}
}

more

Code: Select all

oExcel := ComObjActive("Excel.Application")
oWorkbook := oExcel.ActiveWorkbook
ComObjConnect(oWorkbook, Workbook_Events)
return

class Workbook_Events 
{
	BeforeClose(Cancel)
	{
		; 0 == FALSE, -1 == TRUE 
		; typedef short VARIANT_BOOL
		
		;You can store a "true" value like so:
		NumPut(-1, ComObjValue(Cancel), "short")
		
		msgbox lets count to 100
		Loop 100
		{
			ToolTip %A_index%
			sleep 10
		}
		ToolTip
		
		; Used settimer to start a new thread 
		SetTimer, CloseExcel, -100
	}
}

CloseExcel()
{
	global oExcel, oWorkbook
	ComObjConnect(oWorkbook)
	oExcel.Quit
}

Thank you so much...never did get to test this, needs changed on me at the last minute.

Sorry to be so long in posting my gratitude, I was just going through my old forum posts and I realized I never responded Thanks again for your help