How to change GUI button text (v2) without destroying/recreating new GUI? Topic is solved

[alawsareps]

When I click the button called "OLD", it changes to "NEW", but to achieve that, it first need to destroy the GUI, then create it agan. just an ugly behavior.

Code: Select all

#Requires AutoHotkey v2.0

global btn_name := "OLD"

x::
{
    MyGui := Gui(, "Mouse")
    MyGui.SetFont("s10") 
    MyGui.Add("Button", "w220 h30", btn_name).OnEvent("Click", ButtonClick)

    MyGui.Show("w250 h100")

    ButtonClick(*) {
        global btn_name := "NEW"  
        MyGui.Destroy()
        send "{x}"
    }
}

[Draken]

Code: Select all

#Requires AutoHotkey v2.0

btn_name := "OLD"

x::{
    global
    MyGui := Gui(, "Mouse")
    MyGui.SetFont("s10") 
    MyGui.Add("Button", "w220 h30 vbtn", btn_name).OnEvent("Click", ButtonClick)

    MyGui.Show("w250 h100")

    ButtonClick(*) {
        Mygui["btn"].Text := "NEW"
    }
}

[just me]

The first parameter of an event function is the Guicontrol object (similar to A_GuiControl in v1). So you can use:

Code: Select all

    ButtonClick(BtnObj, *) {
        BtnObj.Text := "NEW"
    }

to change the button's caption.