GUI Creation Topic is solved

Get help with using AutoHotkey (v1.1 and older) and its commands and hotkeys
Forum rules
Post Reply
nahom

GUI Creation

05 May 2016, 01:28

I have a ahk code with me which will open the highlighted text in different search sites when the "`" is pressed. It will provide 4 different search engine options below one another. Now i want to add another 6 sites, but i dont want to add it one below the other as it wont look look. Instead I would like to have it in a table format like 5 rows and 5 columns so it will be easy to use. How should i move the this option to appear in table form? Below is the code i have with me:

Code: Select all

;autoexecute part
Menu, Engines, Add, IMDB, IMDB
Menu, Engines, Add, HULU, HULU
Menu, Engines, Add, AMAZON, AMAZON
Menu, Engines, Add, GOOGLE, GOOGLE
Return
 
`::
Send ^c
ClipWait
Menu, Engines, Show
Return

 
IMDB:
Run, http://www.imdb.com/find?q=%clipboard%&s=tt ; opens the IMDB search results in your default browser
Clipboard =   
Return
 
HULU:
Run, http://www.hulu.com/search?q=%clipboard%
Clipboard =
Return

AMAZON:

aa:="http://www.amazon.com/s/ref=nb_sb_noss?url=search-alias%3Dinstant-video&field-keywords="
run,%aa%%clipboard%
return

GOOGLE:
Run, https://www.google.ie/?gws_rd=cr&ei=Pt0 ... 8bMsIAN#q=%clipboard%
Clipboard =
Return
Top
wolf_II
Posts: 2688
Joined: 08 Feb 2015, 20:55

Re: GUI Creation

05 May 2016, 04:02

Try this for multiple columns:

Code: Select all

;autoexecute part
Menu, Engines, Add, IMDB, IMDB
Menu, Engines, Add, HULU, HULU
Menu, Engines, Add, AMAZON, AMAZON
Menu, Engines, Add, GOOGLE, GOOGLE
Menu, Engines, Add, ENGINE_1, GOOGLE, +BarBreak
Menu, Engines, Add, ENGINE_2, GOOGLE
Menu, Engines, Add, ENGINE_3, GOOGLE
Menu, Engines, Add, ENGINE_4, GOOGLE
Menu, Engines, Add, ENGINE_5, GOOGLE
I hope that helps.

Edit: changed +Break to +BarBreak for better looks. Thanks to Xtra.
Last edited by wolf_II on 05 May 2016, 04:38, edited 1 time in total.
Top
User avatar
Xtra
Posts: 2750
Joined: 02 Oct 2015, 12:15

Re: GUI Creation

05 May 2016, 04:15

You can make separate glabels for each button or do like in this example:

Code: Select all

#NoEnv

; Row 1 :
Gui, Add, Button, x-4 y0 w70 h20 gButton, IMDB        ; Col 1
Gui, Add, Button, x66 y0 w70 h20 gButton, HULU        ; Col 2
Gui, Add, Button, x136 y0 w70 h20 gButton, AMAZON     ; Col 3
Gui, Add, Button, x206 y0 w70 h20 gButton, GOOGLE     ; Col 4
Gui, Add, Button, x276 y0 w70 h20 gButton, Button     ; Col 5
; Row 2 :
Gui, Add, Button, x-4 y20 w70 h20 gButton, Button     ; Col 1
Gui, Add, Button, x66 y20 w70 h20 gButton, Button     ; Col 2
Gui, Add, Button, x136 y20 w70 h20 gButton, Button    ; Col 3
Gui, Add, Button, x206 y20 w70 h20 gButton, Button    ; Col 4
Gui, Add, Button, x276 y20 w70 h20 gButton, Button    ; Col 5
; Row 3 :
Gui, Add, Button, x-4 y40 w70 h20 gButton, Button     ; Col 1
Gui, Add, Button, x66 y40 w70 h20 gButton, Button     ; Col 2
Gui, Add, Button, x136 y40 w70 h20 gButton, Button    ; Col 3
Gui, Add, Button, x206 y40 w70 h20 gButton, Button    ; Col 4
Gui, Add, Button, x276 y40 w70 h20 gButton, Button    ; Col 5
; Row 4 :
Gui, Add, Button, x-4 y60 w70 h20 gButton, Button     ; Col 1
Gui, Add, Button, x66 y60 w70 h20 gButton, Button     ; Col 2
Gui, Add, Button, x136 y60 w70 h20 gButton, Button    ; Col 3
Gui, Add, Button, x206 y60 w70 h20 gButton, Button    ; Col 4
Gui, Add, Button, x276 y60 w70 h20 gButton, Button    ; Col 5
; Row 5 :
Gui, Add, Button, x-4 y80 w70 h20 gButton, Button     ; Col 1
Gui, Add, Button, x66 y80 w70 h20 gButton, Button     ; Col 2
Gui, Add, Button, x136 y80 w70 h20 gButton, Button    ; Col 3
Gui, Add, Button, x206 y80 w70 h20 gButton, Button    ; Col 4
Gui, Add, Button, x276 y80 w70 h20 gButton, Button    ; Col 5
;-----------------------
Gui +ToolWindow -Caption                              ; Remove taskbar button and gui window title bar.

return
 
`::
    Send ^c
    ClipWait, 2
    if (ErrorLevel)    ; Do not show gui if clipboard is still empty after 2 seconds.
	    return
    Gui, Show, w346 h100, Engines
