GUI media launch bar

[zcooler]

Hi!

I don't know if AHK GUI is flexible enough to do a media launch bar. Just began studying GUI and it seems not.
I was imagine having a simple bar just wide enough to fit 4 buttons. Each button when pressed shows a dropdownlist containing mediafiles which is in a folder. First stumble was how to show folder contents inside a dropdownlist and how to make it dynamically adjust dropdownlists width and height depending on how many files there are in the folder and depending on the width of the filenames. Also if dropdownlist are higher than vertical screen resolution (height) make it scrollable. The goal was also to have a sorting function where it is possible to sort the files in ascending/descending and in alphabetical order. Hmm...this was harder than expected!

Perhaps anyone has pointers for me?

Regards
zcooler

[Masonjar13]

Sounds do-able. I created something similar, but in a listview.

To change the choice or add/remove entries from the list after the control has been created, use GuiControl.

For dynamic width, you could parse the folder and grab the longest name, then set the width based off that. Afaik, if you specify a row-count for the ddl, it will automatically implement a scroll-bar if the contents exceed the given rows. Ddl has a built-in sort function.

Reference: http://ahkscript.org/docs/commands/GuiC ... opDownList

[zcooler]

Hi Masonjar13!

Oh, so this thing I wanna do is actually possible with GUI and DDL! Thank you very much for the information. That definitely encourage me to invest the needed time to figure it out. I'll see it as a long-time-to-learn project.

Regards
zcooler

[zcooler]

Hi guys!

Ok, I have now made something that resembles a Media Launch bar gui. Its pretty awful looking, but havent got to the part how to make it nicer yet. Im now struggeling on two and a half problems, which i simply cannot find anything written about in my searches. I am starting to suspect they might be hard to solve as long as using DropDownLists (maybe I should go the html way instead). Anyway the mediafiles can now be launched from all dropdownlists by either click or drag n drop. Getting Dropdownlist much wider compared to the actual DDL button turned out to be solvable (thanks "just me"). The list now displays the full filename width. Haven got it to autoadjust the DDL width after longest filename yet, but it should be possible somehow. The nicest thing is i can sort the files in any order i want and that is great (the only reason for abandoning Windows taskbar toolbars) Its also nice to combine the launch bar with tools such as Copy/Move Files.
The remaining problems im trying to find solutions for are:

(1)
AHK are lacking DropDownButtons and when using the closest equivalence "dropdownlists" i wanna have a static title for the DDL. Only way was to use two pipes signs to get a title. That title also shows up in the actual list according to DDL specifications. Is there a way to prevent it to showing up there? Also the file clicked/launched to not replace DDL title and show up in DDL control (always keep title static like a button).

(2)
Next I can display sub-folders in the DropDownList folder im looping (New Movies) by including folders and recursing. The result is not very pleasing to the eyes though (i get a view of all files). The folder name does not show up and it can be hard to know which movie it is, cuz often the full movie titles are in the foldername and the filename are often a shortname. Windows taskbar toolbars do show sub-folders as yellow maps which can in next turn be recursed into by mouse hovering over foldername and ">" and that sub-folder pops up a new DDL displaying the file contents just for this sub-folder. Is that possible with AHK gui?

(2 1/2)
When drag n drop files from DDL onto for example the VLC player Windows usually displays a little tooltip displaying a small, what can be described as a dragndrop, icon just beside the mousepointer. With my DDL there is nothing displayed when doing the dragndrop, but most importantly drag n drop works.
Does anyone know how to display that icon?

EDIT: Oh, I have two more questions! Is it possible to make the files in the DDL editable (right click menu delete, copy and paste) and manual drag n drop sorting? That is just for editboxes yes?

Here is the script:

Spoiler

Code: Select all

#NoEnv
;--------------------------
;Media players
TSPlayer := "D:\AHK_Scripts\TSPlayer\TSPlayer Script.exe"
VLCPlayer := "D:\AHK_Scripts\VLC-Player\VLC-Playerscript.exe"
;Media folders
RSFolder := "D:\TV\Recording Service"
NMFolder := "D:\Ny Download\Nya Filmer"
ERFolder := "D:\Edited Recordings"
SRFolder := "D:\TV\Seen Recordings"
;--------------------------
CB_SETDROPPEDWIDTH := 0x0160
Gui, +Resize
Gui, Add, DDL, x10 y10 w112 h30 r60 vRecordingService hwndhcbx gRecordingService,  Recording Service||Movies
SendMessage, CB_SETDROPPEDWIDTH, 700, 0, , ahk_id %hcbx%
Gui, Add, DDL, x+10 w81 h30 r60 vNewMovies hwndnm gNewMovies, New Movies||
SendMessage, CB_SETDROPPEDWIDTH, 500, 0, , ahk_id %nm%
Gui, Add, DDL, x+10 w111 h30 r60 vEditedRecordings hwnder gEditedRecordings, Edited Recordings||
SendMessage, CB_SETDROPPEDWIDTH, 700, 0, , ahk_id %er%
Gui, Add, DDL, x+10 w100 h30 r60 vSeenRecordings hwndsr gSeenRecordings, Seen Recordings||
SendMessage, CB_SETDROPPEDWIDTH, 700, 0, , ahk_id %sr%
GroupBox("GB1", "Media folders", 10, 10, "RecordingService|NewMovies|EditedRecordings|SeenRecordings")
Gui, Add, Button, x+10 y17 w100 h41 vCopyMoveFiles gCopyMoveFiles, Copy/Move Files
Gui, Show, yCenter y0, Test
GoSub, DDL
Return

