Tab3 Control Display Glitch

Get help with using AutoHotkey and its commands and hotkeys
User avatar
jballi
Posts: 612
Joined: 29 Sep 2013, 17:34

Tab3 Control Display Glitch

02 Jun 2018, 01:16

I'm getting a weird display glitch on GUI controls within a Tab3 control. The problem occurs consistently in the following example:

Code: Select all

#NoEnv
#SingleInstance Force
ListLines Off

;-- Add new code here
gui -DPIScale
gui Add,Tab3,w350 h250 vMyTab gMyTabAction,General|Station List

;----------------
;-- Tab: General
;----------------
gui Tab,General
gui Font,Bold
gui Add,Text,,Options:
gui Font,Normal
gui Add,CheckBox,Disabled,Always On Top
gui Add,CheckBox,,Escape To Close

gui Font,Bold
gui Add,Text,,System Tray:
gui Font,Normal
gui Add,CheckBox,,Always Show Tray Icon
gui Add,CheckBox,,Close To Tray
gui Add,CheckBox,,Minimize To Tray

;--------------------
;-- Tab: Station List
;--------------------
gui Tab,Station List

gui Font,Bold
gui Add,Text,Section,Font:
gui Font,Normal
gui Add,Edit,xs w250 +ReadOnly,Arial,s12
gui Add,Button,x+0,%A_Space%...%A_Space%
gui Add,Button,x+0 wp,?

gui Font,Bold
gui Add,Text,xs,Background Color:
gui Font,Normal
gui Add,Progress,xs w250 h30 +Background0xFE00FF
gui Add,Button,x+0,%A_Space%...%A_Space%
gui Add,Button,x+0 wp,?

;--------------
;-- After tabs
;--------------
gui Tab

;-- Select tab
GUIControl Choose,MyTab,|Station List

;-- Show it
gui Show,,Options
return

GUIClose:
GUIEscape:
ExitApp


MyTabAction:
gui Submit,NoHide
return
If the glitch occurs, you will see it. It cannot be missed. I am trying to figure out whether this glitch is occurring just for me or whether it is widespread.

Help: If you are able to see this glitch, please let me know and let me know which version of Windows you are using.

Thanks for your help.
User avatar
jeeswg
Posts: 6902
Joined: 19 Dec 2016, 01:58
Location: UK

Re: Tab3 Control Display Glitch

02 Jun 2018, 01:23

Windows 7. I get black bars on 3 controls on tab 2 initially (Static/Edit/Static), if I focus tab 1 and then tab 2 then the 3 controls appear normal.
homepage | tutorials | wish list | fun threads | donate
WARNING: copy your posts/messages before hitting Submit as you may lose them due to CAPTCHA
icuurd12b42
Posts: 202
Joined: 14 Aug 2016, 04:08

Re: Tab3 Control Display Glitch

02 Jun 2018, 01:25

I see it, windows 10...

swap the choose and the show calls

...
;-- Show it
gui Show,,Options
;-- Select tab
GUIControl Choose,MyTab,|Station List
return
...
User avatar
jballi
Posts: 612
Joined: 29 Sep 2013, 17:34

Re: Tab3 Control Display Glitch

02 Jun 2018, 01:49

icuurd12b42 wrote:I see it, windows 10...

swap the choose and the show calls

...
;-- Show it
gui Show,,Options
;-- Select tab
GUIControl Choose,MyTab,|Station List
return
...
Thanks for the feedback. Yes, there are many many workarounds. I'm just checking to see if the glitch can be duplicated on other PCs and other versions of Windows.

Return to “Ask For Help”

Who is online

Users browsing this forum: dentopolis and 136 guests