Return
 
Button:
    Gui, Submit
    if (A_GuiControl = "IMDB")
        Run, http://www.imdb.com/find?q=%clipboard%&s=tt ; opens the IMDB search results in your default browser
    else if (A_GuiControl = "HULU")
        Run, http://www.hulu.com/search?q=%clipboard%
    else if (A_GuiControl = "AMAZON")	
		run, http://www.amazon.com/s/ref=nb_sb_noss?url=search-alias`%3Dinstant-video&field-keywords=%clipboard%
	else if (A_GuiControl = "GOOGLE")
        Run, https://www.google.ie/?gws_rd=cr&ei=Pt0 ... 8bMsIAN#q=%clipboard%
    else
	{   ; Button not added , allow another gui choice:
		MsgBox,, Engine, This button not added yet!, 2
		Gui, Show, w346 h100, Engines
		return
	}
	Clipboard := ""
return

GuiClose:
ExitApp
Top
User avatar
Xtra
Posts: 2750
Joined: 02 Oct 2015, 12:15

Re: GUI Creation

05 May 2016, 04:29

@Wolf_II nice.. I somehow missed seeing that new feature from 1.1.23.00.
+BarBreak might look better to help break up the menu cols.
Top
wolf_II
Posts: 2688
Joined: 08 Feb 2015, 20:55

Re: GUI Creation

05 May 2016, 04:36

Xtra wrote:+BarBreak might look better to help break up the menu cols.
@Xtra: very good, I agree. I will edit my code above. Thank you.
Top
nahom

Re: GUI Creation

05 May 2016, 04:55

Thanks for the help guys..I will try both the codes and see how it looks
Top
garry
Posts: 3770
Joined: 22 Dec 2013, 12:50

Re: GUI Creation

05 May 2016, 06:47

an idea with different checkboxes and ini-file

Code: Select all

;- modified=20160505
;- mark text and press F8 / writes marked text to EditField ---------
;- or type in edit-field the word you want to search

#Warn
#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%
ftext=Mark_Text_and_press F8

F1=%a_scriptdir%\%ftext%.ini
ix=11                 ;- total checkboxes

src=tan soo suan+carmen      ;- TEST search for preselect

;GUI,2:+AlwaysOnTop
Gui,2: Color, ControlColor, Black
Gui,2: Font, CDefault, Lucida Console


