How to store last active folder's filepath and paste it when the "Save as" window pops up

[Avastgard]

I want a script that will do the following:

1. Run in the background and whenever an Explorer folder is activated, store that folder's filepath in a variable. If a new folder is activated, the new filepath replaces the previous one, so there is always just one filepath stored.
2. Whenever the "Save as" window pops up, the default save location (which is almost never what I need it to be) will be changed to the last stored filepath. The "Save as" window doesn't need to already show up on the desired location, something like Ctrl + L to select the address bar and pasting the stored filepath would be enough.

I'm still a noob in v1 and know next to nothing about v2, but I would like this to be written in v2 to get more used to it, so any help is appreciated.

[WarlordAkamu67]

Hello.

This worked for me. Tested trying to save Adobe Illustrator files.

Code: Select all

#Requires AutoHotkey v2.0+
#SingleInstance

SetTimer(checkforFolder, 100)

; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;
; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;
; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;

get_Active_Explorer_Path() {
  explorerHwnd := WinActive("ahk_class CabinetWClass")
  if (explorerHwnd) {
    for window in ComObject("Shell.Application").Windows {
      if (window.hwnd==explorerHwnd) {
        return(window.Document.Folder.Self.Path)
}
}
}
  return(0)
}

; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;

checkforFolder() {
  static folderPath := ""
  if (pathString := get_Active_Explorer_Path()) {
    folderPath := pathString
} else if (WinActive("Save As")) {
    Send("^l")
    Sleep(100)
    SendText(folderPath)
    Sleep(100)
    Send("{enter}")
    WinWaitClose("Save As")
}
  return
}

[WarlordAkamu67]

I receive an error when closing the window. Will update when I can, or if someone else has a solution? I didn't want to just throw it into a try block.

[rommmcek]

Saving the path is not needed.

Spoiler

Code: Select all

#Requires AutoHotkey v2+
#SingleInstance Force
SetTitleMatchMode "RegEx"

