SHFileOperation -> IFileOperation conversion?

[zcooler]

Hello!

Im using this external version of the SHFileOperation (written by just me) in order to keep my GUI operational during file moves/copy of very large files, which has been working nicely up to now. Lately I have come across some issues with it (or rather more correct a lacking of feature). I do like to sort files using created date attribute and this attribute vanishes in cross-volume copy operations. Im abled to workaround that with some awkward coding, but instead of using messy workarounds I was wondering if anyone might be interested in converting it to the more modern IFileOperation, which supports the FOFX_MOVEACLSACROSSVOLUMES (0x02000000) flag which allows "copy the security attributes of the source item to the destination item when performing a cross-volume move operation. Without this flag, the destination item receives the security attributes of its new folder"? This c++ stuff is so over my head.
https://msdn.microsoft.com/en-us/librar ... s.85).aspx

Spoiler

Code: Select all

#NoEnv
#NoTrayIcon
; Example:
; 	Save this file to ParamToObj_Sample.ahk, then run with parameters:
; 		ParamToObj_Sample.ahk /x 20 -novalue1 -y 14 /novalue2 --width=710 --novalue3 --height 90 WillBeIgnored /title:"hi !"
; 	The result will be:
; 		param.height = 90
; 		param.novalue1 = 
; 		param.novalue2 = 
; 		param.novalue3 = 
; 		param.title = hi !
; 		param.width = 710
; 		param.x = 20
; 		param.y = 14
param := ParamToObj()
;For k, v in param
;	param_list .= "param." k " = " v "`n"	
;MsgBox, % param_list
FileArray := []
DropEffect := param.DropEffect
TargetPath := param.FolderPath
DropFile := param.DroppedFiles
If (DropFile = "") {
  FileRead, DroppedFiles, % A_ScriptDir . "\DroppedList.txt"
  Loop, Parse, DroppedFiles, `n, `r
	FileArray.Push(A_LoopField)
  SHFileOperation(FileArray, TargetPath, DropEffect ^ 3, 0x0400)
  FileDelete, % A_ScriptDir . "\DroppedList.txt"
}
Else
  SHFileOperation(DropFile, TargetPath, DropEffect ^ 3, 0x0400)  
