Issue with Building an Array Using a Loop Topic is solved

[Loop]

Hello everyone,

I've been trying to build an array using a loop, but I keep encountering an error: "Invalid index." Here's how my loop looks like:

Code: Select all

#Requires Autohotkey v2.0
#SingleInstance Force


Ier := []
Aer := ["a", "b", "c", "d", "e", "f","g","h"]
Loop 8
{

   Ier[A_index] := []
   Ier[A_Index].Push(Aer[A_index])
}

MsgBox Ier[2][1]

Could you please help me identify what I'm doing wrong?

My array should look like this at the end

Code: Select all

Ier[[a],[b],[c]]

Thank you in advance.

[ntepa]

A valid array index needs to be less than or equal to the array length. Ier := [] creates an array with a length of 0.
In the first iteration of the loop, it tries to set Ier[1] := []. 1 is an invalid index because it's greater than Ier.length.
You can set the length after creating Ier:

Code: Select all

#Requires Autohotkey v2.0
#SingleInstance Force


Ier := []
Ier.Length := 8
Aer := ["a", "b", "c", "d", "e", "f","g","h"]
Loop 8
{

   Ier[A_index] := []
   Ier[A_Index].Push(Aer[A_index])
}

MsgBox Ier[2][1]

Or push an array instead:

Code: Select all

#Requires Autohotkey v2.0
#SingleInstance Force


Ier := []
Aer := ["a", "b", "c", "d", "e", "f","g","h"]
Loop 8
{

   Ier.Push([])
   Ier[A_Index].Push(Aer[A_index])
}

MsgBox Ier[2][1]

[niCode]

What ntepa said. Here's just some more ways of envisioning it.

Code: Select all

Aer := ["a", "b", "c", "d", "e", "f","g","h"]
Ier := []
Ier.Length := Aer.Length

Loop Aer.Length
{
    Ier[A_index] := []
    Ier[A_Index].Push(Aer[A_index])
}

MsgBox(Ier[2][1])

or

Code: Select all

Ier := []
Aer := ["a", "b", "c", "d", "e", "f","g","h"]

Loop Aer.Length
{
    Ier.Push([])
    Ier[A_Index].Push(Aer[A_Index])
}

MsgBox(Ier[2][1])

or

Code: Select all

Ier := []

for index, value in ["a", "b", "c", "d", "e", "f","g","h"]
{
    Ier.Push([value])
}

MsgBox(Ier[2][1])

[teadrinker]

Without a loop:

Code: Select all

Aer := ["a", "b", "c", "d", "e", "f","g","h"]
Ier := [((e, _, &v) => e(&v) && v := [v]).Bind(Aer.__Enum(1), &v)*]
MsgBox Ier[2][1]

[Loop]

Thank you for your responses.
But is this new in AHK2?

[teadrinker]

I'm not sure exactly what you mean, but yes, arrays are arranged differently in the second version. In the first version there was no difference between obj := [] and obj := {}. See this post.

[Loop]

Thank you, I meant that previously you didn't have to assign a length to an index-based array. Is ier.Length := 8 ;>>> new?

[teadrinker]

Yes, in the first version arrays didn't have a "Length" property at all, they had a Length() method that returned the maximum positive numeric key:

Code: Select all

#Requires AutoHotkey v1
arr := []
arr.a := "a"
arr[-1] := "b"
arr[5] := "c"
MsgBox % "length: " . arr.Length()
for k, v in arr {
    MsgBox % "key: " . k . "`nvalue: " . v
}

In the second version, you can't write like this:

Code: Select all

#Requires AutoHotkey v2

arr := []
arr[1] := 'test'

because initially there is no key with number 1 in the empty array.
But you can do it this way:

Code: Select all

#Requires AutoHotkey v2

arr := []
arr.Push('test')

In this case, the keys will be created automatically.

[Loop]

Thank you for the explanation

[Rohwedder]

Hallo @teadrinker,
in your opinion, what would be the best translation of your v1 array example to v2?

[teadrinker]

@Rohwedder
I think the closest translation would be this:

Code: Select all

#Requires AutoHotkey v2

obj := {}
obj.a := 'a'
obj.%-1% := 'b'
obj.5 := 'c'
for k, v in obj.OwnProps() {
    MsgBox 'key: ' . k . '`nvalue: ' . v
}