Problem beim Aufruf einer Url im IE11 Topic is solved

Stelle Fragen zur Programmierung mit Autohotkey

Moderator: jNizM

Johnny R
Posts: 250
Joined: 03 Oct 2013, 02:07

Problem beim Aufruf einer Url im IE11

16 Mar 2019, 04:14

Wenn ich mit dem Internet Explorer 11 unter Win7 z. B. mit dem Befehl

Code: Select all

Run, C:\Program Files\Internet Explorer\iexplore.exe https://www.autohotkey.com
eine Url aufrufe, wird immer ein neues IE-Fenster mit dieser Url geöffnet obwohl ich bei den IE-Einstellungen unter Internetoptionen->Registerkarten->Von anderen Programmen stammende Links öffnen in: ...einer neuen Registerkarte im aktuellen Fenster angehakt habe, also die Url eigentlich in einem neuen Tab geöffnet haben will.

Ist dieses Verhalten AHK-spezifisch oder ein Bug/eine Eigenart des IE11? Gibt es eine Möglichkeit dieses unerwünschte Verhalten zu ändern, die Url also als neuen Tab in einem aktuell geöffneten IE-Fenster zu öffnen?

Im Firefox funktioniert das übrigens wie gewünscht mit der Befehlszeile

Code: Select all

Run, C:\Program Files\Mozilla Firefox\firefox.exe https://www.autohotkey.com
Vielen Dank!
Last edited by Johnny R on 17 Mar 2019, 14:51, edited 1 time in total.
Ahk_fan
Posts: 50
Joined: 31 Aug 2018, 14:34

Re: Problem mit beim Aufruf einer Url im IE11

16 Mar 2019, 05:23

hi,

hier ein Lösung über die API

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
link1 := "http://www.google.de"
link2 := "http://www.web.de"
Pwb :=  ComObjCreate("InternetExplorer.Application")
Pwb.Visible:=True
Pwb.Navigate(link1)
Pwb.Navigate(link2, 2048)
exitapp
die 2048 erzeugt einen neuen Tab

Grüße
regards,
AHK_fan :)
Johnny R
Posts: 250
Joined: 03 Oct 2013, 02:07

Re: Problem mit beim Aufruf einer Url im IE11

16 Mar 2019, 06:16

Lieber Ahk_fan,

das ist schon mal ein schöner Fortschritt, vielen Dank! Dein Code erzeugt aber leider immer noch ein neues IE-Fenster, auch wenn schon ein IE-Fenster geöffnet ist und auch wenn ich bei link1 den Schalter "2048" angebe, nur link2 wird jetzt wunschgemäß in einem Tab innerhalb dieses durch die Variable pwb definierten Fensters geöffnet. Läßt sich Dein Code so anpassen, dass die Url (bzw. link1) auch in einem außerhalb Deines Codes definierten, bzw. geöffneten, (anderen) Fensters in einem neuen Tab geöffnet wird?

Vielen Dank!
Ahk_fan
Posts: 50
Joined: 31 Aug 2018, 14:34

Re: Problem mit beim Aufruf einer Url im IE11  Topic is solved

16 Mar 2019, 07:03

Hi,

hier was von mir

Code: Select all

ifWinExist, ahk_exe iexplore.exe
{
	WinActivateBottom, ahk_exe iexplore.exe
	Send,^t
	Sleep, 1000
	ControlSend, Edit1, www.spiegel.de, ahk_exe iexplore.exe
	Send,{ENTER}
}
Else
{
	link1 := "http://www.google.de"
	link2 := "http://www.web.de"
	Pwb :=  ComObjCreate("InternetExplorer.Application")
	Pwb.Visible:=True
	Pwb.Navigate(link1)
	Pwb.Navigate(link2, 2048)
}
hier ein anderer Vorschlag, der viel besser ist:

Code: Select all

OutputVar4 = www.google.com

if  hWnd :=  WinExist("ahk_class IEFrame")
{
   For wb in ComObjCreate("Shell.Application").Windows
   {} Until  (hWnd = wb.hwnd)
   params := [OutputVar4, 2048]
}
else
{
   wb := ComObjCreate("InternetExplorer.Application")
   wb.Visible := True
   params := [OutputVar4]
}
wb.Navigate(params*)
While, (wb.ReadyState != 4)
   Sleep, 100
Return
Funktioniert sicherer...
und von hier kopiert: https://autohotkey.com/board/topic/86537-solvedcreating-a-new-ie-tab-instead-of-new-window-if-it-exists/ von jethrow
regards,
AHK_fan :)
Johnny R
Posts: 250
Joined: 03 Oct 2013, 02:07

Re: Problem mit beim Aufruf einer Url im IE11

17 Mar 2019, 01:27

Hallo Ahk_fan,

Deine 2. Variante funktioniert gut! Vielen Dank. Ist zwar etwas kompliziert, aber immerhin. Kannst Du - oder sonst jemand - mir erklären, warum sich der IE11 da so merkwürdig verhält, und zwar trotz entsprechenden Häkchens und obwohl der Firefox das auch problemlos beherrscht? Gibt es vielleicht doch noch einen hilfreichen Registry-Trick oder sonst einen?

Es handelt sich übrigens nicht um ein AHK-spezifisches Problem. Der IE11 verhält sich beim Aufruf unter "Ausführen" und in der cmd-Konsole ebenso problematisch, wie unter AHK...

Viele Grüße!
Ahk_fan
Posts: 50
Joined: 31 Aug 2018, 14:34

Re: Problem mit beim Aufruf einer Url im IE11

17 Mar 2019, 09:17

bitteschön, is ja nicht von mir ;)

mit Run, C:\Program Files\Internet Explorer\iexplore.exe https://www.autohotkey.com startest du eine neue Instanz vom IE, d.h. eine vorhanden wird ignorierert...das siehst du im Taskmanager, da tauchen dann 2 oder mehr Einträge von IE11 auf.
Die Einstellung, die du meinst ist (so denke ich mal) nur gültig, wenn der IE als Standardbrowser läuft, und man per Klick auf einen Link z.B. in einer Email, einen Webseitenaufruf startet. Das ist dann das gleiche wie in AHK Run, www.google.de, da dürfte sich dann theoretisch nur ein neuer TAB öffnen.
Zu Registery oder passenden Commandline-Befehlen finde ich nichts.
hier gibt es noch was: https://www.autohotkey.com/boards/viewtopic.php?f=76&t=36131
funktioniert aber nur wenn IE der Standartbrowser ist.
regards,
AHK_fan :)
Johnny R
Posts: 250
Joined: 03 Oct 2013, 02:07

Re: Problem beim Aufruf einer Url im IE11

17 Mar 2019, 14:58

Die Einstellung, die du meinst ist (so denke ich mal) nur gültig, wenn der IE als Standardbrowser läuft...
Hallo Ahk_fan,

möglich. Aber wenn dem so wäre, würde ein anständiger IE-Programmierer die Einstellungsmöglichkeit ("Häkchen") ja wohl ausgrauen, wenn der IE nicht der Standardbrowser ist, denke ich, nämlich um zu zeigen, dass die Einstellung unter diesen Bedingungen nicht möglich ist. Auf der Registerkarte ist ja viel ausgegraut, so dass es darauf auch nicht mehr ankäme...

Viele Grüße!

Return to “Ich brauche Hilfe”

Who is online

Users browsing this forum: Bing [Bot] and 17 guests