PathX() : Split & modify a filepath easily

[SKAN]

PathX() is an alternative solution for SplitPath(). It breaks down a fullpath to individual parts and returns them as an object. Note that the results from PathX() will be different from SplitPath(). The common reason a filepath is split is to concatenate them back again to form a different filepath. PathX() can do this in one go. Custom key values can be provided as variadic parameters to substitute individual parts of the returned array.
 

PathX() is powered by two API functions

 
1) GetFullPathNameW (kernel32.dll): To pre-process the filepath into a clean fullpath.
2) _wsplitpath (msvcrt.dll): To break down a full filepath into 4 parts.

GetFullPathNameW (kernel32.dll):
The path passed to the function will be converted to a full path unconditionally. If only a filename is passed, it will be resolved to a full path by prefixing the filename with A_WorkingDir. Any relative path will be converted to full path. For example: A_AhkPath . "\..\License.txt" would be converted to "C:\Program Files\AutoHotkey\License.txt" (assuming you did a default install.). If you are passing a fullpath, the first two chars must be a proper drive letter.. means if you pass a path like a file:/// URL, then it will be unconditionally prefixed with A_WorkingDir. GetFullPathNameW() will also clean up the filepath. It will convert any forward slashes present in filepath to back slashes and then remove any redundant ones. For eg. D:\/Folder\/\/\\\\file.ext will be cleaned up to D:\Folder\file.ext before it is split into parts. GetFullPathNameW() will fail, if null filepath is passed or filepath is longer than MAX_PATH (260 chars)

_wsplitpath (msvcrt.dll)
This function breaks down a filepath differently when compared to the output of SplitPath(). It splits a filepath into 4 parts (red/blue/red/blue) as follows:
Example path: C:\Program Files\AutoHotkey\AutoHotkey.exe

Code: Select all

C:                              ;  Drive - First 2 chars 
\Program Files\AutoHotkey\      ;  Dir   - Every thing after first colon up till the last slash (last slash will be included)
AutoHotkey                      ;  Fname - Every thing in between last slash and last period  
.exe                            ;  Ext   - The last period and every thing after it

If anyone wants to test and validate my above statements, use two colons :: after drive letter as well as multiple slashes before the filename.
Then one can easily see how _wsplipath() does the chop chop.
_wsplitpath() will fail in any of the individual filepath part exceeds MAX_PATH (260 chars).

The object returned by PathX() will contain all the four properties namely Drive, Dir, Fname, Ext. and additionally: Folder (Drive+Dir), File (Fname+Ext) and Full (Drive+Dir+Fname+Ext). The reason for returning the fullpath is that PathX() accepts variadic parameters through which any or 3 of the filepath parts can be replaced with new values. The Full key property (in returned object) will contain the modified filepath as value.
 

---

 
PathX(Path, X*)
PathX() splits a filepath and returns filepath parts as an object with following properties:

• 1) Drive
• 2) Dir
• 3) Fname (Filename without extension)
• 4) Ext
• 5) Folder (Concatenation of 1 & 2)
• 6) File (Concatenation of 3 & 4)
• 7) Full (Concatenation of 1,2,3 & 4)

 
 
Try the following example to see the properties returned:

Code: Select all

#Requires AutoHotkey v2.0

Px := PathX(A_AhkPath)
MsgBox( "Drive`t:`t"    Px.Drive   "`n"
      . "Dir`t:`t"      Px.Dir     "`n"
      . "Fname`t:`t"    Px.Fname   "`n"
      . "Ext`t:`t"      Px.Ext     "`n"
      . "Folder`t:`t"   Px.Folder  "`n"
      . "File`t:`t"     Px.File    "`n"
      . "Full`t:`t"     Px.Full
      , "PathX(A_AhkPath)" )

 

 
 
The first 4 properties Drive, Dir, Fname and Ext can be overwritten with custom values:

Code: Select all

