Ich brauche einen senkrechten Progress-Balken, habe aber bisher nur die Gui-Variante gefunden. Ich hätte aber geren den "normalen" Progress mit allen Optionen, aber eben senkrecht.
Geht das?
LG Julius
Senkrechter Progress Topic is solved
Moderator: jNizM
Re: Senkrechter Progress
Ich nehme an, mit der GUI-Variante meinst du den: https://autohotkey.com/docs/commands/Gu ... m#Progress ? Der geht ja auch vertikal.
Aber was ist dann ein "normaler" Progress mit allen Optionen - an welche Optionen, die die Gui-Variante nicht hat, denkst du da?
Aber was ist dann ein "normaler" Progress mit allen Optionen - an welche Optionen, die die Gui-Variante nicht hat, denkst du da?
Re: Senkrechter Progress
Moin,
es gibt wohl keine Option dafür. Und ich habe Zweifel, ob man das nachträglich ändern kann. Man müsste dann auch die Parameter für das Fensterlayout passend für ein vertikales Control übergeben oder ebenfalls nachträglich korrigieren. Für mich ist ein Progress-Gui einfacher zu handhaben.
es gibt wohl keine Option dafür. Und ich habe Zweifel, ob man das nachträglich ändern kann. Man müsste dann auch die Parameter für das Fensterlayout passend für ein vertikales Control übergeben oder ebenfalls nachträglich korrigieren. Für mich ist ein Progress-Gui einfacher zu handhaben.
Re: Senkrechter Progress
Daran: https://autohotkey.com/docs/commands/Progress.htmgregster wrote:Ich nehme an, mit der GUI-Variante meinst du den: https://autohotkey.com/docs/commands/Gu ... m#Progress ? Der geht ja auch vertikal.
Aber was ist dann ein "normaler" Progress mit allen Optionen - an welche Optionen, die die Gui-Variante nicht hat, denkst du da?
Re: Senkrechter Progress
Eigentlich will ich nur den Balken darstellen, ohne Rahmen, ohne alles. Das geht bei https://autohotkey.com/docs/commands/Progress.htm wesentlich besser als bei der Gui-Variante. Oder ...?just me wrote:Moin,
es gibt wohl keine Option dafür. Und ich habe Zweifel, ob man das nachträglich ändern kann. Man müsste dann auch die Parameter für das Fensterlayout passend für ein vertikales Control übergeben oder ebenfalls nachträglich korrigieren. Für mich ist ein Progress-Gui einfacher zu handhaben.
Re: Senkrechter Progress
Es wäre gut, wenn Du ein Beispiel für Deine Progress Anweisung einstellst. Dann kann ich Dir zeigen, wie man das in ein GUI überführen könnte.
Re: Senkrechter Progress
Gerne:just me wrote:Es wäre gut, wenn Du ein Beispiel für Deine Progress Anweisung einstellst. Dann kann ich Dir zeigen, wie man das in ein GUI überführen könnte.
Code: Select all
Progress, 1:ZH50 W400 R0-%speed% FM22 y200 b1 CBred
loop, % speed
{
Progress, 1:%A_Index%
sleep % T_Progress*10
}
Progress, 1:off
Re: Senkrechter Progress Topic is solved
Das sähe dann ungefähr so aus:
Code: Select all
T_Progress := 10
Speed := 50
; Progress -----------------------------------------------------------
Progress, 1:ZH50 W400 R0-%speed% FM22 Y200 B1 CBred
Loop, %Speed%
{
Progress, 1:%A_Index%
Sleep, % T_Progress*10
}
Progress, 1:Off
; Gui ----------------------------------------------------------------
Gui, New, -Caption +Border +HwndPBGUI
Gui, Margin, 5, 5 ; kannst Du auch auf 0, 0 setzen, dann gibt es keinen Rand
Gui, Add, Progress, h400 w50 Range0-%speed% CRed Vertical +HwndPBCTL
Gui, Show, y200
Loop, %Speed%
{
GuiControl, , %PBCTL%, %A_Index%
Sleep % T_Progress*10
}
Gui, %PBGUI%:Destroy
ExitApp
Re: Senkrechter Progress
Das ist ganz super! Danke!
Re: Senkrechter Progress
Eine Frage noch, bitte: wie lasse ich den Balken rückwärts laufen, als bei 100 anfangen und schrittweise auf Null?
Re: Senkrechter Progress
Code: Select all
i :=100
Gui, New, -Caption +Border +HwndPBGUI
Gui, Margin, 5, 5 ; kannst Du auch auf 0, 0 setzen, dann gibt es keinen Rand
Gui, Add, Progress, h400 w50 Range0-%i% CRed Vertical +HwndPBCTL
Gui, Show, y200
Loop, %i%
{
i--
GuiControl, , %PBCTL%, %i%
Sleep,30
}
Gui, %PBGUI%:Destroy
ExitApp
esc::exitapp
Re: Senkrechter Progress
Danke, garry! Alternativ:
Code: Select all
RangeMin := 0
RangeMax := 100
Gui, New, -Caption +Border +HwndPBGUI
Gui, Margin, 5, 5 ; kannst Du auch auf 0, 0 setzen, dann gibt es keinen Rand
Gui, Add, Progress, h400 w50 Range%RangeMin%-%RangeMax% CRed Vertical +HwndPBCTL, %RangeMax% ; <<<<<
Gui, Show, y200
Loop, % (RangeMax - RangeMin) ; <<<<<
{
GuiControl, , %PBCTL%, +-1 ; <<<<<
Sleep, 30
}
Gui, %PBGUI%:Destroy
ExitApp
Esc::ExitApp
Re: Senkrechter Progress
@just me , danke für die Beispiele
Re: Senkrechter Progress
Danke, das hilft weiter
Who is online
Users browsing this forum: No registered users and 29 guests