Clipboard --UTF-8-->to file

[knn]

OK, I've been looking around for a day now and I cannot find the solution.

I want to

• select a text in Notepad++, e.g. фирменно
• create a UTF-8 file and save the text into it

I managed to get the text to display correctly in a MsgBox, so I know that AHK got фирменно correctly. But when I save it into a file it's all messed up,
??????????, consisting of only #3F (?).

This is the code I use so far

Code: Select all

file := FileOpen(path, "w")
file.Encoding := UTF-8
file.write(vText)
file.close()

[teadrinker]

file.Encoding := "UTF-8"

[knn]

Thank you, I can confirm that the file is being saved correctly. But now the reading back doesn't work.

Code: Select all

file := FileOpen(path, "r-d")
file.Encoding := "UTF-8"
vText := file.read()
MsgBox % vText <--- Shows �ннемЀѸЄ�
file.close()

I tried also with file := FileOpen(path, "r-d", "UTF-8")

[teadrinker]

For me it works correctly like this:

Code: Select all

filePath := A_Desktop . "\test.txt"

File := FileOpen(filePath, "w")
File.Encoding := "UTF-8"
File.Write("фирменно")
File.Close()

File := FileOpen(filePath, "r-d")
File.Encoding := "UTF-8"
text := File.Read()
File.Close()

MsgBox, % text

More correct way:

Code: Select all

filePath := A_Desktop . "\test.txt"

File := FileOpen(filePath, "w", "UTF-8")
File.Write("фирменно")
File.Close()

File := FileOpen(filePath, "r") ; don't need to specify encoding since BOM presents in the file
text := File.Read()
File.Close()

MsgBox, % text

[knn]

Thank you very much for your help. I found out the reason why it didn't work.

I use PHP to process the UTF-8 file and it turned out that PHP does not automatically handle UTF-8 files with BOM, i.e. the file that was created by AHK's file.write().

I needed to write my own UTF-8 BOM read/write function in PHP to fix that issue.

[teadrinker]

If you need you could use UTF-8 without BOM like this:

Code: Select all

filePath := A_Desktop . "\test.txt"

File := FileOpen(filePath, "w", "UTF-8-RAW")
File.Write("фирменно")
File.Close()

File := FileOpen(filePath, "r", "UTF-8")
text := File.Read()
File.Close()

MsgBox, % text

[knn]

Does File := FileOpen(filePath, "r", "UTF-8") handle UTF-8 with BOM automatically?

[teadrinker]

If BOM presents, you don't need to specify encoding here: File := FileOpen(filePath, "r")