Best way to ensure single instance of GUI?

[kunkel321]

With some help from gpt, then some additional tweaking, I got the below code working. Is this the best way to ensure that I don't get multiple instances of g2? (Assume that the user clicks the g1 'make' button over and over.)

It occurs to me to keep g2 in RAM and just show/hide it... Should I do that, or do you guys think the approach below is all-good?

Code: Select all

#SingleInstance
#Requires AutoHotkey v2+
; multi gui test

g1 := Gui()
g1.add('text',, 'click for on-demand gui')
g1.add('button', 'w300', 'make').OnEvent('click', makeg2)
g1.Show()

g2 := 0  ; Initialize g2 as null

makeg2(*)
{	; Check if g2 exists and is an object, then destroy it
	global g2
	if (IsObject(g2))
		g2.Destroy()
	g2 := Gui()
	g2.add('text',, 'this is gui 2')
	g2butt := g2.add('button', 'w200', 'okay')
	g2butt.OnEvent('click', alldone)
	g2.Show()
}

alldone(*)
{	g2.Destroy() 
	MsgBox('thank you')
}

[RussF]

I always create all my GUIs up front in the autoexec section and then just show or hide them as need be. I've seen many others here agree with that. It's not like you're talking about gigabytes of RAM being used to keep your GUIs loaded - you'll actually probably hardly notice a difference.

Russ

[Seven0528]

　Personally, if it isn't too heavy, I prefer to Destroy and recreate Gui every time.

Code: Select all

#Requires AutoHotkey v2.0
#SingleInstance Force
gui1 := gui()
gui1.add("Button", "w300", "Gui1").onEvent("Click", gui1Button_Click)
gui1.Show()
gui1Button_Click(guiCtrlObj, info)    {
    gui2.show()
}
;---------------------
gui2 := gui()
gui2.add("Button", "w200", "Gui2").onEvent("Click", gui2Button_Click)
gui2.onEvent("Close", gui2_Close)
gui2Button_Click(guiCtrlObj, info)    {
    winClose(guiCtrlObj.gui)
}
gui2_Close(guiObj)    {
    guiObj.hide()
    return true ;  Prevent the window from closing.
}

[xMaxrayx]

@kunkel321
depends if you use g2 a lot you better keep it on RAM by hide() method, RAM is cheap these days and people prefer speed and snapy experience.

you can add if statement to check if g2 exited like this (i didn't test it you gone need to fix it.)

if winexit(your g2 title){
g2.show()
return
}

[Noitalommi_2]

Hi.

You could also disable the button to prevent it from being used multiple times.

Code: Select all

#SingleInstance
#Requires AutoHotkey v2+

g1 := Gui()
g1.add('text',, 'click for on-demand gui')
g1.add('button', 'w300', 'make').OnEvent('click', makeg2)
g1.Show()

makeg2(GuiCtrlObj, *) {

	GuiCtrlObj.Enabled := false

	g2 := Gui()
	g2.add('text',, 'this is gui 2')
	g2butt := g2.add('button', 'w200', 'okay')
	g2butt.OnEvent('click', alldone)
	g2.Show()

	alldone(*) {
		g2.Destroy()
		MsgBox('thank you')
		GuiCtrlObj.Enabled := true
	}
}

[kunkel321]

These are all excellent approaches. Thanks Folks!