How to access variables of Gui callback event in AHK v2? Topic is solved

[yousef_badr23]

I am trying to get the content of a edit control in a Gui i create in AHK v2, triggered after pressing a submit button, as the following code:

Code: Select all

myGui:=Gui()
myGui.addEdit("vInput")
myGui.addButton(,"Submit").onEvent("Click",(*)=> output:=myGui.submit())
myGui.show()
winwaitclose myGui
msgbox output.Input

The problem is that I can't access the output variable. I think because the callback function is its own thread, and that it does not return the variable to the script. Is there a proper way to submit Gui in AHK v2? How to use the callback event to return variables to the main script/ assign values to variable??

[teadrinker]

As an option:

Code: Select all

myGui:=Gui()
myGui.addEdit("vInput")
myGui.addButton(,"Submit").onEvent("Click",(*)=> (myGui.output := myGui.submit()))
myGui.show()
winwaitclose myGui
msgbox myGui.output.Input

[kczx3]

There are numerous ways to do this. One would be:

Code: Select all

myGui:=Gui()
myGui.addEdit("vInput")
myGui.addButton(,"Submit").onEvent("Click", submit_handler)
myGui.show()

submit_handler(ctrl, *) {
    output := ctrl.gui.submit()
    msgbox(output.Input)
}

[yousef_badr23]

There are numerous ways to do this. One would be:

Code: Select all

myGui:=Gui()
myGui.addEdit("vInput")
myGui.addButton(,"Submit").onEvent("Click", submit_handler)
myGui.show()

submit_handler(ctrl, *) {
    output := ctrl.gui.submit()
    msgbox(output.Input)
}

I want to use the variable outsite the callback function

[flyingDman]

Code: Select all

myGui:=Gui()
edt1 := myGui.addEdit("vInput")
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.submit())
myGui.show
winwaitclose myGui
msgbox edt1.text

You do not even need vInput.

[teadrinker]

You do not even need vInput.

Moreover, you don't need submit() in this case.

Code: Select all

myGui:=Gui()
editObj := myGui.addEdit()
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.Hide())
myGui.show()
winwaitclose myGui
msgbox editObj.Text

[yousef_badr23]

You do not even need vInput.

Moreover, you don't need submit() in this case.

Code: Select all

myGui:=Gui()
editObj := myGui.addEdit()
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.Hide())
myGui.show()
winwaitclose myGui
msgbox editObj.Text

The problem with this approach is that I can't close the gui to stop the script, it will always get the control text.

[yousef_badr23]

Thanks for all the responses

[teadrinker]

The problem with this approach is that I can't close the gui to stop the script, it will always get the control text.

Why not:

Code: Select all

myGui:=Gui()
myGui.onEvent('Close', (*) => ExitApp())
editObj := myGui.addEdit()
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.Hide())
myGui.show()
winwaitclose myGui
msgbox editObj.Text

[yousef_badr23]

The problem with this approach is that I can't close the gui to stop the script, it will always get the control text.

Why not:

Code: Select all

myGui:=Gui()
myGui.onEvent('Close', (*) => ExitApp())
editObj := myGui.addEdit()
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.Hide())
myGui.show()
winwaitclose myGui
msgbox editObj.Text

Better! Is there a way to use Exit instead of ExitApp? I understand that having a separate thread for the event would make this difficult.

[teadrinker]

Maybe like this:

Code: Select all

myGui:=Gui()
myGui.onEvent('Close', (*) => myGui.Destroy())
editObj := myGui.addEdit()
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.Hide())
myGui.show()
winwaitclose myGui
if !WinExist()
    return
msgbox editObj.Text

[yousef_badr23]

Maybe like this:

Code: Select all

myGui:=Gui()
myGui.onEvent('Close', (*) => myGui.Destroy())
editObj := myGui.addEdit()
myGui.addButton(,"Submit").onEvent("Click",(*)=> myGui.Hide())
myGui.show()
winwaitclose myGui
if !WinExist()
    return
msgbox editObj.Text

Thanks alot!!!