GUI script conversion request Topic is solved

[LAPIII]

@Rohwedder had helped me write this:

Code: Select all

#SingleInstance, Force
Path = C:\Users\LPIII\OneDrive\Documents\AutoHotkey\AHK Scripts\Bookmark Manager
Gui, Add, Text, gLink1, PostImages
Gui, Show
Return

Link1:
Run, PostImages.ahk, %Path%
Return

I'm missing an Event:

Code: Select all

#SingleInstance Force
#Requires Autohotkey v2.0+
Path := "C:\Users\LPIII\OneDrive\Documents\AutoHotkey\AHK Scripts\Bookmark Manager"
myGui := Gui()
File1 := myGui.Add("Text", , "PostImages")
myGui.Show()
Return

[mikeyww]

Code: Select all

#Requires AutoHotkey v2.0
gui1 := Gui(, 'Test'), gui1.SetFont('s10 underline')
gui1.AddText('w200 cBlue Center', 'Click this text').OnEvent('Click', txt_Click)
gui1.Show 'x400'

txt_Click(txt, info) {
 MsgBox 123
}

[LAPIII]

Thank you very much. This is so awesome!

[LAPIII]

Can you tell me why couldn't I change it to:

Code: Select all

#Requires AutoHotkey v2.0
myGui := Gui()
myGui.SetFont('s10 underline')
myGui.AddText('w200 cBlue Center', 'Click this text')
myGui.OnEvent('Click', txt_Click)
myGui.Show 'x400'

txt_Click(txt, info) {
 MsgBox 123
}

[mikeyww]

The object you want is the text control, not the GUI itself.

Code: Select all

#Requires AutoHotkey v2.0
myGui := Gui()
myGui.SetFont('s10 underline')
txt := myGui.AddText('w200 cBlue Center', 'Click this text')
txt.OnEvent('Click', txt_Click)
myGui.Show 'x400'

txt_Click(txt, info) {
 MsgBox 123
}