Ocr.ahk

[Felix Siano]

Is it possible to modify the code to be activated when pressing F1 and when clicking with the left mouse it copies it to the clipboard?

Code: Select all

#include OCR.ahk

CoordMode "Mouse", "Screen"
CoordMode "ToolTip", "Screen"

Loop {
    MouseGetPos(&X, &Y)
    Highlight(x-75, y-25, 150, 50)
    ToolTip(OCR.FromRect(X-75, Y-25, 150, 50,,2).Text, , Y+40)
	
	
}

Highlight(x?, y?, w?, h?, showTime:=0, color:="Red", d:=2) {
	static guis := []

	if !IsSet(x) {
        for _, r in guis
            r.Destroy()
        guis := []
		return
    }
    if !guis.Length {
        Loop 4
            guis.Push(Gui("+AlwaysOnTop -Caption +ToolWindow -DPIScale +E0x08000000"))
    }
	Loop 4 {
		i:=A_Index
		, x1:=(i=2 ? x+w : x-d)
		, y1:=(i=3 ? y+h : y-d)
		, w1:=(i=1 or i=3 ? w+2*d : d)
		, h1:=(i=2 or i=4 ? h+2*d : d)
		guis[i].BackColor := color
		guis[i].Show("NA x" . x1 . " y" . y1 . " w" . w1 . " h" . h1)
	}
	if showTime > 0 {
		Sleep(showTime)
		Highlight()
	} else if showTime < 0
		SetTimer(Highlight, -Abs(showTime))
}

[Descolada]

Code: Select all

#include OCR.ahk

CoordMode "Mouse", "Screen"
CoordMode "ToolTip", "Screen"

Loop {
    MouseGetPos(&X, &Y)
    Highlight(x-75, y-25, 150, 50)
    ToolTip(currentText := OCR.FromRect(X-75, Y-25, 150, 50,,2).Text, , Y+40)
}

F1 & LButton::A_Clipboard := currentText

Highlight(x?, y?, w?, h?, showTime:=0, color:="Red", d:=2) {
	static guis := []

	if !IsSet(x) {
        for _, r in guis
            r.Destroy()
        guis := []
		return
    }
    if !guis.Length {
        Loop 4
            guis.Push(Gui("+AlwaysOnTop -Caption +ToolWindow -DPIScale +E0x08000000"))
    }
	Loop 4 {
		i:=A_Index
		, x1:=(i=2 ? x+w : x-d)
		, y1:=(i=3 ? y+h : y-d)
		, w1:=(i=1 or i=3 ? w+2*d : d)
		, h1:=(i=2 or i=4 ? h+2*d : d)
		guis[i].BackColor := color
		guis[i].Show("NA x" . x1 . " y" . y1 . " w" . w1 . " h" . h1)
	}
	if showTime > 0 {
		Sleep(showTime)
		Highlight()
	} else if showTime < 0
		SetTimer(Highlight, -Abs(showTime))
}

[Felix Siano]

perfect! Thanks

[Felix Siano]

I'm trying to add to increase or decrease the size of the red highlight.
I'm putting it inside the loop. Am I doing something wrong
Last question! You helped me a lot!

Code: Select all

#include OCR.ahk
#Requires AutoHotkey v2.0
CoordMode "Mouse", "Screen"
CoordMode "ToolTip", "Screen"
Width := 70
Height := 70
Loop {
MouseGetPos(&X, &Y)
Highlight(X - Width / 2, Y - Height / 2, Width, Height)
ToolTip(currentText := OCR.FromRect(X - Width / 2, Y - Height / 2, Width, Height, , 2).Text, , Y + 40)
}
~LButton::
{
A_Clipboard := currentText
ExitApp
}


Up::
{
width := Width + 3
Height := Height +3 
Return
}


Down::
{
width := Width - 3
Height := Height - 3 
Return
}