; ==================================================================================================================================
ParamToObj() {
	global 0
	obj := {}
 
	Loop, %0%
	{
		param := %A_Index%
		If RegExMatch(param, "^(/|-)+(\w+)(\W(.+))?$", match) {
			obj[match2] := match4
			key         := match2
		}
		Else If (key != "")
			obj[key] := param, key := ""
	}
 
	Return obj
}
; ==================================================================================================================================
; Copies, moves, renames, or deletes a file system object using the SHFileOperation() function.
; SHFileOperation -> msdn.microsoft.com/en-us/library/bb762164(v=vs.85).aspx
; Parameters:
;     Sources        -  A string containing a list of fully qualified source pathes separated by `n if needed
;                       or an array of fully qualified source pathes.
;     Targets        -  A string containing a list of fully qualified target pathes separated by `n if needed
;                       or an array of fully qualified target pathes.
;     Operation      -  A value that indicates which operation to perform. One of the following values:
;                          FO_MOVE     = 1
;                          FO_COPY     = 2
;                          FO_DELETE   = 3
;                          FO_RENAME   = 4
;     Flags          -  Any reasonable combination of the FOF_ flags -> msdn.microsoft.com/en-us/library/bb759795(v=vs.85).aspx
;                          FOF_MULTIDESTFILES         = 0x0001
;                          FOF_CONFIRMMOUSE           = 0x0002
;                          FOF_SILENT                 = 0x0004
;                          FOF_RENAMEONCOLLISION      = 0x0008
;                          FOF_NOCONFIRMATION         = 0x0010
;                          FOF_WANTMAPPINGHANDLE      = 0x0020
;                          FOF_ALLOWUNDO              = 0x0040
;                          FOF_FILESONLY              = 0x0080
;                          FOF_SIMPLEPROGRESS         = 0x0100
;                          FOF_NOCONFIRMMKDIR         = 0x0200
;                          FOF_NOERRORUI              = 0x0400
;                          FOF_NOCOPYSECURITYATTRIBS  = 0x0800
;                          FOF_NORECURSION            = 0x1000
;                          FOF_NO_CONNECTED_ELEMENTS  = 0x2000
;                          FOF_WANTNUKEWARNING        = 0x4000
;                          FOF_NO_UI                  = 0x0614
;                       Default: FOF_NOCONFIRMMKDIR (0x0200)
;     HWND           -  A handle to the window which will own the dialog.
;                       Default: 0
;     MappedFiles    -  Optional ByRef Variable to return an array of files which were renamed because of name collisions  
;                       if the FOF_RENAMEONCOLLISION and FOF_WANTMAPPINGHANDLE flags were specified. Each array element
;                       provides the keys OldPath and NewPath.
; Return values:
;     Returns 1 (True) if successful, otherwise 0 (False).
;     ErrorLevel is set to non-zero (True) if if any file operations were aborted before they were completed.
; Remarks:
;     You cannot rename multiple files with a single function call. Use FO_MOVE instead.
; ==================================================================================================================================
SHFileOperation(Sources, Targets, Operation, Flags := 0x0200, HWND := 0, ByRef MappedFiles := "") {
   ; Special file operation flags
   Static FOF_MULTIDESTFILES    := 0x0001
        , FOF_RENAMEONCOLLISION := 0x0008
        , FOF_WANTMAPPINGHANDLE := 0x0020
        , FOF_SIMPLEPROGRESS    := 0x0100
   Static TCS := A_IsUnicode ? 2 : 1 ; size of a TCHAR
   If Operation Not Between 1 And 4
      Return False
   ; Count source pathes and total string length
   TotalLength := 0
   Files := []
   If IsObject(Sources) {
      For Each, FilePath In Sources {
         If (Length := StrLen(FilePath))
            Files.Push({Path: FilePath, Len: Length + 1})
         TotalLength += Length
      }
   }
   Else {
      Loop, Parse, Sources, `n
      {
         If (Length := StrLen(A_LoopField))
            Files.Push({Path: A_LoopField, Len: Length + 1})
         TotalLength += Length
      }
   }
   FileCount := Files.Length()
   If !(FileCount && TotalLength)
      Return False
   ; Store the source pathes in Sources (the string must be double-null terminated)
   VarSetCapacity(Sources, (TotalLength + FileCount + 1) * TCS, 0)
   Offset := 0
   For Each, File In Files
      Offset += StrPut(File.Path, &Sources + Offset, File.Len) * TCS
   ; Count target pathes and total string length
   TotalLength := 0
   Files := []
   If IsObject(Targets) {
      For Each, FilePath In Targets {
         If (Length := StrLen(FilePath))
            Files.Push({Path: FilePath, Len: Length + 1})
         TotalLength += Length
      }
   }
   Else {
      Loop, Parse, Targets, `n
      {
         If (Length := StrLen(A_LoopField))
            Files.Push({Path: A_LoopField, Len: Length + 1})
         TotalLength += Length
      }
   }
   FileCount := Files.Length()
   ; Operations other than FO_DELETE require a target path
   If !(FileCount && TotalLength) && (Operation <> 3)
      Return False
   ; Store the target pathes in Targets (the string must be double-null terminated)
   VarSetCapacity(Targets, (TotalLength + FileCount + 1) * TCS, 0)
   Offset := 0
   For Each, File In Files
      Offset += StrPut(File.Path, &Targets + Offset, File.Len) * TCS
   ; Set FOF_MULTIDESTFILES if necessary
   If (FileCount > 1)
      Flags |= FOF_MULTIDESTFILES
   ; Check for FOF_SIMPLEPROGRESS to set the the title of the progress dialog box.
   If (Flags & FOF_SIMPLEPROGRESS)
      Title := A_ScriptName
   Else
      Title := ""
   ; Create and fill the SHFILEOPSTRUCT
   SHFOSSize := A_PtrSize * (A_PtrSize = 8 ? 7 : 8)
   VarSetCapacity(SHFOS, SHFOSSize, 0) ; SHFILEOPSTRUCT
   NumPut(HWND, SHFOS, 0, "UPtr")                     ; hwnd
   NumPut(Operation, SHFOS, A_PtrSize, "UInt")        ; wFunc
   NumPut(&Sources, SHFOS, A_PtrSize * 2, "UPtr")     ; pFrom
   NumPut(&Targets, SHFOS, A_PtrSize * 3, "UPtr")     ; pTo
   NumPut(Flags, SHFOS, A_PtrSize * 4, "UInt")        ; fFlags
   NumPut(&Title, SHFOS, 8 + (A_PtrSize * 5), "UPtr") ; lpszProgressTitle
   If (A_IsUnicode)
      RetVal := !DllCall("Shell32.dll\SHFileOperationW", "Ptr", &SHFOS, "Int")
   Else
      RetVal := !DllCall("Shell32.dll\SHFileOperationA", "Ptr", &SHFOS, "Int")
   ; Check for name collisions
   If IsByRef(MappedFiles) && (Flags & FOF_RENAMEONCOLLISION) && (Flags & FOF_WANTMAPPINGHANDLE) {
      If (MapPointer := NumGet(SHFOS, 8 + (A_PtrSize * 4), "UPtr")) {
         If (MapCount := NumGet(MapPointer + 0, "UInt")) {
            MappedFiles := []
            ArrayPointer := NumGet(MapPointer + A_PtrSize, "UPtr")
            Loop, %MapCount% {
               OldLen := NumGet(ArrayPointer + 0, A_PtrSize * 2, "Int")
               OldPath := StrGet(NumGet(ArrayPointer + 0, "UPtr"), OldLen, "UTF-16")
               NewLen := NumGet(ArrayPointer + 4, A_PtrSize * 2, "Int")
               NewPath := StrGet(NumGet(ArrayPointer + A_PtrSize, "UPtr"), NewLen, "UTF-16")
               MappedFiles.Push({OldPath: OldPath, NewPath: NewPath})
               ArrayPointer += 8 + (A_PtrSize * 2)
            }
         }
         DllCall("Shell32.dll\SHFreeNameMappings", "Ptr", MapPointer)
      }
   }
   ErrorLevel := NumGet(SHFOS, 4 + (A_PtrSize * 4), "UInt")
   Return RetVal
}

