Is possible to bind an action to a GUI button?

[fabricio234]

I know its possible to bind a call to function or a label

Code: Select all

gui, add, button, hWndbut vbut, minimize
onclick := ObjBindMethod("WinMinimize", "")
GuiControl, +g, %but%, %onclick%

gui, show, w300 h100
Return

WinMinimize() {
   WinMinimize, A
}

Is it possible to execute the function directly? something like this:

Code: Select all

gui, add, button, hWndbut vbut, minimize
onclick := ObjBindMethod("WinMinimize", "A")
GuiControl, +g, %but%, %onclick%

gui, show, w300 h100
return

[Helgef]

Use func + bind instead of ObjBindMethod. Example,

Code: Select all

Gui, Add, Button, hWndbut vbut, minimize
onclick := func("f").bind("abc")
GuiControl, +g, %but%, %onclick%

Gui, Show, w300 h100
Return

f(x){
	msgbox % x
}

WinMinimize isn't a function, but a command. So you cannot use it with func directly. You can call it from a user defined function instead.
Cheers.

[fabricio234]

Use func + bind instead of ObjBindMethod

Just for clarification, there's any problem using objbindmethod? is it wrong or what?

[Helgef]

It is wrong in this case, yes. See the documentation I linked to. ObjBindMethod takes an object as its first parameter, a method names as its second, subsequent parameters are values to bind to the method's remaining parameters. Here is how you could use ObjBindMethod, in your case,

Code: Select all

Gui, Add, Button, hWndbut vbut, minimize

obj := func("f")				; the object
onclick := objBindMethod(obj	
	, "call"					; the method name
	, "abc")					; the value to bind to the first parameter

GuiControl, +g, %but%, %onclick%

Gui, Show, w300 h100
Return

f(x){
	msgbox % x
}

Ofc, this is unnecessarily complex, just use func + bind.

Cheers.