Problem with unhiding a window

[afshindavoudy]

I want to know why this script cannot unhide windows?

Code: Select all

hidden := []

F2:: {
	hwnd := WinExist('A')
	hidden.Push(hwnd)
	WinHide(hwnd)
}

F3:: {
	; MsgBox (hidden.Length) ; This detect the length correctly
	loop(hidden){
		WinShow(hidden[A_Index])
		WinActivate(hidden[A_Index])
	}
}

[mikeyww]

Hello,

hidden is an array, not a number.

Syntax for Loop:

Loop [Count]

Count:

Type: Integer

If omitted, the loop continues indefinitely until a Break or Return is encountered. Otherwise, specify how many times (iterations) to perform the loop. However, an explicit blank value or number less than 1 causes the loop to be skipped entirely.

Explained: Length property

Code: Select all

#Requires AutoHotkey v2.0
hidden := []

F2:: {
 Try {
  hidden.Push(WinExist('A'))
  WinHide()
 }
}

F3:: {
 DetectHiddenWindows True
 While hidden.Length
  If WinExist(hidden.RemoveAt(1))
   WinShow(), WinActivate()
}

[afshindavoudy]

@mikeyww
Yes, that was my mistake.
Thanks

[mikeyww]

This version may be better.

Code: Select all

#Requires AutoHotkey v2.0
hidden := []

F2:: {
 If hWnd := WinActive('A')
  hidden.Push(hWnd), WinHide()
}

F3:: {
 DetectHiddenWindows True
 While hidden.Length
  If WinExist(hidden.RemoveAt(1))
   WinShow(), WinActivate()
}