Hide from taskbar

[samardac]

Is it any way to hide notepad from taskbar?

[TheDewd]

http://www.autohotkey.com/board/topic/3 ... /?p=231982

Works by applying ToolWindow style to a window.

Code: Select all

DetectHiddenWindows, On

^F2::
	WinHide, % "ahk_id " (ID:=WinExist("A"))
	WinSet, ExStyle, ^0x80, ahk_id %ID% ; Apply ToolWindow Style
	WinShow, ahk_id %ID%
Return

Code: Select all

#SingleInstance, Force

DetectHiddenWindows, On
 
Run, notepad.exe
WinWait, Untitled - Notepad
WinHide, ahk_class Notepad
WinSet, ExStyle, ^0x80, ahk_class Notepad
WinShow, ahk_class Notepad

[Flipeador]

Code: Select all

Run, notepad.exe
WinWait, ahk_class Notepad
TaskBarRemove( WinExist( "ahk_class Notepad" ) )
Sleep 3000
TaskBarRemove( WinExist( "ahk_class Notepad" ), 1 )
TaskBarRemove(hWnd, Show := 0) {
	hTaskBar := ComObjCreate("{56FDF344-FD6D-11d0-958A-006097C9A090}", "{56FDF342-FD6D-11d0-958A-006097C9A090}")
	DllCall(NumGet(NumGet(hTaskBar+0), 3*A_PtrSize), "Ptr", hTaskBar, "Ptr", hWnd)
	return DllCall(NumGet(NumGet(hTaskBar+0), (Show?4:5)*A_PtrSize), "Ptr", hTaskBar, "Ptr", hWnd)
		, ObjRelease( hTaskBar )
}