Highlight(x?, y?, w?, h?, showTime := 0, color := "Blue", d := 2) {
static guis := []
if !IsSet(x) {
for _, r in guis
r.Destroy()
guis := []
return
}
if !guis.Length {
Loop 4
guis.Push(Gui("+AlwaysOnTop -Caption +ToolWindow -DPIScale +E0x08000000"))
}
Loop 4 {
i := A_Index
x1 := (i = 2 ? x + w : x - d)
y1 := (i = 3 ? y + h : y - d)
w1 := (i = 1 or i = 3 ? w + 2 * d : d)
h1 := (i = 2 or i = 4 ? h + 2 * d : d)
guis[i].BackColor := color
guis[i].Show("NA x" . x1 . " y" . y1 . " w" . w1 . " h" . h1)
}
if showTime > 0 {
Sleep(showTime)
Highlight()
} else if showTime < 0
SetTimer(Highlight, -Abs(showTime))
}

[Descolada]

Global-scope variables (defined inside the auto-execute section) can be by default from a local scope (hotkey) only read. To change the variable you need to define it as global:

Code: Select all

#include OCR.ahk
#Requires AutoHotkey v2.0
CoordMode "Mouse", "Screen"
CoordMode "ToolTip", "Screen"
Width := 70, Height := 70
Loop {
	MouseGetPos(&X, &Y)
	Highlight(X - Width // 2, Y - Height // 2, Width, Height)
	ToolTip(currentText := OCR.FromRect(X - Width // 2, Y - Height // 2, Width, Height, , 2).Text, , Y + 40)
}
~LButton::
{
	A_Clipboard := currentText
	ExitApp
}

Up::global height += 3
Down::global height -= 3
Left::global width += 3
Right::global width -= 3

Highlight(x?, y?, w?, h?, showTime := 0, color := "Blue", d := 2) {
	static guis := []
	if !IsSet(x) {
		for _, r in guis
			r.Destroy()
		guis := []
		return
	}
	if !guis.Length {
		Loop 4
			guis.Push(Gui("+AlwaysOnTop -Caption +ToolWindow -DPIScale +E0x08000000"))
	}
	Loop 4 {
		i := A_Index
		x1 := (i = 2 ? x + w : x - d)
		y1 := (i = 3 ? y + h : y - d)
		w1 := (i = 1 or i = 3 ? w + 2 * d : d)
		h1 := (i = 2 or i = 4 ? h + 2 * d : d)
		guis[i].BackColor := color
		guis[i].Show("NA x" . x1 . " y" . y1 . " w" . w1 . " h" . h1)
	}
	if showTime > 0 {
		Sleep(showTime)
		Highlight()
	} else if showTime < 0
		SetTimer(Highlight, -Abs(showTime))
}

[Felix Siano]

PERFECT! THANKS! BREAKING MY HEAD HERE

[Felix Siano]

one last doubt. Is it possible to copy with the original line break?

[Descolada]

Yes it is possible. OCR.FromRect(...).Text outputs the text without linebreaks, but you can loop over OCR.FromRect(...).Lines, get Line.Text and concatenate them with a linebreak.

[emp00]

Yes it is possible. OCR.FromRect(...).Text outputs the text without linebreaks, but you can loop over OCR.FromRect(...).Lines, get Line.Text and concatenate them with a linebreak.

I am trying to achieve exactly this (getting the OCR'ed text with line breaks from an image) --> can you show me how this "loop" must look like? I just need a simple string variable including the linebreaks...

Code: Select all

OCRText_Lines := OCR.FromBitmap(hBitmap_Clipboard, ).Lines ; This contains the OCR'ed lines
OCRText_with_Linebreaks := xxxxxx ???

[Descolada]

@emp00

Code: Select all

OCRText_Lines := OCR.FromBitmap(hBitmap_Clipboard, ).Lines
OCRText_with_Linebreaks := ""
for line in OCRText_Lines
    OCRText_with_Linebreaks .= line.Text "`n"
OCRText_with_Linebreaks := Trim(OCRText_with_Linebreaks, "`n")
MsgBox OCRText_with_Linebreaks