spread an array in function parameters? Topic is solved

[hpta]

Is it possible in the following example to do something like? (preferably in a simple way)

Code: Select all

this.f.Call(this.params.spread())

instead of

Code: Select all

this.f.Call(this.params[1], this.params[2], this.params[3])

Code: Select all

class F_obj {
   f := ""
   params := ""
   __New(f, params*) {
      this.f := f
      this.params := params
   }
   Call() {
   ; this works but it's cumbersome
      ; this.f.Call(this.params[1], this.params[2], this.params[3])
      
   ; this doesn't work
       this.f.Call(this.params)
   }
}

F1 := F_obj(foo, "a", "b", "c")
F1()

foo(p1,p2,p3) {
   msgbox p1 p2 p3
}

[swagfag]

Code: Select all

this.f.Call(this.params*)

[hpta]

Thanks! I really got stuck on this.

[Cornelius-Figgle]

Code: Select all

this.f.Call(this.params*)

I know this is an old topic, but is this possible with a map?

In Python you can have to following:

Code: Select all

function_with_positional_args(*list_of_positional_args)
function_with_keyword_args(**dict_of_keyword_args)

Where * expands a list (ie an array) and ** expands a dictionary (ie a map) - the dictionary keys have to match the parameter names

Using 2 asterisks on a map in AHK throws an error, and using one seems to pass the key names through rather than the values. Is there anyway to pass the map values to function parameters (so that the keys match the parameter names)?

[iPhilip]

Is there anyway to pass the map values to function parameters (so that the keys match the parameter names)?

@Cornelius-Figgle, I don't believe there is a built-in way to do so. You could achieve that by defining a Values property for the Map's in your script as follows:

Code: Select all

DefineMapValuesProperty()
M := Map('a', 'aa', 'b', 'bb', 'c', 'cc')
MsgBox List(M.Values*)

DefineMapValuesProperty() {
   Map.Prototype.DefineProp('Values', {Get: GetValues})
   GetValues(this) {
      Values := []
      for , Value in this
         Values.Push(Value)
      return Values
   }
}

List(Params*) {
   List := ''
   for Value in Params
      List .= Value '`n'
   return List
}