Split - to many lines Topic is solved

[Albireo]

Hi!
this work

Code: Select all

A .= info1 ";" info2 ";" Trim(Info3) "`n"

but this does not work for me .:

Code: Select all

A .=
( 	info1 ";"
	info2 ";"
	Trim(info3) "`n"
)

or this .:

Code: Select all

A .= .
( 	info1 ";" .
	info2 ";" .
	Trim(info3) "`n"

how to solve this?

[mikeyww]

Code: Select all

A .= info1 ";"
  .  info2 ";"
  .  Trim(info3) "`n"

[Albireo]

thank you!

[Albireo]

Is it possible to split

Code: Select all

invRow ~= "(.*\s+((\d+.)?\d+,\d+)\s+.*\s+((\d+,\d+)\s[%])\s+((\d+.)?\d+,\d+)\s+((\d+.)?\d+,\d+))$" )

to many lines with comments?
Something like this .:

Code: Select all

invRows ~=
( LTrim Join Comments
   (.*\s+   ; bla bla 
   ((\d+.)?\d+,\d+)   ; New Comments
      ...
   etc.
)

(I did not make it work)

[mikeyww]

Interesting issue. My best guess is that + is somehow being interpreted as a literal character, rather than a regex character. The following works.

Code: Select all

regex =
( LTrim Join Comments
   (.*\s+     ; Line 1
   ((\d+.)?   ; Line 2
   \d+,\d+))  ; Line 3
)
invRows = x 3l6,0 ; Example to see whether the regex works

; Show results
info = regex       %regex%`n`ninvRows   %invRows%`n`n
If invRows ~= regex
 MsgBox, 64, Success, %info%It worked!
Else MsgBox, 48, Failure, %info%Nope!

[just me]

The regex needle is a simple string so the concat operator . should work as already shown by mikeyww .

[mikeyww]

Yes, that works, too. It also appears that \s is tripping up the problematic code, so perhaps the continuation section also does not like the backslash somehow when used with ~=. Below, the first script fails; the second and third succeed.

Code: Select all

If "5" ~=
(
\d
)
MsgBox, Success

Code: Select all

regex =
(
\d
)
If "5" ~= regex
MsgBox, Success

Code: Select all

If "5" ~=
(
5
)
MsgBox, Success

[boiler]

It’s because ~= an expression operator, so literal strings, like in the first example, must be quoted. It’s similar to using a continuation section like that with := instead of =. The following works:

Code: Select all

If "5" ~= "
(
\d
)"
MsgBox, Success

The second example uses the legacy assignment operator =, so the assignment works unquoted. The third example works because it’s being assigned a value, not a string, so no quotes are needed.

[mikeyww]

Interesting again! Thanks, @boiler. You solved the mystery.

[Albireo]

Thanks!
But the only way to be able to write notes, is to follow mikeyww's first suggestion?

Code: Select all

regex =
( LTrim Join Comments
   (.*\s+     ; Line 1
   ((\d+.)?   ; Line 2
   \d+,\d+))  ; Line 3
)
invRows = x 3l6,0 ; Example to see whether the regex works

; Show results
info = regex       %regex%`n`ninvRows   %invRows%`n`n
If invRows ~= regex
 MsgBox, 64, Success, %info%It worked!
Else MsgBox, 48, Failure, %info%Nope!

[just me]

It might help to try the other suggestions.

[Albireo]

To split @boiler has a nice suggestion.
(but I miss being able to make notes)

[boiler]

You can make your notes. Did you try it?

Code: Select all

invRows = x 3l6,0 ; Example to see whether the regex works
if invRows ~= "
( LTrim Join Comments
   (.*\s+     ; Line 1
   ((\d+.)?   ; Line 2
   \d+,\d+))  ; Line 3
)"
	MsgBox, 64, Success, It worked!
Else
	MsgBox, 48, Failure, Nope!

[just me]

The regex needle is a simple string so the concat operator . should work as already shown by mikeyww .

Code: Select all

invRows := "x 3l6,0" ; Example to see whether the regex works
if invRows ~= "(.*\s+"     ; Line 1
            . "((\d+.)?"   ; Line 2
            . "\d+,\d+))"  ; Line 3
	MsgBox, 64, Success, It worked!
Else
	MsgBox, 48, Failure, Nope!