Very first Autohotkey V2 script, need advice

[hlbnet]

Hello everybody,

Here is my very first Autohotkey V2 script. I want to remap around 50 keys of my keyboard, plus a lot of "modified" states (with Shift, Control, Alt, Shift+Control, Shift+Alt, Control+Alt, Shift+Control+Alt). In total, I expect to have a few hundreds of hotkeys.

I started with remaping only 4 keys (without modifier): j, k, i and l. Here is my script. It seems to works well for now.

My question to experienced Autohotkey V2 users :
Is there a shorter way to get the same result with Autohotkey V2 ?
Do you think it will perform well (be responsive ...) after having added a few hundreds of other hotkeys in my script ?

Code: Select all

#SingleInstance Force
Hotkey "<", RemapAll
Hotkey "< up", RestoreAll

RemapAll(ThisHotkey)
{
	Hotkey "j", Key_j, "On"
	Hotkey "k", Key_k, "On"
	Hotkey "i", Key_i, "On"
	Hotkey "l", Key_l, "On"
}

RestoreAll(ThisHotkey)
{
	Hotkey "j", "Off"
	Hotkey "k", "Off"
	Hotkey "i", "Off"
	Hotkey "l", "Off"
}

Key_j(ThisHotkey)
{
    SendInput "{Left}"
}

Key_k(ThisHotkey)
{
    SendInput "{Down}"
}

Key_i(ThisHotkey)
{
    SendInput "{Up}"
}

Key_l(ThisHotkey)
{
    SendInput "{Right}"
}

Thanks by advance.

[mikeyww]

Welcome to this AutoHotkey forum!

Yes, there is a shorter and easier way. Instead of calling the Hotkey function, just map your hotkeys directly.

Code: Select all

#Requires AutoHotkey v2.0
j::Left

Performance will not suffer, but your memory might suffer in trying to remember hundreds of key sequences. Using hotstrings could be one way to address this.

[AHK_user]

This is the same script, written shorter:

Code: Select all

#Requires AutoHotkey v2.0
#SingleInstance force

Hotkey("<", RemapAll)
Hotkey("< up", RestoreAll)

RemapAll(ThisHotkey){
	Hotkey("j", (*)=>(SendInput("{Left}")), "On")
	Hotkey("k", (*)=>(SendInput("{Down}")), "On")
	Hotkey("i", (*)=>(SendInput("{Up}")), "On")
	Hotkey("l", (*)=>(SendInput("{Right}")), "On")
}

RestoreAll(ThisHotkey){
	Hotkey("j", "Off")
	Hotkey("k", "Off")
	Hotkey("i", "Off")
	Hotkey("l", "Off")
}

[hlbnet]

Welcome to this AutoHotkey forum!

Yes, there is a shorter and easier way. Instead of calling the Hotkey function, just map your hotkeys directly.

Code: Select all

#Requires AutoHotkey v2.0
j::Left

Performance will not suffer, but your memory might suffer in trying to remember hundreds of key sequences. Using hotstrings could be one way to address this.

Thank for your answer, but I expected the same behaviour as my script, which is not the case of your proposal. Maybe my post wasn't clear on this.

[mikeyww]

To block (release) the modifiers, you can use Send.

Code: Select all

#Requires AutoHotkey v2.0
#HotIf GetKeyState('<', 'P')
*j::Send '{Left}'
*i::Send '{Up}'
*k::Send '{Down}'
*l::Send '{Right}'
#HotIf

Or possibly:

Code: Select all

#Requires AutoHotkey v2.0
<::<
< & j::Send '{Left}'
< & i::Send '{Up}'
< & k::Send '{Down}'
< & l::Send '{Right}'

US keyboard, but there may be key jamming with K:

Code: Select all

#Requires AutoHotkey v2.0

< Up::Send A_PriorKey = ',' ? '<' : ''

#HotIf GetKeyState('Shift', 'P')
, & j::Send '{Left}'
, & i::Send '{Up}'
, & k::Send '{Down}'
, & l::Send '{Right}'
#HotIf