better way to make a pdf from a Word docx Topic is solved

[AmDeG 11]

the following script works. It saves a Word doc then creates a pdf from that Word doc and closes both.

Is there a better way to do it?

Code: Select all

+^!z:: ;save docx as pdf replacing old one with last one if needed
       Send ^s
       Sleep 1500
       Send {F12}    ;FileAs
       Sleep 300
       Send !t  
       Sleep 200
       Send p{Return}
       Sleep 300
       Send y{Return}
       Sleep 1000
       WinClose ahk_class AcrobatSDIWindow
       Sleep 1000
       WinClose ahk_class OpusApp
     ;  Sleep 200
       Send {Return}
    Return

[TheDewd]

This code should create a PDF from the active word document, saving the PDF in the same directory as the opened doc.

Code: Select all

#SingleInstance, Force

oWord := ComObjActive("Word.Application")
oWord.ActiveDocument.SaveAs2("Document.pdf", 17)

[AmDeG 11]

should I add anything else?

it is not working

[aifritz]

Not working could be everything and nothing...
What error do you get?

Also have a look here, if you are using a prior version of word 2010:

https://www.autohotkey.com/boards/viewtopic.php?f=76&t=7332&hilit=ActiveDocument.SaveAs2

[flyingDman]

It works here.
Instead of saveas2 you can also use ExportAsFixedFormat like:

Code: Select all

oWord.ActiveDocument.ExportAsFixedFormat("document.pdf",17)

[AmDeG 11]

it does not work for me

I have the latest version of Word

And I don't get any error. It simply doesn't work

[flyingDman]

Try:

Code: Select all

oWord.ActiveDocument.ExportAsFixedFormat("document.pdf",17,1)

[AmDeG 11]

now it works

in the sense that it does open a pdf window with the file in pdf format

however it does not automatically saves it at the same folder of the original Word file (which would be great too!)

the best would be that I see just a little that the pdf was done and then close knowing that I'll have it at my folder next to the Word original

[flyingDman]

If it opened it means that the file is on your drive. Just look for it (in the same folder as your script maybe?). You can save it in whatever path you want.
To retrieve the path of the the word document use oword.Activedocument.path

[AmDeG 11]

sorry I'm at a loss in order to save the file in the same folder as the Word file

+^s opens de Save As dialog

then I send a Return to open it but I don´t how it works with the oword.Activedocument.path

[flyingDman]

The following should save the .pdf in the same folder as the .docx file wherever the latter is located.

Code: Select all

oWord := ComObjActive("Word.Application")
fullname := oword.Activedocument.fullname
SplitPath, fullname , , OutDir, , OutNameNoExt
oWord.ActiveDocument.ExportAsFixedFormat(OutDir "\" OutNameNoExt ".pdf",17)    
return	

[AmDeG 11]

great Christmas present!