DDL:
Loop, %RSFolder%\*.ts
 {  
   RSFiles .= A_LoopFileName . "`n"
   RSFileDir := A_LoopFileDir
 } 
Sort, RSFiles, R
Loop, parse, RSFiles, `n
   GuiControl, , RecordingService, %A_LoopField%
Loop, %NMFolder%\*.*, 1, 1
 {  
   NMFiles .= A_LoopFileName . "`n" 
   NMFileDir := A_LoopFileDir
 }
Sort, NMFiles
Loop, parse, NMFiles, `n
   GuiControl, , NewMovies, %A_LoopField%
Loop, %ERFolder%\*.*
 {  
   ERFiles .= A_LoopFileName . "`n" 
   ERFileDir := A_LoopFileDir
 } 
Sort, ERFiles, R
Loop, parse, ERFiles, `n
   GuiControl, , EditedRecordings, %A_LoopField%
Loop, %SRFolder%\*.ts
 {  
   SRFiles .= A_LoopFileName . "`n" 
   SRFileDir := A_LoopFileDir
 } 
Sort, SRFiles, R
Loop, parse, SRFiles, `n
         GuiControl, , SeenRecordings, %A_LoopField% 
    
Return

GuiClose:
Exitapp

RecordingService:
GuiControlGet, RecordingService,, RecordingService  
PlayFile := """" RSFileDir "\" . RecordingService """" 
Run, %TSPlayer% %PlayFile%
Return

NewMovies:
GuiControlGet, NewMovies,, NewMovies  
PlayFile := """" NMFileDir "\" . NewMovies """" 
Run, %VLCPlayer% %PlayFile%
Return

EditedRecordings:
GuiControlGet, EditedRecordings,, EditedRecordings  
PlayFile := """" ERFileDir "\" . EditedRecordings """" 
Run, %TSPlayer% %PlayFile%
Return

SeenRecordings:
GuiControlGet, SeenRecordings,, SeenRecordings  
PlayFile := """" SRFileDir "\" . SeenRecordings """" 
Run, %TSPlayer% %PlayFile%
Return

CopyMoveFiles:
Run, FileMove.exe, D:\TV\test

;************************** GroupBox *******************************
;
;   Adds and wraps a GroupBox around a group of controls in
;   the default Gui. Use the Gui Default command if needed.
;   For instance:
;
;       Gui, 2:Default
;
;   sets the default Gui to Gui 2.
;
;   Add the controls you want in the GroupBox to the Gui using
;   the "v" option to assign a variable name to each control. *
;   Then immediately after the last control for the group
;   is added call this function. It will add a GroupBox and
;   wrap it around the controls.
;
;   Example:
;
;   Gui, Add, Text, vControl1, This is Control 1
;   Gui, Add, Text, vControl2 x+30, This is Control 2
;   GroupBox("GB1", "Testing", 20, 10, "Control1|Control2")
;   Gui, Add, Text, Section xMargin, This is Control 3
;   GroupBox("GB2", "Another Test", 20, 10, "This is Control 3")
;   Gui, Add, Text, yS, This is Control 4
;   GroupBox("GB3", "Third Test", 20, 10, "Static4")
;   Gui, Show, , GroupBox Test
;
;   * The "v" option to assign Control ID is not mandatory. You
;   may also use the ClassNN name or text of the control.
;
;   Author: dmatch @ AHK forum
;   Date: Sept. 5, 2011
;
;********************************************************************
GroupBox(GBvName            ;Name for GroupBox control variable
        ,Title              ;Title for GroupBox
        ,TitleHeight        ;Height in pixels to allow for the Title
        ,Margin             ;Margin in pixels around the controls
        ,Piped_CtrlvNames   ;Pipe (|) delimited list of Controls
        ,FixedWidth=""      ;Optional fixed width
        ,FixedHeight="")    ;Optional fixed height
{
    Local maxX, maxY, minX, minY, xPos, yPos ;all else assumed Global
    minX:=99999
    minY:=99999
    maxX:=0
    maxY:=0
    Loop, Parse, Piped_CtrlvNames, |, %A_Space%
    {
        ;Get position and size of each control in list.
        GuiControlGet, GB, Pos, %A_LoopField%
        ;creates GBX, GBY, GBW, GBH
        if(GBX<minX) ;check for minimum X
            minX:=GBX
        if(GBY<minY) ;Check for minimum Y
            minY:=GBY
        if(GBX+GBW>maxX) ;Check for maximum X
            maxX:=GBX+GBW
        if(GBY+GBH>maxY) ;Check for maximum Y
            maxY:=GBY+GBH

        ;Move the control to make room for the GroupBox
        xPos:=GBX+Margin
        yPos:=GBY+TitleHeight+Margin ;fixed margin
        GuiControl, Move, %A_LoopField%, x%xPos% y%yPos%
    }
    ;re-purpose the GBW and GBH variables
    if(FixedWidth)
        GBW:=FixedWidth
    else
        GBW:=maxX-minX+2*Margin ;calculate width for GroupBox
    if(FixedHeight)
        GBH:=FixedHeight
    else
        GBH:=maxY-MinY+TitleHeight+2*Margin ;calculate height for GroupBox ;fixed 2*margin

    ;Add the GroupBox
    Gui, Add, GroupBox, v%GBvName% x%minX% y%minY% w%GBW% h%GBH%, %Title%
    return
}