RegExMatch Match.Count is 0, not as expected Topic is solved

[valuex]

I am trying to get the last occurance position of a char in a string as below.
But it's wired that the ObjMatch.Count is always 0.
Any idea to fix it? Thanks.

Code: Select all

msgbox Str_LastCharPos("1.2.33.",".")


Str_LastCharPos(InputStr,InChar)
{
    if(InStr("\.*?+[{|()^$",InChar))
        InChar:="\" . InChar ; Escape some chars
    Pos:=RegExMatch(InputStr, InChar , &ObjMatch, 1)
    If(Pos>0)
    {
        MatchNumber:=ObjMatch.Count
		msgbox MatchNumber
        LastMatchPos:=ObjMatch.Pos[MatchNumber]
        return LastMatchPos
    }
    else
        return 0
}

[just me]

Match Object (RegExMatchInfo)

Match.Count: Returns the overall number of subpatterns (capturing groups), which is also the maximum value for N.

Your RegEx has no subpatterns.

If you want to search for a single character, why don't you use

Code: Select all

    Pos := InStr(InputStr, InChar, 1, -1)

[valuex]

Oh, I get it. The NeedleRegE shall be enclosed with parentheses like: (reg_pattern).
Thans for your reply.

[william_ahk]

It's because AHK never implemented a global flag for regex matches. (Have a look at the author's genius comment about this here if anyone is interested).
So you're only going to match the first occurrence. And also because there is no group in the pattern, the overall match will be at Match[0], which is confusing and got me in the past since index starts at 1 in AHK.

To implement a global match:

Code: Select all

msgbox Str_LastCharPos("1.2.33.",".")

Str_LastCharPos(InputStr,InChar)
{
	InChar := "\Q" InChar "\E" ; Pattern as literal
	StartingPos := 1
	Pos := 0
	While (FoundPos := RegExMatch(InputStr, InChar, &ObjMatch, StartingPos))
	{
		StartingPos := Pos + StrLen(ObjMatch[0])
		Pos := FoundPos
	}
	return Pos
}

Or, if you're only matching characters verbatim, just use InStr which supports searching backwards (and occurrence) as just me suggested:

Code: Select all

Str_LastCharPos(InputStr,InChar)
{
	Return InStr(InputStr, InChar, 1, -1)
}

[boiler]

No loop is needed if you write the pattern to match the last instance of the character:

Code: Select all

#Requires AutoHotkey v2.0

msgbox Str_LastCharPos("1.2.33.",".")


Str_LastCharPos(InputStr,InChar)
{
    if(InStr("\.*?+[{|()^$",InChar))
        InChar:="\" . InChar ; Escape some chars
    return RegExMatch(InputStr, '.*\K' InChar)
}