How to remove the word by regular expressions? Topic is solved

[hancre]

This following code removes only english words and doesn't work for the non-english words such as 시작, こんにちは, 時作 é è ? ! ".

How can I remove all letters and special characters(? ! " .) Thanks for any help in advance.

Code: Select all

; case-sensitive
MyMenu := Menu()
MyMenu.Add '1. Remove inputword', RemoveWord


Capslock & f:: {     
    global IB, textClipboard
    IB:='',  textClipboard:= ''
    A_Clipboard := ''
    Send('^c')
    if (ClipWait(1))    {
        textClipboard := A_Clipboard
        txt := SubStr(textClipboard, 1, 65)
        IB := InputBox('Clipboard:`n' txt '`n`nEnter text to change.', 'Change text', 'w530 h150')
        if (ib.Result = 'OK' && ib.Value != '')
            MyMenu.Show
            Send('^v')
    }  else  {
        MsgBox 'An error occurred while waiting for the clipboard.', 'Error', 'Icon!'
    }
}


RemoveWord(ItemName, ItemPos, MyMenu) {
  A_Clipboard := RegExReplace(A_Clipboard, '\b' ib.Value '\b\h*', "") 
   }
    

[boiler]

Do you mean you want to remove everything but numbers?

[hancre]

Do you mean you want to remove everything but numbers?

Ah. I want to remove any inputdata (word, not string)
If I type Number, it should also be removed.
Thanks for your interest. ^^

[Seven0528]

Code: Select all

#Requires AutoHotkey v2.0
#SingleInstance Force
haystack := "그러니까 이런 거 말이죠?"
needle := "이런 거"
newStr := regExReplace(haystack, "(?<=\h|^)\Q" needle "\E(?=\h|$)\h*")
msgbox newStr ;  "그러니까 말이죠?"

　English description

Although \b is commonly known as the "word boundary" in regular expressions,
if you examine its definition closely, it actually refers to the boundary between \w and \W.
\w represents [a-zA-Z0-9_], so it's more accurate to think of it as the "English word boundary."
Therefore, if you want to detect word boundaries in languages other than alphanumeric when using regular expressions, you need to specify additional conditions.
I've also mentioned using \Q and \E to escape entire strings, so keep that in mind as well.

　日本語説明

\bは一般的に「単語境界」として知られていますが、実際にはその定義をよく調べると、\wと\Wの境界を意味します。
\wは[a-zA-Z0-9_]を表すので、実質的には「英単語の境界」と考えるのが良いでしょう。
したがって、正規表現を使用する際に、英数字だけでなく他の言語の単語の境界を検出したい場合には、別の条件を付ける必要があります。
また、\Qと\Eを使って文字列全体をエスケープする方法も書いておいたので、参考にしてください。

　한국어 설명

\b는 "단어 경계"로 잘 알려져있지만, 사실 그 정의를 잘 살펴보면 \w와 \W의 경계를 의미합니다.
\w는 [a-zA-Z0-9_]를 의미하므로, 실질적으로 "영단어 경계"라고 생각하는 것이 좋을 겁니다.
때문에 정규식을 사용할 때, 영숫자만이 아닌 다른 언어의 단어 경계를 감지하고 싶다면, 별도로 조건을 작성해줘야 합니다.
또한 \Q와 \E를 통해 문자열 통째로 피신하는 방법도 적어두었으니, 참고 바랍니다.

[Seven0528]

Code: Select all

haystack := "漢字が含まれていると困ります。"
needle := "漢字が"
if (haystack ~= "\p{Han}") ;  if (regExMatch(haystack, "\p{Han}"))
    newStr := regExReplace(haystack, "\Q" needle "\E")
else
    newStr := regExReplace(haystack, "(?<=\h|^)\Q" needle "\E(?=\h|$)\h*")
msgbox newStr ;  "含まれていると困ります。"

　Ah, I think it would indeed become much more complex if we had to consider Chinese characters(漢字), especially in the context of Japanese where we need to consider the relationship between 漢字 and ひらがな. There isn't an easy way to determine word boundaries.
漢字 can be detected using \p{Han}.
If we are considering the presence of 漢字, perhaps removing assertions would help.

(For reference, 한글 can be specified as [ㄱ-ㅣ가-힣], and as for ひらがな, カタカナ, and 半角ｶﾀｶﾅ, their Unicode ranges tend to be somewhat scattered, so I won't list them here.)

[Rohwedder]

@hancre write! What exactly you want this input text to become:

Code: Select all

#Requires AutoHotkey v2.0
InputText := " Hello 'World' 1 12 123 42 4 2 𝟒𝟐 𝟰 𝟮 시작, こんにちは, 時作 é è ? ! `" . "
MsgBox InputText

[Seven0528]

Code: Select all

haystack := 'Hello Nice To Meet You'
needle := 'Meet'
msgbox regExReplace(haystack, '\b' needle '\b\h*') ;  'Hello Nice To You'
haystack := '안녕 만나서 반가워'
needle := '만나서'
msgbox regExReplace(haystack, '\b' needle '\b\h*') ;  '안녕 만나서 반가워'

　@hancre is asking why this regular expression only works in English sentences.
They're also asking how to handle special characters like \.*?+[{|()^$ in the needle part of the regular expression so that they are treated literally.
(I don't think @hancre's question was vague; rather, they were quite clear about what they wanted to ask.)

To answer this, \b denotes the boundary between \w and \W, so it doesn't detect non-alphanumeric word boundaries.
As for covering the entire string, you can use \Q and \E to encapsulate the string.

[Rohwedder]

Try:

Code: Select all

haystack := '안녕 만나서 반가워'
needle := '만나서'
msgbox regExReplace(haystack, '(*UCP)\b' needle '\b\h*') ;  '안녕 반가워'

[Seven0528]

Holly molly...

[Seven0528]

　The perfect answer here, @hancre.
Thank you for letting me know about (*UCP), @Rohwedder!
https://www.autohotkey.com/docs/v2/misc/RegEx-QuickRef.htm#Common

For performance, \d, \D, \s, \S, \w, \W, \b and \B recognize only ASCII characters by default. If the pattern begins with (*UCP), Unicode properties will be used to determine which characters match. For example, \w becomes equivalent to [\p{L}\p{N}_] and \d becomes equivalent to \p{Nd}.

Code: Select all

newStr := regExReplace(haystack, "(*UCP)\b\Q" needle "\E\b\h*")

[hancre]

@Rohwedder @Seven0528

Thank you for your help. Wow.. It works.

I have an additional question. How can I keep the blank cased by inpudata like the attached image?
haystack := '안녕 만나서 반가워'
needle := '만나서'

text doesn't show the right result.
so I attached an image file.

sorry. I tried to add < \K(?=\S)") > to the current Regex. but it doesn't work.

[Seven0528]

　Are you asking if you want to replace the specific characters with whitespace characters?
However, in this case, how should we consider whether the characters are half-width or full-width?

Code: Select all

"Hello Nice To Meet You"
"Hello      To Meet You"

Code: Select all

"안녕 만나서 반가워"
"안녕 　　　 반가워"

[hancre]

@Seven0528
Oh. I prefer the same width. the width of sample looks different.
sorry to make you confused.