MsgBox( PathX(A_ScriptName, "Fname:Hello World").Full, "Change name"         )
MsgBox( PathX(A_ScriptName, "Drive:Z:").Full,          "Change drive"        )
MsgBox( PathX(A_ScriptName, "Dir:\").Full,             "Change path to root" )
MsgBox( PathX(A_ScriptName, "Ext:.txt").Full,          "Change extension"    )

 
PathX() will resolve relative path to fullpath unconditionally:

Code: Select all

MsgBox( PathX("..\" . A_ScriptName).Full,                  "One level up"    )
MsgBox( PathX("Sub_folder\Sub_folder\" A_ScriptName).Full, "Two levels down" )

 
One may pass multiple parameters as well as shorten the key names to two chars:
The following example shows how to substitute Drive and Fname in one go.
Note: Make sure there are no spaces between Key:Value unless it was intended.

Code: Select all

MsgBox( PathX(A_ScriptName, "Dr:X:", "Fn:MyScript").Full, "New path" )

 
Keys Fprefix and Fsuffix can be used to add prefix/suffix to Fname.

Code: Select all

MsgBox( PathX(A_ScriptName, "fp:Copy of ").Full,                     "Prefix Fname"  )
MsgBox( PathX(A_ScriptName, "fs:_001").Full,                         "Suffix Fname"  )
MsgBox( PathX(A_ScriptName, "fp:Backup_", "fs:" . "_" . A_Now).Full, "Prefix/Suffix" ) 

 

Additional file extension can be kind of prefixed indirectly by suffixing Fname.

Code: Select all

MsgBox( PathX(A_AhkPath, "fs:.old").Full, "Prefix extension" )

 
Keys Dprefix and Dsuffix may be used to add prefix/suffix to Dir.

Code: Select all

MsgBox( PathX(A_ScriptName, "Dr:N:", "dp:\Backup", "ds:001\").Full, "Prefix/Suffix Dir")

 
Keys Pprefix and Psuffix may be used to add prefix/suffix to Fullpath.

Code: Select all

MsgBox( PathX(A_ScriptName, "pp:file:///").Full,    "Prefix fullpath" )
MsgBox( PathX(A_ScriptName, "pp:\\?\").Full,        "Prefix fullpath" )
MsgBox( PathX(A_ScriptName, "ps::HiddenData").Full, "Suffix ADS name" )

 
Within Loop Files, A_LoopFileName is available but no built-in var for base file name (file name without extension).
PathX() can be used as follows:

Code: Select all

Loop Files, A_AhkPath "\..\*.exe"
    MsgBox( PathX(A_LoopFileFullPath).FName )

 
While File extension can be forced with Ext key for File save dialog...

Code: Select all

sfile   :=  FileSelect("S2", A_DeskTop "\test", "Select save file",  "Documents (*.*)")
sfile2  :=  sfile ? PathX(sfile, "Ext:.txt").Full : ""
MsgBox( sFile "`n" sFile2 )

... *Ext key will add extension only if not already present:

Code: Select all

sfile  :=  FileSelect("S2", A_DeskTop "\test", "Select save file",  "Documents (*.txt)")
sfile2 :=  sfile ? PathX(sfile, "*Ext:.txt").Full : ""
MsgBox( sFile "`n" sFile2 )

---

 
The function:
 

Code: Select all

PathX(Path, X*)             ; PathX() v0.67 by SKAN for ah2 on D34U/D68M @ autohotkey.com/r?p=120582
{
    Local  K,V,N,U, Dr,   Di,   Fn,   Ex
        ,  FPath := Dr := Di := Fn := Ex := Format("{:260}", "")

    U := Map(),  U.Default := "",  U.CaseSense := 0

    For  K, V  in  X
         N     :=  StrSplit(V, ":",, 2)  ;  split X into Key and Value
      ,  K     :=  SubStr(N[1], 1, 2)    ;  reduce Key to leading 2 chars
      ,  U[K]  :=  N[2]                  ;  assign Key and Value to Map

    DllCall("Kernel32\GetFullPathNameW", "str",Trim(Path,Chr(34)), "uint",260, "str",FPath, "ptr",0)
    DllCall("Msvcrt\_wsplitpath", "str",FPath, "str",Dr, "str",Di, "str",Fn, "str",Ex)

    Return {  Drive  :  Dr  :=  U["Dr"] ? U["Dr"] : Dr
           ,  Dir    :  Di  :=  U["dp"] ( U["Di"] ? U["Di"] : Di ) U["ds"]
           ,  Fname  :  Fn  :=  U["fp"] ( U["Fn"]!="" ? U["Fn"] : Fn )  U["fs"]
           ,  Ext    :  Ex  :=  U["*E"]!="" ? ( Ex ? Ex : U["*E"] ) : ( U["Ex"]!="" ? U["Ex"] : Ex )
           ,  Folder :  Dr Di
           ,  File   :  Fn Ex
           ,  Full   :  U["pp"] ( Dr Di Fn Ex ) U["ps"] }
}

[SKAN]

PathU(Filename)
Returns a fully qualified path that is unique in entire filesystem.
 
The function: (Along with examples)

Code: Select all

PathU(Filename)              ;  PathU v0.91 by SKAN for ah2 on D35E/D68M @ autohotkey.com/r?p=535235
{
    Local  OutFile := Format("{:260}", "")
    DllCall("Kernel32\GetFullPathNameW", "str",Filename, "uint",260, "str",OutFile, "ptr",0)
    DllCall("Shell32\PathYetAnotherMakeUniqueName", "str",OutFile, "str",OutFile, "ptr",0, "ptr",0)
    Return OutFile
}

#Requires AutoHotkey v2.0
#SingleInstance

MsgBox( PathU(A_ScriptFullPath) )               ; to copy a backup of this script
MsgBox( PathU(A_ScriptName) )                   ; A_WorkingDir is used to resolve fullpath
MsgBox( PathU(A_AhkPath . "\..\License.txt") )  ; relative path is auto-resolved
MsgBox( PathU(A_ScriptDir) )                    ; Works for folder too..Avoid trailing slash!
MsgBox( PathU(A_Temp . "\ahk.tmp") )            ; Simple way to create a temp file

[ozzii]

Thank you SKAN.
Always a pleasure to read all of your exemples.

[SKAN]

Hi @ozzii

[tdalon]

Many thanks @SKAN
Perfectly done and you saved me some time.