How to duplicate text of Edit control while editing? Topic is solved

[hiahkforum]

How to duplicate text of Edit control while editing? Without clicking buttons and MsgBoxes, all changes only in current GUI, but Text control can be replaced with disabled Edit control.

Code: Select all

1::{
	Title := WinGetTitle('A')
	TableC := Gui('+AlwaysOnTop +ToolWindow', Title)
	TableC.Add('Text',, 'Batch name:')
	TableC.Add('Text',, 'Clones amount:')
	TableC.Add('Edit', 'vBatchName ym')
	TableC.Add('Edit', '+Number vClonesAmount w95')
	TableC.Add('Edit', '+Number vStartingPosition x190 y32 w22 Center', '1')
	TableC.Add('Text', 'xm', 'Duplicate of Edit control "vBatchName"') ; Here I want to duplicate the text of the "vBatchName" variable while editing.
	TableC.Add('Button', 'Default x8 y85 w102 h35', 'OK').OnEvent('Click', ProcessUserInput)
	TableC.Add('Button', 'x112 y85 w102 h35', 'Close').OnEvent('Click', Close)
	TableC.Show()

	ProcessUserInput(*) {
	}
	Close(*) {
		WinClose()
	}
}

[mikeyww]

Code: Select all

#Requires AutoHotkey v2.0
g := Gui(, 'Mirror')
g.AddEdit('w300').OnEvent('Change', (ed, info) => mirror.Text := ed.Text)
mirror := g.AddEdit('wp ReadOnly')
g.Show

[hiahkforum]

@mikeyww It works perfectly with one result from vBatchName, but how to combine 3 results at once and add vClonesAmount and vStartingPosition to it? I tried it myself, but I couldn't handle it.

[mikeyww]

Code: Select all

#Requires AutoHotkey v2.0
TableC := Gui('+AlwaysOnTop +ToolWindow', 'Mirror')
TableC.SetFont 's10'
TableC.AddText 'ym+3 w120', 'Batch name:'
TableC.AddText 'wp', 'Clones amount:'
TableC.AddEdit('vBatchName ym').OnEvent('Change', ed_Change)
TableC.AddEdit('+Number vClonesAmount w95').OnEvent('Change', ed_Change)
TableC.AddEdit('+Number vStartingPosition x+m w22 Center', 1).OnEvent('Change', ed_Change)
txt := TableC.AddEdit('xm w200 r3 ReadOnly')
ed_Change
TableC.Show 'y500'

ed_Change(ed := '', info := '') {
 g := TableC.Submit(0)
 txt.Text := g.BatchName '`r`n' g.ClonesAmount '`r`n' g.StartingPosition
}

[hiahkforum]

@mikeyww Thanks, this is exactly what I wanted. But also I wanted to do math operations with g.StartingPosition and g.ClonesAmount, but got an error "Expected a Number but got an empty string.". Could you please tell me how to solve this?

[mikeyww]

Code: Select all

If IsNumber(g.ClonesAmount) and IsNumber(g.StartingPosition)
 txt.Text := g.ClonesAmount + g.StartingPosition

[hiahkforum]

Everything just beatiful.

---

Beatiful.png (11 KiB) Viewed 142 times