While ((Tbw:="ToolbarWindow32", exId:="ahk_class (Cabinet|Explore)WClass", Edt:="Edit2", ap:=StrSplit(A_Desktop, "\")), 1) {
    WinWaitActive sd:= "i)^Save|Open|Choose ahk_class #32770" ; sd - Save dialog
    try While (InStr(exPth:= RegExReplace(ControlGetText(Tbw (RegExReplace(A_OSVersion, "(^[^.]*\.)|\.", "$1")<10.022000? 3: 4), exId), "^.+:\s"), ":\")? "": exPth:= ap[1] "\" ap[2] (exPth=A_UserName? "": "\" A_UserName) "\" exPth, InStr(sp:= RegExReplace(ControlGetText(Tbw (InStr(WinGetTitle(sd), "Save")? "4": "3"), sd), "^.+:\s"), ":\")? "": sp:= ap[1] "\" ap[2] (sp=A_UserName? "": "\" A_UserName) "\" sp, DirExist(exPth) && exPth != sp)
       SetPath(exPth)
    WinWaitNotActive sd
}

#HotIf WinActive(sd)
F3:: { ; now the Hotkey is context sesitive and will trigger only if Save dialog is Active  
    Static count:= 0, arrPth:= ["Downloads", "Documents", "Music", "Pictures", "Videos", "C:\Users"] ; Default Paths (Paths may lack a part until including A_UserName)
    While KeyWait("F3", "D T.3")
        count++, KeyWait("F3")
    try While (InStr(exPth:= arrPth[count>arrPth.Length? arrPth.Length: count], (count:= 0, ":\"))? "": exPth:= ap[1] "\" ap[2] (exPth=A_UserName? "": "\" A_UserName) "\" exPth, InStr(sp:=RegExReplace(ControlGetText(Tbw (InStr(WinGetTitle(sd), "Save")? "4": "3"), sd), "^.+:\s"), ":\")? "": sp:= ap[1] "\" ap[2] (sp=A_UserName? "": "\" A_UserName) "\" sp, DirExist(exPth) && exPth != sp)
       SetPath(exPth)
}

SetPath(Pth) {
        SendMessage(0x111, 0x500,, Tbw (InStr(WinGetTitle(sd), "Save")? "4": "3"), sd)
        While ControlGetClassNN(ControlGetFocus(sd)) != Edt
            Continue
        While (ControlSetText(Pth, Edt, sd), ControlGetText(Edt, sd) != Pth)
            Continue
        ControlClick(Tbw (InStr(WinGetTitle(sd), "Save")? "5": "4"), sd)
        While !ControlGetVisible(Tbw (InStr(WinGetTitle(sd), "Save")? "4": "3"), sd)
            Sleep 15
        While (ControlFocus("Edit1", sd), ControlGetClassNN(ControlGetFocus(sd)) != "Edit1")
            Continue
}

[Avastgard]

Saving the path is not needed.

Spoiler

Code: Select all

#Requires AutoHotkey v2+
#SingleInstance
SetTitleMatchMode 2

loop {
  WinWaitActive "Save ahk_class #32770"
  if (explrPath:=get_Active_Explorer_Path())&&!InStr(explrPath, "{") {
    Send "!d"
  try While !ControlGetVisible("Edit2", "A")
    Continue
  While explrPath!=ControlGetText("Edit2", "A")
    ControlSetText explrPath, "Edit2", "A" ;Address bar is more responsive
  ControlSend "{Enter}", "Edit2", "ahk_class #32770" ;Using Class is less general
  try While !ControlGetVisible("ToolbarWindow324", "A")
    Continue
  ControlFocus "Edit1", "A"
  } WinWaitNotActive "Save ahk_class #32770"
}

^F3:: { ;the hotkey for some 'default' path
  Static defaultPath:= "C:\" ;set your 'default' path
  if !FileExist(defaultPath)
    Return
  Send "!d"
  try While !ControlGetVisible("Edit2", "A")
    Continue
  While defaultPath!=ControlGetText("Edit2", "A")
    ControlSetText defaultPath, "Edit2", "A"
  ControlSend "{Enter}", "Edit2", "ahk_class #32770" ;Using Class is less general
  try While !ControlGetVisible("ToolbarWindow324", "A")
    Continue
  ControlFocus "Edit1", "A"
}

get_Active_Explorer_Path() {
  explorerHwnd:= WinExist("ahk_class CabinetWClass")
  if (explorerHwnd) {
    for window in ComObject("Shell.Application").Windows {
      if (window.hwnd==explorerHwnd) {
        return(window.Document.Folder.Self.Path)
      }
    }
  } return(0)
}

Edited four times the post/code in the spoiler!

Thanks for the script, but it is way too advanced for me. Could you explain me in general terms what it is doing, particulartly why I need the Ctrl+F3 hotkey and why it sends Alt+d?

[rommmcek]

I asked ChatGPT...

Spoiler

Set Up:

Code: Select all

#Requires AutoHotkey v2+
#SingleInstance
SetTitleMatchMode 2

This part of the script sets up the environment. It requires AutoHotkey version 2 or higher, allows only a single instance of the script to run, and sets the title match mode to 2 (which means it can match anywhere in the title).

Main Loop:

Code: Select all

loop {
  WinWaitActive "Save ahk_class #32770"
  ...
  WinWaitNotActive "Save ahk_class #32770"
}

This is the main loop of the script. It waits for a "Save" dialog (with the class #32770) to become active, performs some actions, and then waits for the dialog to become inactive before looping again.

Active Explorer Path:

Code: Select all

if (explrPath:=get_Active_Explorer_Path())&&!InStr(explrPath, "{") {
  ...
}

This part checks if there's a last active Explorer path that doesn't contain a "{" character. If there is, it performs some actions.

Send Key Strokes:

Code: Select all

Send "!d"
try While !ControlGetVisible("Edit2", "A")
  Continue
While explrPath!=ControlGetText("Edit2", "A")
  ControlSetText explrPath, "Edit2", "A"
ControlSend "{Enter}", "Edit2", "ahk_class #32770"

This part sends the "!d" keystroke (which selects the address bar in the Save dialog), waits for the "Edit2" control to become visible, sets the text of the "Edit2" control to the last active Explorer path, and then sends the Enter key.

Control Focus:

Code: Select all

try While !ControlGetVisible("ToolbarWindow324", "A")
  Continue
ControlFocus "Edit1", "A"

This part waits for the "ToolbarWindow324" control to become visible, and then sets the focus to the "Edit1" control.

Hotkey Definition:

Code: Select all

^F3:: { 
  ...
}

This part defines a hotkey (Ctrl + F3) that performs similar actions to the main loop, but with a static default path.

Function Definition:

Code: Select all

get_Active_Explorer_Path() {
  ...
}

This part defines a function that gets the path of the last active Explorer window.

In summary, this script waits for a Save dialog to become active, sets the path in the dialog to the path of the last active Explorer window, and then waits for the dialog to become inactive before repeating. It also defines a hotkey that sets the path in the dialog to a static default path.

P.s.: !d does essentially the same as ^l, but now I know how to do it without any of these.
P.p.s.: Script has potential flaws have new versions, no time now, report issues.

[Avastgard]

Saving the path is not needed.

Spoiler

Code: Select all

#Requires AutoHotkey v2+
#SingleInstance
SetTitleMatchMode 2

loop {
  WinWaitActive "Save ahk_class #32770"
  if (explrPath:=get_Active_Explorer_Path())&&!InStr(explrPath, "{") {
    Send "!d"
  try While !ControlGetVisible("Edit2", "A")
    Continue
  While explrPath!=ControlGetText("Edit2", "A")
    ControlSetText explrPath, "Edit2", "A" ;Address bar is more responsive
  ControlSend "{Enter}", "Edit2", "ahk_class #32770" ;Using Class is less general
  try While !ControlGetVisible("ToolbarWindow324", "A")
    Continue
  ControlFocus "Edit1", "A"
  } WinWaitNotActive "Save ahk_class #32770"
}

^F3:: { ;the hotkey for some 'default' path
  Static defaultPath:= "C:\" ;set your 'default' path
  if !FileExist(defaultPath)
    Return
  Send "!d"
  try While !ControlGetVisible("Edit2", "A")
    Continue
  While defaultPath!=ControlGetText("Edit2", "A")
    ControlSetText defaultPath, "Edit2", "A"
  ControlSend "{Enter}", "Edit2", "ahk_class #32770" ;Using Class is less general
  try While !ControlGetVisible("ToolbarWindow324", "A")
    Continue
  ControlFocus "Edit1", "A"
}

get_Active_Explorer_Path() {
  explorerHwnd:= WinExist("ahk_class CabinetWClass")
  if (explorerHwnd) {
    for window in ComObject("Shell.Application").Windows {
      if (window.hwnd==explorerHwnd) {
        return(window.Document.Folder.Self.Path)
      }
    }
  } return(0)
}

Edited four times the post/code in the spoiler!

Unfortunately it's not working for me. I made some changes to the script, but still no luck. Here is the exact same script I'm using:

Code: Select all

#Requires AutoHotkey v2+
#SingleInstance
SetTitleMatchMode 2

loop {
  WinWaitActive "Save ahk_class #32770"
  if (explrPath:=get_Active_Explorer_Path())&&!InStr(explrPath, "{") {
    Send "^l" ; !d does not select the address bar in my computer.
  try While !ControlGetVisible("Edit2", "A")
    Continue
  While explrPath!=ControlGetText("Edit2", "A")
    ControlSetText explrPath, "Edit2", "A" ;Address bar is more responsive
  ControlSend "{Enter}", "Edit2", "ahk_class #32770" ;Using Class is less general
  try While !ControlGetVisible("ToolbarWindow324", "A")
    Continue
  ControlFocus "Edit1", "A"
  } WinWaitNotActive "Save ahk_class #32770"
}

^F2:: { ;the hotkey for some 'default' path. >>> I already use ^F3 for something else, so I changed it to ^F2
  Static defaultPath:= "C:\Users\flima\Downloads" ;set your 'default' path
  if !FileExist(defaultPath)
    Return
  Send "^l"
  try While !ControlGetVisible("Edit2", "A")
    Continue
  While defaultPath!=ControlGetText("Edit2", "A")
    ControlSetText defaultPath, "Edit2", "A"
  ControlSend "{Enter}", "Edit2", "ahk_class #32770" ;Using Class is less general
  try While !ControlGetVisible("ToolbarWindow324", "A")
    Continue
  ControlFocus "Edit1", "A"
}

get_Active_Explorer_Path() {
  explorerHwnd:= WinExist("ahk_class CabinetWClass")
  if (explorerHwnd) {
    for window in ComObject("Shell.Application").Windows {
      if (window.hwnd==explorerHwnd) {
        return(window.Document.Folder.Self.Path)
      }
    }
  } return(0)
}

Perhaps I need a Sleep between lines 6 and 7? Right now the script doesn't even select the address bar of the "Save as" window when I try to download a chrome page. I checked it and it's class #32770.

[rommmcek]

For me on Win10 works your version too. On Win11 I can test it only in the weekend.
Now we have to debug it. First try to run the script as Administrator.
Then, start by sections as declared by ChatGPT (I edited it to be better shown).

E.g.:

Code: Select all

loop {
  WinWaitActive "Save ahk_class #32770"
  MsgBox WinGetTitle("A")
  WinWaitNotActive "Save ahk_class #32770"
}

Code: Select all

MsgBox explrPath:=get_Active_Explorer_Path()

get_Active_Explorer_Path() {
  explorerHwnd:= WinExist("ahk_class (Cabinet|Explore)WClass")
  if (explorerHwnd) {
    for window in ComObject("Shell.Application").Windows {
      if (window.hwnd==explorerHwnd) {
        return(window.Document.Folder.Self.Path)
      }
    }
  } return(0)
}

And so on for every section!

[rommmcek]

Indeed on Win11 in some applications there was a problem and even on Win10 on some "asleepy" browser (that was not used for a prolonged period of time) the FileName Control did not focus after the Path setting...
I edited the code to be more robust yet still fast and updated the post above.

P.s.: Since e.g. launching Win Explorer from batch file, doesn't seem to support COM, I rewrote code based only on ControlGet/ControlSet. Sending Enter is dangerous, so is changing Folder via File-name Control.
Updated the post above, it should work on Win11 too (now only one safe version, but working on Open dialog too).

[rommmcek]

Finished the script above.
Hope I'll get some feedback from both Win10 & Win11.