Loop,%ix%
   {
   IniRead, Ch%A_Index%, %f1%, ss, Cb%A_Index% , 0
    If (Ch%A_Index% = 1)
       Cb%A_Index% = Checked
    Else
       Cb%A_Index% =
   }


Gui,2: Show, NA x100 y5 w300 h500, %ftext%
Gui,2: Add, Edit,      x20 y5  w265 h20 cWhite vSearchx,%src%

Gui,2:  Add, CheckBox, x20 y40  vCh1  %cb1%   cYellow, Google
Gui,2:  Add, CheckBox, x20 y65  vCh2  %cb2%   cYellow, Google  I``m feeling lucky
Gui,2:  Add, CheckBox, x20 y90  vCh3  %cb3%   cYellow, Bing    Pictures
Gui,2:  Add, CheckBox, x20 y115 vCh4  %cb4%   cYellow, Flickr  Pictures
Gui,2:  Add, CheckBox, x20 y140 vCh5  %cb5%   cYellow, Google  Pictures
Gui,2:  Add, CheckBox, x20 y165 vCh6  %cb6%   cYellow, Google  News
Gui,2:  Add, CheckBox, x20 y190 vCh7  %cb7%   cYellow, Google  News NL
Gui,2:  Add, CheckBox, x20 y215 vCh8  %cb8%   cYellow, Google  PDF
Gui,2:  Add, CheckBox, x20 y240 vCh9  %cb9%   cYellow, Google  Video
Gui,2:  Add, CheckBox, x20 y265 vCh10 %cb10%  cYellow, Youtube Video
Gui,2:  Add, CheckBox, x20 y290 vCh11 %cb11%  cYellow, Wikipedia

Gui,2:  Add, CheckBox, x20 y400 vCh98 gCheckAll   cYellow, Select All
Gui,2:  Add, CheckBox, x20 y425 vCh99 gUnCheckAll cYellow, De-Select All

Gui,2:  Add, Button,   x10 y465 w100 h26 gAA ,Start

GuiControl,2:Focus,Searchx
clipboard=
return



;----------------------------------------------------------


F8::
gui,2:submit,nohide
Send ^c                                      ;- copies marked text
IfWinNotActive,%ftext%, , WinActivate, %ftext%,
 WinWaitActive,%ftext%
sleep,900
GuiControl,2:,Searchx,
cl:=clipboard
cl=%cl%
GuiControl,2:,Searchx,%cl%
clipboard =
return

;------------------------------
CheckAll:
Loop, %ix%
    GuiControl,2:, Ch%A_Index%, 1
GuiControl,2:, Ch99, 0
Return
;------------------------------

UnCheckAll:
Loop, %ix%
    GuiControl,2:, Ch%A_Index%, 0
GuiControl,2:, Ch98, 0
Return
;------------------------------