[zcooler]

Oh man! MS has developed their IFileOperation function even further, which i noticed during copy of two individually separated copy oprerations. Only one dialog was used in this case (instead of opening two separate dialogs like the SHFileOperation does) where each operation was stacked in a scrollable list within the dialog. Pretty cool I have to say

So again are anyone willing/qualified to build an AHK function of the IFileOperation? Unfortunatley the smartest one in here (@just me) doesnt involve himself in the hardest MS integration stuff, which elevates whats possible to do with AHK to much higher levels, as he used to and the old AHK dragons (which produced fantastic stuff, but in many areas dated) are hardly active anymore (the likes of SKAN), which sadly slows down progress of AHK. Guys like that (who have the ability to revolutionize/elevate the language) do not seem to come around that often. It might be time to start investigating a second language, cuz I dont see how V2 elevates the AHK experience the slightest (to me it just appears as an continuously ongoing syntax squabble). It sure looks like Im never going to use V2 at all (too much hassle with converting already made scripts). Haha...well with this kind of reflection Im never gonna get any help with this, but who cares! There are no takers anyway

[jeeswg]

- Once in every lifetime, comes a COM object job like this. Or for me, two of them, two object implementations, and tutorial links, which I mentioned as possible templates for DigiDon:
RichEdit : New Features to All - AutoHotkey Community
https://autohotkey.com/boards/viewtopic ... 61#p198061
- Sometimes the pain of anticipation of how difficult it's going to be, is worse than actually doing it. I usually work out a list of what I want to investigate, research and test, and then ask questions if I get stuck.
- I would recommend to have a go, and ask questions along the way.
- It would be a good idea to try and produce here, a list of all the interfaces and methods, that you think you are going to need. If people have some idea of your objective, it'll be easier to help. Also, it might turn out that some of what you want has already been partially done by other people, or that it ties in/overlaps with something that they've wanted to do, meaning that they already have some degree of motivation.

[zcooler]

@jeeswg, your motivation to help people and the desire/drive to elevate AHK as a language is admirable. Imagine what AHK would be like if that motivation and drive would match your COM object programming skills Regarding myself im an intermediate AHK user, but an absolute beginner when it comes to DLL calls. So starting to develop AHK COM objects functions out of the blue is very far fetched. Heck, when studying @just me`s dragndrop COM interface makes my head feel dizzy.

More interestingly, when reading about @DigiDon`s adventures where he managed to successfully convert an AutoIt COM object class to AHK, which makes me wonder...why has AutoIt come so much further compared to AHK! Do they pay for COM object classes or what? If not what makes AutoIt more interesting for the absolutely most knowledgable programmers who amongst others also are abled to do COM object programming. And what in the world are the best AHK programmers we have thinking (just me excluded) when they are not motivated to bring AHK to the absolute forefront? Pretty much useless I say, except for AHK newbies AHK is in dire straits if the most knowledgable guy of them all are forced to syntax tinker with v2 and fix petty bugs in v1, in the same time AutoIt and others are passing by faster then hell. The need to investigate AutoIt for the first time is here. I cant come any further with my applications using AHK, which makes me sad cuz AHK (as my first language) is very dear to me.

