BoundFunc Object, .Bind() parameter variadic syntax: Preserve function paramter type

[hotkeyguy]

Hello,

suppose I have a string like (that's how I get the function parameters from my regex)

Code: Select all

sParams := "true, 123, ""Hello""   "

which consists of an boolean, integer and string value.
After parsing that string I get an array of parameter values:

Code: Select all

aParams := []
Loop, Parse, sParams, `, , %A_Space%
{
  sParam := A_LoopField
  aParams.Push( sParam ) 
}

Then I want to bind these values to a non-variadic function with variadic syntax.
That works, but how can I preserve the function parameter types?


Test code:

Code: Select all

sFuncName := "FuncTest"
sParams := "true, 123, ""Hello""   " ; that's how I get the function parameters from my regex

aParams := []
Loop, Parse, sParams, `, , %A_Space%
{
  sParam := A_LoopField
  aParams.Push( sParam )

}

oFunc := Func( sFuncName ).Bind( aParams* )
oFunc.Call()


FuncTest( p_bVal, p_iVal, p_sVal)
{
  MsgBox, % "bVal = " p_bVal "`niVal = " p_iVal "`nsVal = " p_sVal
}

Many thanks and greetings
hotkeyguy

[Chunjee]

"I have a function that takes 3 arguments, I want to give it an array of arguments as though it was variadic, which it isn't"

Doesn't seem possible to me. Have a thread bump though.

[swagfag]

Code: Select all

theFunction(myArrayOfParams*)

don't know what u mean by preserve the types. if u expect the bool param to say "true" in the msgbox instead of 1, can't be done. AHK doesn't have bools.

[jeeswg]

Perhaps something like this:

Code: Select all

aParams := []
sParams := "true, 123, ""Hello"""
MsgBox, % sParams ;true, 123, "Hello"

for vKey, vValue in StrSplit(sParams, ", ")
{
	if RegExMatch(vValue, "s)^\x22.*\x22$")
		aParams.Push("" SubStr(vValue, 2, -1))
	else if (vValue = "true")
		aParams.Push(1)
	else if (vValue = "false")
		aParams.Push(0)
	else if vValue is number
		aParams.Push(0+vValue)
	else
		MsgBox, % "unhandled: " vValue
}

vOutput := ""
for vKey, vValue in aParams
	vOutput .= vKey " " vValue "`r`n"
MsgBox, % vOutput