Play a single random sound from this folder Topic is solved

[hced]

Hi, I'm trying to cobble together a script that should reside in folders containing sound files.



Here's what I got so far:

Code: Select all

; Play a single random sound from this folder
path := A_ScriptDir
Loop Files, path "\*.wav"
    lst .= A_LoopFilePath "`n"
lst := Sort(lst, "Random")
for x,y in StrSplit(lst,"`n")
    SoundPlay(y, Wait)

But I'm getting a

Code: Select all

Warning: This variable appears to never be assigned a value

pointing to line 7:

Code: Select all

SoundPlay(y, Wait)

...



For the record, I'm to implement this script in V2.

Would some kind-hearted person please help me to make this script work in V2?

[gregster]

Afaics, "Wait" should be a string in v2, thus quoted.
Unquoted it will be evaluated as a variable (which is empty in this case).

[hced]

@gregster That worked as far as playback goes, thank you. Now, I'm not particularly great at coding and just realize I've made it to play ALL files in a LOOP. I wish to just play ONE single file once. How should I adjust this script accordingly?

[SKAN]

I wish to just play ONE single file once.

 

Code: Select all

#Requires AutoHotkey v2.0
#SingleInstance

path := A_WinDir "\Media"
Loop Files, path "\*.wav"
    lst .= A_LoopFileFullPath "`n"
lst := RTrim(lst, "`n")
arr := StrSplit(lst, "`n")
rnd := Random(1, arr.Length)

SoundPlay(arr[rnd], "Wait")

[hced]

Thank you SKAN, that did the trick!

Note. For anyone wanting the exact functionality per my first post, I added A_ScriptDir (to search the current folder of the script) and #NoTrayIcon to get rid of the systray icon popup.

Code: Select all

; Play a single random sound from this folder
#Requires AutoHotkey v2.0
#SingleInstance
#NoTrayIcon

path := A_ScriptDir
Loop Files, path "\*.wav"
    lst .= A_LoopFileFullPath "`n"
lst := RTrim(lst, "`n")
arr := StrSplit(lst,"`n")
rnd := Random(1, arr.Length)

SoundPlay(arr[rnd], "Wait")