Stop a loop with A_TimeIdlePhysical

[Melancoholic]

Hello guys!
I want to script a loop which starts with user input and ends with a keystroke/moving the mouse.
Looking at other posts I found "A_TimeIdlePhysical" which could help but in every instance I saw the code it was always used to start something not to end it.
And the line I was using to break the loop didn't seemed to work
The code I'm using is

Spoiler

#InstallMouseHook
#InstallKeybdHook
^k::
loop
{
send text here{enter}
Random, OutputVar , 13000, 25000
sleep OutputVar
Ifless, A_TimeIdlePhysical, 100, break
}

Can anybody help me?
I'm also fine to end the loop with a specific keystroke like ctrl+l.

[swagfag]

dont use deprecated commands(IfLess, etc) in new scripts

Code: Select all

Esc::ExitApp
^k::
{
	Loop
	{
		Send your_text_here{Enter}
		Sleep rand(1000, 2000)

		if (A_TimeIdlePhysical < 100)
			break
	}
return
}

rand(a, b) {
	Random, rand, a, b
	return rand
}

[Melancoholic]

dont use deprecated commands(IfLess, etc) in new scripts

Code: Select all

Esc::ExitApp
^k::
{
	Loop
	{
		Send your_text_here{Enter}
		Sleep rand(1000, 2000)

		if (A_TimeIdlePhysical < 100)
			break
	}
return
}

rand(a, b) {
	Random, rand, a, b
	return rand
}

Thank you, but pressing a key or moving a mouse didn't break the loop
However Esc::ExitApp did.
FYI I started using AHK today

[swagfag]

yeah, i noticed now too that theres the issue that when the script is sleeping, naturally, no checks are being done, so moving the mouse or pressing a key wont break it

[Xtra]

Code: Select all

#NoEnv

Esc::ExitApp

^k::
    KeyWait, Ctrl
    KeyWait, k
	Loop
	{
		Send your_text_here{Enter}
        if (randSleep(1000, 2000) = false)
            break
	}
return

randSleep(a, b) {
	Random, r, a, b
    Loop, 50
    {
        Sleep r//50
        if (A_TimeIdlePhysical < 25)
            return 0
    }
	return 1
}