How to batch import ahk scripts using 'Loop Files'? Topic is solved

[XMB-7]

I'd like to import (using #include) multiple AHK scripts into one single script.
However, the following code snippet reported an error that the '.../a_loopfilepath' file doesn't exist.
Appreciate any guidance on this issue.

Code: Select all

base_dir := 'utils'
Loop Files, (base_dir . '/' . '*.ahk'), 'R'
{
    #Include A_LoopFilePath
    ; A_LoopFilePath='utils/test.ahk'
    ; directly #Include 'utils/test.ahk' works
    break
}

[boiler]

#Include happens before the script is run, so you can't have it be part of a loop or anything like that. You can automate the creation of the list of files and then paste that text into your script. It cannot be done dynamically.

[ntepa]

You can automatically create a file instead, then include that:

Code: Select all

#Include *i auto_includes.ahk

AutoInclude("R", "utils")

; recurse - R to recurse
; folders - variadic list of folders to include
AutoInclude(recurse?, Folders*) {
    static writeFile := A_WorkingDir "\auto_includes.ahk"
    newIncludes := ""
    for folder in Folders {
        if !(FileExist(folder) ~= "D")
            throw Error("Folder not found", -2, folder)
        loop files, folder "\*.ahk", "F" (recurse??"") {
            if A_LoopFileFullPath = writeFile
            || A_LoopFileFullPath = A_ScriptFullPath
            || A_LoopFileFullPath = A_LineFile
                continue
            newIncludes .= "#Include *i " A_LoopFileFullPath "`n"
        }
    }
    currentIncludes := FileRead(writeFile, "`n UTF-8")
    if currentIncludes != newIncludes {
        fileObj := FileOpen(writeFile, "w`n")
        fileObj.Write(newIncludes)
        fileObj.Close()
        Reload()
        Exit()
    }
}