[just me]

Back to the roots:

I do like to sort files using created date attribute and this attribute vanishes in cross-volume copy operations. Im abled to workaround that with some awkward coding, but instead of using messy workarounds I was wondering if anyone might be interested in converting it to the more modern IFileOperation, which supports the FOFX_MOVEACLSACROSSVOLUMES (0x02000000) flag ...

Access Control Lists have nothing to do with the 'created date attribute'.

[jeeswg]

- How much evidence do you have that AutoIt is progressing faster? I don't have any information on this. (Maybe sometimes AutoIt people think, I wish we had that AutoHotkey feature/script.) Personally, AutoHotkey has all the functionality I need, it's just a question of completing my projects.
- We are in the age of COM, and we need to attract/grow more COM programmers. I'm going to add a bit more on object implementation to my objects tutorial, and do beginner/DllCall/mathematics/other tutorials, to get more people/experts into AutoHotkey.
- This might be useful for learning DllCall for now:
AutoHotkey via DllCall: AutoHotkey functions as custom functions - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=7&t=37871
- just me's library is difficult only because it's large. Take the hello world approach: you find a way 'in' to an interface, and then you implement one method. To understand the library better, list all of the interfaces/methods/CLSIDs, and look them up on MSDN, that's mostly what you'd need to do.
- Do outline what interfaces/methods you are interested in, and your goals.

[zcooler]

Back to the roots:

I do like to sort files using created date attribute and this attribute vanishes in cross-volume copy operations. Im abled to workaround that with some awkward coding, but instead of using messy workarounds I was wondering if anyone might be interested in converting it to the more modern IFileOperation, which supports the FOFX_MOVEACLSACROSSVOLUMES (0x02000000) flag ...

Access Control Lists have nothing to do with the 'created date attribute'.

Oh crap, a classic zcooler misunderstanding Well, its not the first time

FOFX_MOVEACLSACROSSVOLUMES (0x02000000)

Copy the security attributes of the source item to the destination item when performing a cross-volume move operation. Without this flag, the destination item receives the security attributes of its new folder.

I thought it sounded spot on if crossing out "security" Didnt know the meaning of a security attribute, but does now, thanks! Right now im writing over all file attributes for copied files in destination when SHFileOperation is done. I dont know how to do it in any other way and should not SHFileOp or IFileOperation take care of the cross-volume copy case in some way in the first place?

Code: Select all

  If (DropEffect = 1) {
   For k, v in FileArray {
	  FileGetTime, CreatedTime, % v, C
	  SplitPath, v, FileName
	  File := {FilNamn: FileName, CTime: CreatedTime, DestDir: TargetPath}
	  FileSetTime, % File.CTime, % File.DestDir "\" File.FilNamn, C, 1, 0 ; 20170623 sets the old created date for copied files.
   }
  }

- How much evidence do you have that AutoIt is progressing faster? I don't have any information on this. (Maybe sometimes AutoIt people think, I wish we had that AutoHotkey feature/script.) Personally, AutoHotkey has all the functionality I need, it's just a question of completing my projects.
- We are in the age of COM, and we need to attract/grow more COM programmers. I'm going to add a bit more on object implementation to my objects tutorial, and do beginner/DllCall/mathematics/other tutorials, to get more people/experts into AutoHotkey.
- This might be useful for learning DllCall for now:
AutoHotkey via DllCall: AutoHotkey functions as custom functions - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=7&t=37871
- just me's library is difficult only because it's large. Take the hello world approach: you find a way 'in' to an interface, and then you implement one method. To understand the library better, list all of the interfaces/methods/CLSIDs, and look them up on MSDN, that's mostly what you'd need to do.
- Do outline what interfaces/methods you are interested in, and your goals.

I do not have any evidence, that is what I intend to find out. I just assumed AutoIt has progressed faster based on the fact when they are doing classes (DigiDon example) out of COM Obejcts they have nailed it pretty well, which makes it easier (my assumption again) for others to build upon and develop further with other COM objects. Other than that I think these listed points are awesome, even though I have no idea how you are going to attract COM object programmers into AHK. Im quite possitive folks with these kind of skills do not involve themselves in a free scripting language, which has always been profiling itself as easy to learn and for newbies. Its as of late when lexikos took over it has become the awesome flully fledged and powerful language it is today. But doing what you are doing is defintely the right track, motivating and supporting the people already into AHK. Also you never know if contributions from a few shining stars (like the one im adressing above) might arrive, and if so its a party