;------------------------------
AA:
Gui,2: submit, nohide
c1=
c2=
stringsplit,c,searchx,`+
c1=%c1%
c2=%c2%
c1=`%22%c1%`%22
if c2<>
   {
   c2=`%22%c2%`%22
   stringreplace,c2,c2,%A_space%, +, All
   searchx=%c1% and %c2%
   }
else
   {
   stringreplace,c1,c1,%A_space%, +, All
   searchx=%c1%
   }

  if Ch1
    run,http://www.google.de/search?hl=&q=%searchx%
  if Ch2
    run,http://www.google.com/search?btnI=I`%27m+Feeling+Lucky&q=%searchx%
  if Ch3
    run,http://www.bing.com/images/search?q=%searchx%&FORM=HDRSC2
  if Ch4
    run,https://www.flickr.com/search/?q=%searchx%
  if Ch5
    run,https://www.google.com/search?q=%searchx%&tbm=isch
  if Ch6
    run,https://www.google.com/search?q=%searchx%#q=%searchx%&tbm=nws
  if Ch7
    run,https://www.google.com/search?q=%searchx%#q=%searchx%&tbm=nws&hl=nl  ;- hl=nl nederlands
  if Ch8
    run,http://www.google.de/search?hl=&q=%searchx% filetype:pdf
  if Ch9
    run,https://www.google.com/search?q=%searchx%#q=%searchx%&tbm=vid
  if Ch10
    run,http://www.youtube.com/results?search_query=%searchx%
  if Ch11
     {
     StringReplace,searchx,c1,+,%A_space%, All
     StringUpper,searchx,searchx,T
     StringReplace,searchx,searchx,%A_space%,_, All
     StringReplace,searchx,searchx,`%22, , All
     run, http://en.wikipedia.org/wiki/%searchx%
     }
c1=
c2=
return
;------------------------------

;------------------------------
2GuiClose:
Gui,2:  Submit,nohide
Loop,%ix%
   {
   ex= % ch%a_index%
   IniWrite, %ex%, %f1%, ss, Cb%a_index%
   }
ExitApp
;---------------------------------------------------------------
;===============================================================
Top
nahom

Re: GUI Creation

09 May 2016, 22:30

WOWwwwwwwwwwwww :shock:

This is awesome and looks super cool!! :clap:

Will try it out and post my doubts!!
Top
nahom

Re: GUI Creation  Topic is solved

10 May 2016, 01:39

I want to add the below sites instead of the default ones. I'm not sure how to include copied text in the hyperlinks in the given code. The highlighted text should open in the search pages of the below sites

Code: Select all

IMDB - 	 http://www.imdb.com
HULU - 	http://www.hulu.com/search?q=
AMAZON Video - 	http://www.amazon.com/s/ref=nb_sb_noss?url=search-alias%3Dinstant-video&field-keywords=
Google - 	 https://www.google.ie/?gws_rd=cr&ei=Pt0 ... 8bMsIAN#q=
Food Network- 	http://www.foodnetwork.com/
Life Time -	http://www.mylifetime.com/
Travel Channel	 - http://www.travelchannel.com/
HG TV - 	http://www.hgtv.com/
Showtime -	http://www.sho.com/
Crackle-	http://www.crackle.com/
HBO -	http://www.hbo.com/
Starz -	https://www.starz.com/
Yupp TV-	http://www.yupptv.com/
Google translator
Top
User avatar
Xtra
Posts: 2750
Joined: 02 Oct 2015, 12:15

Re: GUI Creation

10 May 2016, 03:09

I'll do one:

Google Translator English to Spanish:

Code: Select all

Run, https://translate.google.com/#en/es/%clipboard%
Top
nahom

Re: GUI Creation

10 May 2016, 03:20

Thanks! I take that the same method can be followed for other links?
Top
User avatar
Xtra
Posts: 2750
Joined: 02 Oct 2015, 12:15

Re: GUI Creation

10 May 2016, 03:27

They will not be all the same you will need to check them.

Example Food Network:

Code: Select all

Run, http://www.foodnetwork.com/search/search-results.html?searchTerm=%clipboard%&form=global&_charset_=UTF-8
There that's 2 done...
Top
nahom

Re: GUI Creation

10 May 2016, 03:49

OK I ll do it accordingly and keep this thread updated
Top
nahom

Re: GUI Creation

10 May 2016, 04:31

I used the below code and there were several error throwing up once the webpages opened. Also when I run the script after i close it, it opens with check boxes checked from previous instance.

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

;- modified=20160505
;- mark text and press F8 / writes marked text to EditField ---------
;- or type in edit-field the word you want to search
 
#Warn
#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%
ftext=Mark_Text_and_press F8
 
F1=%a_scriptdir%\%ftext%.ini
ix=11                 ;- total checkboxes
 
src=     ;- TEST search for preselect
 
;GUI,2:+AlwaysOnTop
Gui,2: Color, ControlColor, Black
Gui,2: Font, CDefault, Lucida Console
 
 
Loop,%ix%
   {
   IniRead, Ch%A_Index%, %f1%, ss, Cb%A_Index% , 0
    If (Ch%A_Index% = 1)
       Cb%A_Index% = Checked
    Else
       Cb%A_Index% =
   }
 
 
Gui,2: Show, NA x100 y5 w300 h500, %ftext%
Gui,2: Add, Edit,      x20 y5  w265 h20 cWhite vSearchx,%src%
 
Gui,2:  Add, CheckBox, x20 y40  vCh1  %cb1%   cYellow, IMDB
Gui,2:  Add, CheckBox, x20 y65  vCh2  %cb2%   cYellow, HULU
Gui,2:  Add, CheckBox, x20 y90  vCh3  %cb3%   cYellow, AMAZON VIDEO
Gui,2:  Add, CheckBox, x20 y115 vCh4  %cb4%   cYellow, GOOGLE
Gui,2:  Add, CheckBox, x20 y140 vCh5  %cb5%   cYellow, FOOD NETWORK
Gui,2:  Add, CheckBox, x20 y165 vCh6  %cb6%   cYellow, Travel CHANNEL
Gui,2:  Add, CheckBox, x20 y190 vCh7  %cb7%   cYellow, HG TV
Gui,2:  Add, CheckBox, x20 y215 vCh8  %cb8%   cYellow, SHOWTIME
Gui,2:  Add, CheckBox, x20 y240 vCh9  %cb9%   cYellow, HBO
Gui,2:  Add, CheckBox, x20 y265 vCh10 %cb10%  cYellow, YUPPTV
Gui,2:  Add, CheckBox, x20 y290 vCh11 %cb11%  cYellow, GOOGLE TRANSLATOR
 
Gui,2:  Add, CheckBox, x20 y400 vCh98 gCheckAll   cYellow, Select All
Gui,2:  Add, CheckBox, x20 y425 vCh99 gUnCheckAll cYellow, De-Select All
 
Gui,2:  Add, Button,   x10 y465 w100 h26 gAA ,Start
 
GuiControl,2:Focus,Searchx
clipboard=
return
 
 
 
;----------------------------------------------------------
 
 
F8::
gui,2:submit,nohide
Send ^c                                      ;- copies marked text
IfWinNotActive,%ftext%, , WinActivate, %ftext%,
 WinWaitActive,%ftext%
sleep,900
GuiControl,2:,Searchx,
cl:=clipboard
cl=%cl%
GuiControl,2:,Searchx,%cl%
clipboard =
return
 
;------------------------------
CheckAll:
Loop, %ix%
    GuiControl,2:, Ch%A_Index%, 1
GuiControl,2:, Ch99, 0
Return
;------------------------------
 
UnCheckAll:
Loop, %ix%
    GuiControl,2:, Ch%A_Index%, 0
GuiControl,2:, Ch98, 0
Return
;------------------------------
 
 
;------------------------------
AA:
Gui,2: submit, nohide
c1=
c2=
stringsplit,c,searchx,`+
c1=%c1%
c2=%c2%
c1=`%22%c1%`%22
if c2<>
   {
   c2=`%22%c2%`%22
   stringreplace,c2,c2,%A_space%, +, All
   searchx=%c1% and %c2%
   }
else
   {
   stringreplace,c1,c1,%A_space%, +, All
   searchx=%c1%
   }
 
  if Ch1
    run, http://www.imdb.com/find?q=%searchx%&s=tt
  if Ch2
    run,http://www.hulu.com/search?q=%searchx%
  if Ch3
    aa:="http://www.amazon.com/s/ref=nb_sb_noss?url=search-alias%3Dinstant-video&field-keywords="
run,%searchx%
  if Ch4
    run,https://www.google.ie/?gws_rd=cr&ei=Pt0 ... 8bMsIAN#q=%searchx%
  if Ch5
    run,http://www.foodnetwork.com/search/search-results.html?searchTerm=%searchx%&form=global&_charset_=UTF-8
  if Ch6
    run,http://www.travelchannel.com/search.html/%searchx%
  if Ch7
    run,http://www.hgtv.com/search/%searchx%-
  if Ch8
    run,http://www.sho.com/sho/search?q=%searchx%
  if Ch9
    run,http://www.hbo.com/search?q=%searchx%
  if Ch10
    run,http://www.yupptv.com/search.aspx?q=%searchx%
  if Ch11
    run, https://translate.google.com/#en/es/%searchx%
c1=
c2=
return
;------------------------------
 
;------------------------------
2GuiClose:
Gui,2:  Submit,nohide
Loop,%ix%
   {
   ex= % ch%a_index%
   IniWrite, %ex%, %f1%, ss, Cb%a_index%
   }
ExitApp
;---------------------------------------------------------------
;===============================================================
Top
garry
Posts: 3770
Joined: 22 Dec 2013, 12:50

Re: GUI Creation

10 May 2016, 05:35

... it opens with check boxes checked from previous instance
you can remove iniread / iniwrite part
try original search and replace the part searched words with %searchx%
see also failure in 'if ch3'

; if Ch4
; run,https://www.google.ie/search?q=%searchx%

Code: Select all

;-------- saved at Dienstag, 10. Mai 2016 12:22:46 --------------
;-------- https://autohotkey.com/boards/viewtopic.php?f=5&t=17484 ---
#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

;- modified=20160505
;- mark text and press F8 / writes marked text to EditField ---------
;- or type in edit-field the word you want to search

#Warn
#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%
ftext=Mark_Text_and_press F8

F1=%a_scriptdir%\%ftext%.ini
ix=11                 ;- total checkboxes

src=     ;- TEST search for preselect

;GUI,2:+AlwaysOnTop
Gui,2: Color, ControlColor, Black
Gui,2: Font, CDefault, Lucida Console


Loop,%ix%
   {
   IniRead, Ch%A_Index%, %f1%, ss, Cb%A_Index% , 0
    If (Ch%A_Index% = 1)
       Cb%A_Index% = Checked
    Else
       Cb%A_Index% =
   }


Gui,2: Show, NA x100 y5 w300 h500, %ftext%
Gui,2: Add, Edit,      x20 y5  w265 h20 cWhite vSearchx,%src%

Gui,2:  Add, CheckBox, x20 y40  vCh1  %cb1%   cYellow, IMDB
Gui,2:  Add, CheckBox, x20 y65  vCh2  %cb2%   cYellow, HULU
Gui,2:  Add, CheckBox, x20 y90  vCh3  %cb3%   cYellow, AMAZON VIDEO
Gui,2:  Add, CheckBox, x20 y115 vCh4  %cb4%   cYellow, GOOGLE
Gui,2:  Add, CheckBox, x20 y140 vCh5  %cb5%   cYellow, FOOD NETWORK
Gui,2:  Add, CheckBox, x20 y165 vCh6  %cb6%   cYellow, Travel CHANNEL
Gui,2:  Add, CheckBox, x20 y190 vCh7  %cb7%   cYellow, HG TV
Gui,2:  Add, CheckBox, x20 y215 vCh8  %cb8%   cYellow, SHOWTIME
Gui,2:  Add, CheckBox, x20 y240 vCh9  %cb9%   cYellow, HBO
Gui,2:  Add, CheckBox, x20 y265 vCh10 %cb10%  cYellow, YUPPTV
Gui,2:  Add, CheckBox, x20 y290 vCh11 %cb11%  cYellow, GOOGLE TRANSLATOR

Gui,2:  Add, CheckBox, x20 y400 vCh98 gCheckAll   cYellow, Select All
Gui,2:  Add, CheckBox, x20 y425 vCh99 gUnCheckAll cYellow, De-Select All

Gui,2:  Add, Button,   x10 y465 w100 h26 gAA ,Start

GuiControl,2:Focus,Searchx
clipboard=
return



;----------------------------------------------------------


F8::
gui,2:submit,nohide
Send ^c                                      ;- copies marked text
IfWinNotActive,%ftext%, , WinActivate, %ftext%,
 WinWaitActive,%ftext%
sleep,900
GuiControl,2:,Searchx,
cl:=clipboard
cl=%cl%
GuiControl,2:,Searchx,%cl%
clipboard =
return

;------------------------------
CheckAll:
Loop, %ix%
    GuiControl,2:, Ch%A_Index%, 1
GuiControl,2:, Ch99, 0
Return
;------------------------------

UnCheckAll:
Loop, %ix%
    GuiControl,2:, Ch%A_Index%, 0
GuiControl,2:, Ch98, 0
Return
;------------------------------


;------------------------------
AA:
Gui,2: submit, nohide
c1=
c2=
stringsplit,c,searchx,`+
c1=%c1%
c2=%c2%
c1=`%22%c1%`%22   ;- "text1 text2"  means exact search , if desactivated then means search for  >  ' text1 and text2 ' 
if c2<>
   {
   c2=`%22%c2%`%22
   stringreplace,c2,c2,%A_space%, +, All
   searchx=%c1% and %c2%
   }
else
   {
   stringreplace,c1,c1,%A_space%, +, All
   searchx=%c1%
   }

  if Ch1
    run, http://www.imdb.com/find?q=%searchx%&s=tt
  if Ch2
    run,http://www.hulu.com/search?q=%searchx%
  if Ch3
    {
    aa:="http://www.amazon.com/s/ref=nb_sb_noss?url=search-alias%3Dinstant-video&field-keywords="
    run,%aa%%searchx%
    }
  if Ch4
    run,https://www.google.ie/search?q=%searchx%
  if Ch5
    run,http://www.foodnetwork.com/search/search-results.html?searchTerm=%searchx%&form=global&_charset_=UTF-8
  if Ch6
    run,http://www.travelchannel.com/search.html/%searchx%
  if Ch7
    run,http://www.hgtv.com/search/%searchx%
  if Ch8
    run,http://www.sho.com/sho/search?q=%searchx%
  if Ch9
    run,http://www.hbo.com/search?q=%searchx%
  if Ch10
    run,http://www.yupptv.com/search.aspx?q=%searchx%
  if Ch11
    run, https://translate.google.com/#en/es/%searchx%
c1=
c2=
return
;------------------------------

;------------------------------
2GuiClose:
Gui,2:  Submit,nohide
;Loop,%ix%
;   {
;   ex= % ch%a_index%
;   IniWrite, %ex%, %f1%, ss, Cb%a_index%
;   }
ExitApp
;---------------------------------------------------------------
;===============================================================
Last edited by garry on 11 May 2016, 13:16, edited 1 time in total.
Top
nahom

Re: GUI Creation

10 May 2016, 05:54

I want the check box to rest every time F8 is pressed. Also, the highlighted text comes enclosed with quotes. Can you pls help me with this?
Top
nahom

Re: GUI Creation

10 May 2016, 05:56

---------------------------Correction-----------------------------------

I want the check box to reset every time start button is pressed. Also, the highlighted text comes enclosed with quotes. Can you pls help me with this?
Top
garry
Posts: 3770
Joined: 22 Dec 2013, 12:50

Re: GUI Creation

10 May 2016, 06:13

desactivate :
;c1=`%22%c1%`%22 ;- "test text"
Top
nahom

Re: GUI Creation

10 May 2016, 23:15

where should i write the above code?
Top
garry
Posts: 3770
Joined: 22 Dec 2013, 12:50

Re: GUI Creation

11 May 2016, 13:20

see script above
if commandline begins with ' ; ' means it has no function ( used for comments )

Code: Select all

;c1=`%22%c1%`%22   ;- "text1 text2"  means exact search , if desactivated then means search for    ' text1 or text2 '
Top
Post Reply

Return to “Ask for Help (v1)”

Who is online

Users browsing this forum: Araphen, Bing [Bot], Peiya, ShatterCoder and 311 guests