#If WinActive() shorthand? Topic is solved

[leo007]

Hi Everyone,

I got follow script to select full line depending on activity.

Code: Select all

 #If WinActive("ahk_exe notepad.exe") OR WinActive("ahk_exe notepad++.exe") OR WinActive("ahk_exe Code.exe") OR WinActive("ahk_exe studio64.exe") OR WinActive("ahk_exe idea64.exe") OR WinActive("- OneNote ahk_class ApplicationFrameWindow", "OneNote")
  $!LButton:: ; SELECT FULL TEXT LINE IN TEXT
  {
    KeyWait, Alt
    SendInput, {Esc}{LButton}
    SendInput, {HOME}{ShiftDown}{End}{ShiftUp}
    return
  }
  #IfWinActive
  
 #If WinActive("ahk_exe chrome.exe") OR WinActive("ahk_exe firefox.exe")
  $!LButton:: ; SELECT FULL TEXT LINE IN TEXT
  {
    KeyWait, Alt
    SendInput, {Esc}{LButton 3}
    Return
  }
  #IfWinActive
  

is there a shorter way to write this if select activity that repeat itself with "OR WinActive("") each time?

Thanks in advance

[blad4]

Code: Select all

SetTitleMatchMode, REGEX
#IfWinActive "ahk_exe notepad.exe")|("ahk_exe notepad++.exe") ...

[leo007]

blad4 Thanks for your Reply
yes its look exactly as I wanted it but of some reason it doesn't trigger anything.
could you please check if all the syntax is correct please

modified script

Code: Select all

SetTitleMatchMode, REGEX
#IfWinActive "ahk_exe chrome.exe")|("ahk_exe firefox.exe")
  $!LButton:: ; SELECT FULL TEXT LINE IN TEXT
{
    MsgBox,  Triggered
    Return
}

[Xtra]

See: GroupAdd
Example:

Spoiler

Code: Select all

GroupAdd, GroupOne, ahk_exe notepad.exe
GroupAdd, GroupOne, ahk_exe notepad++.exe
GroupAdd, GroupOne, ahk_exe Code.exe
GroupAdd, GroupOne, ahk_exe studio64.exe
GroupAdd, GroupOne, ahk_exe idea64.exe
GroupAdd, GroupOne, - OneNote ahk_class ApplicationFrameWindow, OneNote

GroupAdd, GroupTwo, ahk_exe chrome.exe
GroupAdd, GroupTwo, ahk_exe firefox.exe

#If WinActive("ahk_group GroupOne")   ; SELECT FULL TEXT LINE IN TEXT
    !LButton::
        KeyWait, Alt
        SendInput, {Esc}{LButton}
        SendInput, {HOME}{Shift Down}{End}{Shift Up}
    return
#If

#If WinActive("ahk_group GroupTwo")    ; SELECT FULL TEXT LINE IN TEXT
    !LButton:: 
        KeyWait, Alt
        SendInput, {Esc}{LButton 3}
    Return
#If

[boiler]

Code: Select all

SetTitleMatchMode, REGEX
#IfWinActive "ahk_exe notepad.exe")|("ahk_exe notepad++.exe") ...

Can’t use #IfWinActive that way. Has to be #If followed by multiple WinActive() function calls like the OP had. Changing to the other “or” operator alone won’t save any characters, especially because:

A single | (vertical bar) character is for bit-wise operations and doesn’t apply here. The alternative to or to be used here is || (double vertical bar).

You’re also missing an open parenthesis.

Edit: A properly formed regular expression may allow you to do something more along these lines, but the syntax show is not a regular expression.

[blad4]

Code: Select all

SetTitleMatchMode, REGEX
#IfWinActive "ahk_exe notepad.exe")|("ahk_exe notepad++.exe") ...

Can’t use #IfWinActive that way. Has to be #If followed by multiple WinActive() function calls like the OP had. Changing to the other “or” operator alone won’t save any characters, especially because:

A single | (vertical bar) character is for bit-wise operations and doesn’t apply here. The alternative to or to be used here is || (double vertical bar).

You’re also missing an open parenthesis.

Edit: A properly formed regular expression may allow you to do something more along these lines, but the syntax show is not a regular expression.

Thank you boiler

[Helgef]

#ifwinactive regex example,

Code: Select all

setTitleMatchMode regex
#ifwinactive ahk_exe (notepad|opera)\.exe
a::msgbox

Matches either notepad or opera exe.

Cheers.

[leo007]

blad4, boiler, Xtra, Helgef Thank you all guy for great scripts and valued explanation.
I learned by all of your examples thing I haven't know before.

in this particular case the most minimal script I guess would be out of Helgef example

Code: Select all

 setTitleMatchMode regex
 #ifwinactive ahk_exe (notepad|notepad++|Code|studio64|idea64|Everything)\.exe
     $!LButton::
     MsgBox, triggered
     return

only one small question how to add

Code: Select all

 OR WinActive("- OneNote ahk_class ApplicationFrameWindow", "OneNote") 

to this script?

thanks in advance

[Helgef]

I recommend you use Xtra's suggestion (regardless) and just add or WinActive(...) to it.

Edit, I see it already covers that, so just use it as is . You could change it to #ifwinactive ahk_group groupone, though.

Cheers.

[leo007]

ok Thanks)