#HotIf fails to activate when global variant is present Topic is solved

[xypha]

#HotIf fails to activate when global variant is present, while using ahk_group in AHK v2 (AutoHotkey v2.0.10)
Please check the examples below.
Why is example #2 failing (when using Firefox) and how can I correct the error?

Example #1 - works when global variant is disabled

Code: Select all

GroupAdd "HorizontalScroll1", "ahk_class MozillaWindowClass"           ; Firefox
GroupAdd "HorizontalScroll1", "ahk_class other"                     ; other

#HotIf WinActive("ahk_group HorizontalScroll1")

+WheelUp::WheelLeft
+WheelDown::WheelRight

#HotIf

/* global variant disabled
+WheelUp::SendMessage 0x0114, 0, 0, ControlGetFocus("A")        ; scroll left - 0x114 is WM_HSCROLL, 0 is SB_LINERIGHT
+WheelDown::SendMessage 0x0114, 1, 0, ControlGetFocus("A")      ; scroll right - 1 is SB_LINELEFT
*/

ListLines output -

Spoiler

001: GroupAdd("HorizontalScroll1", "ahk_class MozillaWindowClass")
002: GroupAdd("HorizontalScroll1", "ahk_class other")
004: {
006: {
006: {
007: {
007: {
010: Exit (2.81)
007: SetMouseDelay(-1),Send("{Blind+}{WheelRight DownR}") (0.02)
007: } (0.86)
006: SetMouseDelay(-1),Send("{Blind+}{WheelLeft DownR}")
006: } (8.47)

Example #2 - fails when global variant enabled

Code: Select all

GroupAdd "HorizontalScroll1", "ahk_class MozillaWindowClass"           ; Firefox
GroupAdd "HorizontalScroll1", "ahk_class other"                     ; other

#HotIf WinActive("ahk_group HorizontalScroll1")

+WheelUp::WheelLeft
+WheelDown::WheelRight

#HotIf

+WheelUp::SendMessage 0x0114, 0, 0, ControlGetFocus("A")        ; scroll left - 0x114 is WM_HSCROLL, 0 is SB_LINERIGHT
+WheelDown::SendMessage 0x0114, 1, 0, ControlGetFocus("A")      ; scroll right - 1 is SB_LINELEFT

Listlines output -

Spoiler

001: GroupAdd("HorizontalScroll1", "ahk_class MozillaWindowClass")
002: GroupAdd("HorizontalScroll1", "ahk_class other")
004: {
006: {
006: {
007: {
007: {
011: {
012: {
013: Exit (1.55)
012: SendMessage(0x0114, 1, 0, ControlGetFocus("A")) (10.03)
011: SendMessage(0x0114, 0, 0, ControlGetFocus("A")) (14.69)

Error pop-up -

Spoiler

Error: Target window not found.

011: }
012: {
▶ 012: SendMessage(0x0114, 1, 0, ControlGetFocus("A"))
012: }
013: Exit

Call stack:
D:\path_to_ahk\test.ahk (12) : [SendMessage] SendMessage(0x0114, 1, 0, ControlGetFocus("A"))
D:\path_to_ahk\test.ahk (12) : [<Hotkey>] SendMessage(0x0114, 1, 0, ControlGetFocus("A"))
> +WheelDown

[niCode]

Experiencing the same issue. I wonder if this is a bug

Changing the #HotIf portion to this seems to work:

Code: Select all

#HotIf WinActive("ahk_group HorizontalScroll1")

+WheelUp::Send('{WheelLeft}')
+WheelDown::Send('{WheelRight}')

#HotIf

[xypha]

@niCode
This worked. Thank you.

[boiler]

There’s a section of this forum titled Bug Reports.

[xypha]

There’s a section of this forum titled Bug Reports.

Thanks. I will post a new topic there.

[lexikos]

It is not a bug. +WheelUp::WheelLeft is a remapping, not a hotkey. A remapping consists of two wildcard hotkeys. It can be activated by any combination of modifiers that includes Shift (such as Shift+Alt), whereas +WheelUp::SendMessage ... is a hotkey without the wildcard, and therefore cannot be activated if any modifier other than Shift is pressed.

#HotIf is only used to select which variant of the same hotkey activates. You could use +WheelUp::WheelLeft and +WheelUp::SendMessage ... together even without #HotIf, because the differing modifier-key requirements cause them to be treated as separate hotkeys. When a key combination corresponds to multiple hotkeys, generally the more specific hotkey should take precedence. That's the one which doesn't permit modifiers other than Shift.

I deleted the Bug Reports topic.